Discussion :

[zikee]

Bonjour,

Je suis actuellement en cours d'apprentissage du langage Prolog et disons que je rame un peu (beaucoup).
Je dois réaliser un prédicat qui compte le nombre d'entiers dans une liste. Donc par exemple nb_int([1,g,2,2.3,d], R), R=2.
Seulement je n'y arrive pas. Ca doit être tout bête mais impossible d'y arriver.

J'en suis là :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
nb_int([], 0).
nb_int([integer(X)], 1).
nb_int([integer(X)|Y], 1).
nb_int([X|Y], R):- nb_int(Y, R).

et ce code me renvoie toujours R=0. Si quelqu'un peut m'aider.
Ca ne passe jamais sur les lignes 2 & 3. En fait, je ne sais pas comment faire pour savoir si l'élément X est un entier ou non (mais je sais qu'il faut utiliser integer...).
Merci d'avance et bonne journée,
Zikee.

[Trap D]

Non, ça ne fonctionne pas, car Prolog n'évalue pas ses arguments.
Ceci fonctionne :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
nb_int([], 0).
nb_int([X|Y], R1):-
	nb_int(Y, R),
	(   integer(X)
	->  R1 is R+1
	;    R1 = R).

[zikee]

Merci beaucoup ça fonctionne maintenant.
J'avais essayé quelque chose de la même forme mais ça ne fonctionne pas. Dans notre cours l'opérateur "implication" n'est, il me semble, pas mentionnée, je n'y avais donc pas pensé.

[Trap D]

Ce n'est pas une implication, c'est un if/then/else.
On peut le faire sans le if/then/else :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
nb_int([], 0).
nb_int([X|Y], R1):-
	integer(X),
	nb_int(Y, R),
	R1 is R+1.
 
nb_int([X|Y], R):-
	\+integer(X),
	nb_int(Y, R).

On peut rendre le code tail-recursif en utilisant la technique de l'accumulateur :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
nb_int(L, R) :-
  nb_int(L, 0, R).
 
nb_int([], R, R).
nb_int([X|Y], CR, FR):-
	integer(X),
        CR1 is CR+1,
	nb_int(Y, CR1, FR).
 
nb_int([X|Y], CR, FR):-
	\+integer(X),
	nb_int(Y, CR, FR).

[zikee]

Que signifie la ligne "\+integer(X)" ?

[Trap D]

\+ integer(X) réussit lorsque integer(X) échoue. C'est en quelque sorte la négation.
Tout ce que je dis peut-être trouvé dans la doc de SWI-Prolog.

[zikee]

D'accord, merci.

Maintenant j'essaie de trier une liste dans l'ordre croissant. Et comment dire... Ca ne se trie pas. Enfin si, seulement à certains endroits.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
tri_croissant([],[]).
tri_croissant([X], [X]).
 
tri_croissant([X,Y], R):- X > Y,
		R = [Y,X].
 
tri_croissant([X,Y], R):- X < Y,
		R = [X, Y].
 
tri_croissant([X,Y|Z], R):- X < Y,
		tri_croissant([Y|Z], R1),
		R = [X|R1].
 
tri_croissant([X,Y|Z], R):- X > Y,
		tri_croissant([X|Z], R1),
	        R = [Y|R1].

Donc si vous pouvez m'aider...
Vraiment pas évident à intégrer ce langage...

Merci d'avance

[Trap D]

Le problème est que l'algo est faux.
Par exemple :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
tri_croissant([X,Y|Z], R):- X < Y,
		tri_croissant([Y|Z], R1),
		R = [X|R1].

Que se passe-t-il si dans Z il y a un élément plus petit que X ?
Un tri assez simple à implémenter est le tri par insertion.

Vraiment pas évident à intégrer ce langage...

Comme disait quelqu'un , quand on commence Prolog, on commence par oublier tout ce qu'on sait de la prog.

[zikee]

J'ai finalement réussi. Je me suis servi d'un prédicat ajout_trie([X|Y], Element, R).

Maintenant je suis sur un problème d'arbre. Je dois compter le nombre de noeuds dans cet arbre. Il est de la forme : [Valeur, SousArbreGauche, SousArbreDroit].

J'ai donc fait un prédicat :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
/* Nombre de noeuds dans un arbe */
nb_noeuds([_], 1).
nb_noeuds([], 0).
nb_noeuds([_, [Y], [Z]], N):-
	/*write(Y),*/
	nb_noeuds([Y], N1),
	nb_noeuds([Z], N2),
	N is N1 + N2 + 1.

Je fais des appels récursifs sur chaque sous-arbre pour compter le nombre de noeuds dans chacun d'entre eux. Seulement, avec l'exemple suivant :

nb_noeuds([50, [20, [10, [], []], [25, [], [28, [], []]]], [75, [], [100, [80; [], []], []]]], R).

J'ai R = 3. Or, ça devrait m'afficher R = 8.

Merci d'avance pour votre aide...

[Trap D]

Il me semble qu'il n'y a qu'un seul cas de base, l'arbre vide :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
nb_noeuds([], 0).
nb_noeuds([_, Y, Z], N):-
	nb_noeuds(Y, N1),
	nb_noeuds(Z, N2),
	N is N1 + N2 + 1.

Attention, il y a une faute de frappe dans l'appel
nb_noeuds([50, [20, [10, [], []], [25, [], [28, [], []]]], [75, [], [100, [80; [], []], []]]], R). :
il y a un point virgule après 80.