Discussion :

[artichaulo]

Bonjour,

Je bosse depuis quelques temps sur un script .VBS qui permet d'automatiser le montage de nos lecteurs réseaux (en se basant sur un fichier .CSV). Ceux-ci se montent par GPO via ce fameux script VBS en fonction des groupes Active Directory auquels appartient l'utilisateur qui se connecte.

Voici la partie du code qui m'intérèsse

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
 
Set ADSysInfo = CreateObject("ADSystemInfo")											
Set CurrentUser = GetObject("LDAP://" & ADSysInfo.username)																				
 
strGroups = CurrentUser.MemberOf														
For Each Item in strGroups 													
	groupeCourant = Split(Item, ",")
        MsgBox groupeCourant(0)
	'Traitement de comparaison du GroupeCourant avec d'autres groupes pour monter le partage '
Next

Le script fonctionne parfaitement lorsque l'utilisateur appartient à minimum 2 utilisateurs.
A l'inverse lorsque l'utilisateur appartient à 0 ou 1 groupe, l'erreur suivante apparait ligne 5 carac 1 : "Err : Cet objet n'est pas une collection".

N'y a t-il pas moyen de garder cette logique de For Each avec eventuellement 0 ou 1 valeur dans ma variable strGroups ?

Merci d'avance !

[pc75]

Bonjour,

Si ça peut t'aider, j'avais fait ça en asp (donc en vbscript) :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
 
<%
Matricule = Request.QueryString("Mat")
Const ADS_SCOPE_SUBTREE = 2
 
Set objConnection = CreateObject("ADODB.Connection")
Set objCommand =   CreateObject("ADODB.Command")
objConnection.Provider = "ADsDSOObject"
 
objConnection.Properties("User ID")= "domaine\user"
objConnection.Properties("Password")= "pwd"
 
objConnection.Open "Active Directory Provider"
Set objCommand.ActiveConnection = objConnection
 
sql = "Select memberOf, sn, givenname "
sql = sql & "from 'LDAP://domaine' "
sql = sql & " where objectCategory = 'user' "
sql = sql & " and objectClass = 'user' "
sql = sql & " and extensionAttribute8 = '" & Matricule & "' "
objCommand.CommandText = sql
objCommand.Properties("Page Size") = 1000
objCommand.Properties("Searchscope") = ADS_SCOPE_SUBTREE
Set objRecordSet = objCommand.Execute
 
Response.Write "<center>"
Response.Write "Liste des groupes de : " & objRecordset.Fields("sn").Value & " " & objRecordset.Fields("givenname").Value & " (" & Matricule & ")<br><br><br>"
Response.Write "</center>"
 
if not objRecordSet.EOF then
	listGroups = ""
	listGroups = objRecordset.Fields("memberOf").Value
	for i = 0 to uBound(listGroups)
        chaine_groupe = listGroups(i)
	    groupTmp = Mid(chaine_groupe, InStr(chaine_groupe, "CN=") + 3, InStr(chaine_groupe, ",") - 4)
'	    if groupTmp <> "Admins du domaine" then
	        strGroupes = strGroupes & groupTmp & "<br>"
'	    end if
	next
	Response.Write strGroupes
end if
Set objCommand = Nothing
Set objConnection = Nothing
%>

[tsuji]

@artichaulo
C'est en effet un problème un peu connu et c'est vrai qu'il est très ennuyeux que le type du retour dépend le nombre soit zero, soit un ou soit plus nombreux qu'un qu'il trouve. Vous pouvez consulter cet article pour s'inspirer.
http://www.rlmueller.net/MemberOf.htm

N'y a t-il pas moyen de garder cette logique de For Each avec eventuellement 0 ou 1 valeur dans ma variable strGroups ?

Si vous voulez absolument garder la boucle, vous pouvez faire comme ça.

Code vbscript :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
strGroups = CurrentUser.MemberOf	
 
If IsEmpty(strGroups) Then
    strGroups=array()
ElseIf TypeName(strGroups) = "String" Then
    strGroups=array(strGroups)
End If
 
For Each Item in strGroups		
    groupeCourant = Split(Item, ",")
        MsgBox groupeCourant(0)
    'Traitement de comparaison du GroupeCourant avec d'autres groupes pour monter le partage '
Next