tableau HTML a partir d'un .CSV

**aka76par1** · 29/07/2013, 14h04

Bonjour,

Je voudrais faire une tableau html a partir d'un fichier csv. (ici)

Je m'explique plus précisément :

J'ai fait un script qui permet de scan un lecteur et recensé tout les fichier d'une tel ou tel extension. Et une fois le scan fini il génère un fichier csv de recette.
Je voudrai pouvoir prendre les infos du fichier csv et l'insérer dans un tableau HTML (plus jolis

).
N'étant qu'as mes débuts dans le HTML j'aurai besoin de vos conseils pour mon projet.
Je suis tomber sur des script PHP mais je n'y connais pas grand chose dans ce language

**Bovino** · 29/07/2013, 14h12

Une chose est sure, c'est que ce n'est certainement pas en HTML que tu pourras faire ça : HTML est un langage de structuration de données, pas un langage de programmation !
Donc tu devras soit passer par un langage de programmation (JavaScript côté client ou n'importe quel langage côté serveur) pour pouvoir construire le code HTML correspondant...

**hackoofr** · 29/07/2013, 14h29

Postez votre code et

**Vil'Coyote** · 29/07/2013, 14h37

pour résumer lire des données de ton csv c'est pas possible en html. maintenant vue que tu as un script qui génère ton fichier excel est ce que lui ne pourrais pas générer ton tableau html?

**hackoofr** · 29/07/2013, 16h12

JS : http://www.winscripter.com/WSH/FileIO/76.aspx
VBS : http://www.tech-archive.net/Archive/.../msg00794.html

**aka76par1** · 30/07/2013, 10h18

Envoyé par Vil'Coyote

pour résumer lire des données de ton csv c'est pas possible en html. maintenant vue que tu as un script qui génère ton fichier excel est ce que lui ne pourrais pas générer ton tableau html?

Le problème est qu'il faudrait que je créer le tableau HTML avant je pense ?! car si je demande (dans mon script)de généré du HTML la mise en page se fait a la suite sans saut de ligne.

Envoyé par Hakoofr

.. Postez votre code..

Le code de mon scan?
Voici, mais c'est du batch et je pense que je ne pourrais pas les faire a partir d'un batch. Tu m'avais parlé de voir en VBscript et j'ai donc commencé a regarder les tutos mais ne suis pas encore au point

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
@echo off
if exist "C:\scan-csv" goto :menu
IF NOT exist "C:\scan-csv" md C:\scan-csv
:menu
echo ...................................
set /p choix= Choix du lecteur?
echo ...................................
set /p choix2= Choix de l'extention?

for /r "%choix%:\" %%i in ("*.%choix2%" ) do echo %%i;%%~zi octet(s);%%~ti;%username% >> C:\scan-csv\scan.csv
echo FIN
goto :menu2
:menu2
echo Pour scanner un autre lecteur tapez 1
echo Pour quitter tapez 2 
set /p choix3= Votre choix?
GOTO %choix3% 
:1
goto :menu
:2
goto :exit
:exit
explorer C:\scan-csv
pause

Envoyé par Bovino

.....Donc tu devras soit passer par un langage de programmation (JavaScript côté client ou n'importe quel langage côté serveur) pour pouvoir construire le code HTML correspondant...

Un conseil sur le choix ....

Pour me lancé dans les tutos (Que je choisisse un language précis et que je me mette a fond dedans

)

Merci pour vos réponses rapide !!!

**aka76par1** · 30/07/2013, 10h23

Je vien de voir tes liens Hackoofr je test sa dans l'aprem (dès que j'ai un creux) sa ma l'air se qu'il faut!

Je vous redit sa dès que j'ai fait le test

**hackoofr** · 30/07/2013, 17h55

Testez ce code

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
Option Explicit
'****************************************************************************************
'* Ce script est Modifié par Hackoo le 30/07/2013
'* Ajout de La Fonction BrowseForFile() pour parcourir le fichier CSV pour la Conversion
'****************************************************************************************
' Vbscript Original
'http://www.tech-archive.net/Archive/Scripting/microsoft.public.scripting.vbscript/2005-05/msg00794.html
'* This VBS (Visual Basic Script) program does the following:
'* Reads a CSV file, formats a HTML table, and writes a HTM file.
'*****************************************************************************************
'* Declare Constants
'*
Const cVBS = "csv2html.vbs"
Const cHTM = "csv2html.htm"
'*
'* Declare Variables
'*
Dim arrCSV,intCSV,strCSV,arrDAT,intDAT,strSFN,cCSV,strHTM
cCSV = BrowseForFile
Dim arrSTR()
ReDim arrSTR(100)
Dim intSTR
intSTR = 0
'*
'* Declare Objects
'*
Dim objFSO,ws
Set objFSO = CreateObject("Scripting.FileSystemObject")
Set ws = CreateObject("WScript.Shell")
Dim objOTF
'*
'* Read CSV Page
'*
Set objOTF = objFSO.OpenTextFile(cCSV,1)
strCSV = objOTF.ReadAll()
Set objOTF = Nothing
'*
'* Build table
'*
Append "<body text=white bgcolor=#1234568>"&_
"<table border='3' cellpadding='1' style='border-collapse: collapse; font size:11pt' bordercolor='#CCCCCC' width='100%'>"
arrCSV = Split(strCSV,vbCrLf)
For intCSV = 0 To UBound(arrCSV)
    arrDAT = Split(arrCSV(intCSV),",")
    Append "</tr>"
    For intDAT = 0 To UBound(arrDAT)
        Append "<td><center>" & arrDAT(intDAT) & "</center></td>"
    Next
    Append "</tr>"
Next
Append "</table>"
'*
'* Write HTM File
'*
strHTM = Concat()
Set objOTF = objFSO.OpenTextFile(strSFN & cHTM,2,true)
objOTF.WriteLine(strHTM)
Set objOTF = Nothing
'*
'* Destroy Objects
'*
Set objFSO = Nothing
'*
'* Finish
'*
'MsgBox UBound(arrCSV)+1 & " Lignes dans le tableau",vbInformation,cVBS
Ws.Run cHTM

Sub Append(strSTR)
'****
'* Append()
'*
'* Appends strings to array entries ReDim as needed; (see "Concat()").
'****
    strSTR = strSTR & ""
    If intSTR > UBound(arrSTR) Then
        ReDim Preserve arrSTR(UBound(arrSTR) + 100)
    End If
    arrSTR(intSTR) = strSTR & vbCrLf
    intSTR = intSTR + 1
End Sub

Function Concat()
'****
'* Concat()
'*
'* Concatenates array entries into a single string; (see "Append()").
'****
    Redim Preserve arrSTR(intSTR)
    Concat = Replace(Join(arrSTR, ""),"`",Chr(34))
    Erase arrSTR
    ReDim arrSTR(100)
    intSTR = 0
End Function

Function BrowseForFile() 
    With CreateObject("WScript.Shell") 
        Dim fso : Set fso = CreateObject("Scripting.FileSystemObject") 
        Dim tempFolder : Set tempFolder = fso.GetSpecialFolder(2) 
        Dim tempName : tempName = fso.GetTempName() & ".hta" 
        Dim path : path = "HKCU\Volatile Environment\MsgResp" 
        With tempFolder.CreateTextFile(tempName) 
            .Write "<input type=file name=f>" & _ 
            "<script>f.click();(new ActiveXObject('WScript.Shell'))" & _ 
            ".RegWrite('HKCU\\Volatile Environment\\MsgResp', f.value);" & _ 
            "close();</script>" 
            .Close 
        End With 
        .Run tempFolder & "\" & tempName,0,True 
        BrowseForFile = .RegRead(path) 
        .RegDelete path 
    End With 
End Function

**aka76par1** · 31/07/2013, 08h59

Envoyé par Hackoofr

Testez ce code

C'est ce qui me faillait

Merci beaucoup

**hackoofr** · 31/07/2013, 14h55

Remarque : Dans ton script Batch le séparateur est ";" alors que dans le Vbscript le séparateur est ","
Donc tu dois modifier dans la ligne N°10 de ton Batch par celle-ci

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

for /r "%choix%:\" %%i in ("*.%choix2%" ) do echo %%i,%%~zi octet(s),%%~ti,%username% >> C:\scan-csv\scan.csv

et n'oublies pas le +1

pour la réponse pertinente

**hackoofr** · 31/07/2013, 15h09

Voici une autre approche plus générale en vbscript :
Recherche & Sauvegarde des fichiers par leurs Extensions

tableau HTML a partir d'un .CSV

Discussions similaires

Partager

Partager