Récupération nom champ dans liste et faire pointer dessus [Fait]

[Michel Hubert]

J'aimerais savoir si c'est possible de faire pointer la souris ou la tabulation sur un champ du formulaire en ayant choisi le champ en question, au préalable, dans une liste contenant tous les champs du formulaire. Si c'est possible, ce serait sympa de m'expliquer comment faire.

[marot_r]

Si tu es dans un form, présente ta liste de nom (maListeDeChamp) dans une combobox et sur l'événement :

'AfterUpdate' (AprèsMAJ) fait setfocus(maListeDeChamp).

Tu peux créer ta liste de champ en utilisant la collection Controls du form.

A+

[Michel Hubert]

Je comprends pas trop les termes combobox et collection de contrôle.

j'ai essayé en créant une liste de choix contenant le nom des divers champs du formulaire.

J'ai également testé la procédure évenementielle que tu ma proposé mais rien.

[cafeine]

N'ayant rien trouvé, j'ai fait une petite fonction à ajouter dans ton module de formulaire :

Envoyé par Code

Option Explicit

Private Type RECT
    Left As Long
    Top As Long
    Right As Long
    Bottom As Long
End Type

'   attribue la position de la souris
Private Declare Function apiSetCursorPos Lib "user32" Alias "SetCursorPos" ( _
        ByVal X As Long, ByVal Y As Long) As Long

'   retourne le rectangle d'un objet windows
Private Declare Function GetWindowRect Lib "user32" (ByVal hwnd As Long, lpRect As RECT) As Long

Private Declare Function apiGetFocus Lib "user32" _
        Alias "GetFocus" () As Long

Private Sub MoveMyMouseToControl(ByVal strCtl As String)

Dim ctl As Control
Dim hCtl As Long
Dim myRect As RECT

For Each ctl In Me.Controls
    If ctl.name = strCtl Then
        ' nous calculons le rectangle en pixels
        '  dans lequel s'inscrit le contrôle
        '  nous calculons les coordonnées du centre du
        '  rectangle afin d'y placer la souris
        ctl.SetFocus
        hCtl = apiGetFocus
        GetWindowRect hCtl, myRect
        apiSetCursorPos myRect.Left + (myRect.Right - myRect.Left) / 2, _
                        myRect.Top + (myRect.Bottom - myRect.Top) / 2
        
    End If
Next ctl

Set ctl = Nothing

End Sub

pour appeler la fonction

Code :

MoveMyMouseToControl "NomdeMonContrôle"

[cafeine]

Ensuite faire une liste des contrôles ...

mettre liste valeurs sur la propriété Origine source de txtGo (ma combo de sélection de contrôles)

Envoyé par Code

Private Sub Form_Load()

' constitution de la liste des contrôles ...
Dim ctl As Control
Dim strList As String

For Each ctl In Me.Controls
    Select Case ctl.ControlType
        Case acComboBox, acTextBox, acListBox
        ' nous choisissons certains types de contrôles
            strList = strList & ctl.name & ";"
            
        Case Else
    End Select
Next ctl

Me.txtGo.RowSource = strList

Set ctl = Nothing
End Sub

[Faw]

Et comme ça (sans vouloir t'offenser cafeine)?

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
Private Sub Form_Load()
 
' constitution de la liste des contrôles ...
Dim ctl As Control
Dim strList As String
 
For Each ctl In Me.Controls
    Select Case ctl.ControlType
        Case acComboBox, acTextBox, acListBox
        ' nous choisissons certains types de contrôles
            strList = strList & ctl.Name & ";"
 
        Case Else
    End Select
Next ctl
 
Me.Modifiable0.RowSource = strList
Set ctl = Nothing
End Sub
 
'*******************************
 
Private Sub Modifiable0_AfterUpdate()
Dim ctl As Control
For Each ctl In Me.Controls
 If ctl.Name = Modifiable0 Then
 ctl.SetFocus
 End If
 Next ctl
End Sub

[cafeine]

Hello,

aucune offense
d'autant que l'esprit est le même, tous les autres zigouigouis que j'ai rajoutés sont là pour déplacer le pointeur de la souris sur le contrôle, ce que ne fait pas ta version simplifiée du code

[Faw]

Des zigouigouis que je vais retenir volontiers...Merci cafeine.

[Arkham46]

bon alors vu qu'on offense pas :

Code :

1
2
3
4
5
6
7
8
9
Private Declare Function apiSetCursorPos Lib "user32" Alias "SetCursorPos" ( _
                                         ByVal X As Long, ByVal Y As Long) As Long
 
Private Sub MoveMyMouseToControl(pCtrl As String)
    Dim lx As Long, ly As Long, lw As Long, lh As Long
    Call Me.Controls(pCtrl).accLocation(lx, ly, lw, lh)
    apiSetCursorPos lx + lw / 2, _
                    ly + lh / 2
End Sub

Attention fonction non documentée; risques et périls et tout ça.

Mais c'est diablement pratique, on n'a pas besoin de mettre le focus sur le contrôle pour déterminer sa position sur l'écran; et ça marche avec tous les contrôles.

[cafeine]

Super !

évidemment c'est plus pratique et rapide

et parfois ce n'est pas plus mal d'avoir plusieurs méthodes pour un même résultat.

[Faw]

Arkham46
ça m'a effectivement fait penser à ta classe images & co avec là,
un déplacement de contrôles...

(j'essaye toujours de comprendre )