Créer un compteur de données manquantes pour suppression de variables [Résolu]

[Mirela33]

Bonjour,

J'ai besoin d'exporter une table de SAS à Excel. Cela ne marche pas, je pense que c'est dû à un trop grand nombre de variables (plus de 4000 avec presque 3000 observations).

J'ai pas mal de variables avec beaucoup de données manquantes que je pourrais supprimer. Le problème c'est qu'avec plus de 4000 variables, je ne vais pas m'amuser à les supprimer une par une. Je pensais donc créer un compteur de données manquantes pour chaque variable et si le compteur est supérieur à un certain nombre, dire à SAS de supprimer la variable. Le problème c'est que je ne sais pas comment "appeler" les variables, je ne sais pas comment traduire en SAS le "pour chaque variable".

En espérant que ma question soit claire,

Merci beaucoup

[Géraldine_Cade_SAS]

Bonjour,

Pour votre approche, il faut utiliser des arrays. C'est ce qui permet de faire un même traitement sur plusieurs variables. J'ai écrit un article à ce sujet.

Voici une idée de programme, qui va tester les variables numériques et créées une macro-variable contenant la liste des variables à supprimer). Il faut faire le même programme pour un array _character_.

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
DATA data1 ;
SET sashelp.class ;
age=. ;
height=. ;
run ;
 
DATA data2 (DROP=_:) ;
	Length ListVar $32000. ; /* variable qui contiendra le nom des variables à dropper*/
	Array A_TestVarNum (30) _TEMPORARY_ ; /* *. chaque cas est un booléen indiquant si une valeur non nulle a été lue */
 
	SET data1 end=last;
	Array A_VarNum (*) _NUMERIC_ ; /* référence toutes les variables numériques de la table */
 
	/* on teste chaque variable, dès qu'une valeur est nulle on met une valeur 1 au booléen correspondant*/
	Do _i=1 TO dim(A_VarNum) ;
		IF A_VarNum(_i) ne . then A_TestVarNum (_i)=1 ;
	End ;
 
	/* une fois toutes les lignes testées, on regarde chaque booléen pour déterminer quelles variables sont à dropper*/
	IF last then do ;
		Do _i=1 TO dim(A_VarNum) ;
		put A_TestVarNum(_i)= ;
			IF A_TestVarNum(_i) eq . then ListVar=compbl (ListVar !! vname (A_VarNum(_i)) ) ;
		End ;
put ListVar= ;
   		call symput ("ASupprimer", ListVar) ;
	end ;
run ;
 
DATA data3 ;
SET data2 (DROP= &ASupprimer) ;
run ;

Mais j'imagine qu'il y a d'autres manières de faire, peut-être plus légères, comme faire une proc freq pour savoir quelles variables n'ont que des valeurs manquantes, puis lire le résultat déterminer le drop à faire.


Cordialement
Géraldine Cade Deschamps
Support Clients SAS

[datametric]

une autre méthode listant dans une MV nommée list les variables ayant plus de 1 valeur manquante.

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
proc summary DATA=data1 ;
var _numeric_;
output out = data2 (DROP=_:) nmiss= /autoname;
run;
 
proc transpose DATA=data2 out=data3;
var _all_;
run;
 
proc SQL noprint;
SELECT scan(_name_,1,'_') INTO :list separated BY ' ' 
FROM data3
WHERE col1 > 0;
quit;
%put &list;

[Mirela33]

Merci beaucoup c'est parfait !