Discussion :

[MarcelG]

Bonsoir le Forum,

Je débute sur les modules de classe.

J'essaie de créer l'applicatif mentionné dans le passsionnant tutoriel de Pierre Fauconnier à ce sujet.

Tutoriel de Pierre Fauconnier sur les modules de classe

Difficulté au paragraphe IV-E-2-b-ii.

Une erreur de compilation apparaît suite à un conflit entre le code de l'Userform et le module de Classe.

A noter. Une ambiguïté a été levée par Pierre Gonzales dans les commentaires sur ce tutoriel qui semble, sauf ereur, en rapport avec ma difficulté.

Partie du code du module de classe sur ce point

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
Public Event AnniversaireDans10jours(ByVal DateAnniversaire As Date)
 
....................
 
Property Let DateNaissance(DateNaissance As Date)
    ' Propriété en écriture
    Dim DateAnniversaire As Date
    mDateNaissance = DateNaissance
 
    ' Calcul de la date anniversaire pour l'année en cours
    DateAnniversaire = DateSerial(Year(Date), Month(DateNaissance), Day(DateNaissance))
 
    If DateAnniversaire >= Date And DateAnniversaire <= Date + 10 Then RaiseEvent AnniversaireDans10jours(DateAnniversaire)
End Property

Code Userform

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Option Explicit
Dim WithEvents ocontact As cContact
 
Private Sub Btn_Contact_Click()
    Set ocontact = New cContact
    With ocontact
        .Prenom = "Manon"
        .DateNaissance = DateSerial(1992, 3, 20)
    End With
 
End Sub
 
Private Sub oContact_AnniversaireDans10jours(DateAnniversaire)
    MsgBox "L'anniversaire de " & ocontact.Prenom & " a lieu dans les 10 prochains jours et se fêtera le " _
                & Format(DateSerial(Year(Date), Month(ocontact.DateNaissance), Day(ocontact.DateNaissance)), "d mmmm yyyy")
End Sub

La ligne surlignée pour ce conflit (erreur de compilation) est la première de la procédure évènementielle de "oContact_Anniversaire"

Le message d'erreur indique

"La description de la procédure ne correspond pas à la description de l'évènement ou de la procédure de même nom".

Je cherche sans succès.
Où est mon erreur? Que faut-il écrire? Et pourquoi?

Merci à tous.

[Pierre Fauconnier]

Bonsoir Marcel,

La procédure événementielle doit avoir la même "signature" que l'événement déclaré dans le module de classe.

En d'autres termes, la partie AnniversaireDans10jours(ByVal DateAnniversaire As Date) de la procédure événementielle du code appelant doit correspondre à la partie AnniversaireDans10jours(ByVal DateAnniversaire As Date) de la déclaration de l'événement dans le module de classe , pour ce qui concerne byval ou ByRef et le type du paramètre (as Date). Seul le nom du paramètre peut changer.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Private Sub oContact_AnniversaireDans10jours(ByVal DateAnniversaire As Date)

Désolé, je n'avais pas réagi sur le commentaire de Pierre Gonzales.

Je vais compléter le tuto, car je ne donne pas d'exemple de code appelant. Cela étant, si tu crées la procédure événementielle via les listes déroulantes de la fenêtre de code, tu obtiendras automatiquement la bonne signature.

[MarcelG]

Bonjour Pierre, Bonjour le(s) Forum,

Merci pour ette précision.

Le code est désormais effectif.

Bonne journée à tous.