Installation d'une appli en fonction d'une valeur de registre [Résolu]

[Flagathor]

Bonjour,

Je veux faire le chose suivante :
-Dans la clé de registre “HKLM\SOFTWARE\Network Associates\ePolicy Orchestrator\Agent” je souhaite interroger la chaine REG_SZ appelée ePOServerList
-Si la valeur de ePOServerList est différente de EPOSERVER|192.168.0.33|444, lancer un .exe avec options.
-Sinon, ne rien faire.

Si en plus j’ai la possibilité de loguer tout ça pour un suivi (même sous excel) ce serait le must.

Le but est de balancer l’installation d’un package via GPO.

Le truc c'est que j'y connais franchement pas grand chose en scripting

quelqu'un a un idée ?

[Flagathor]

Bon bah j'ai galéré mais j'ai fini par faire ça (avec un peu d'aide )
ça fait ce que je veux et en plus ça fait un log par PC.

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
On Error Resume Next
 
'**** Déclaration des variables ****'
sLogPath = "\\Server1\Logs" '*** Path du fichier log ***'
sReferalValue = "EPOSERVER|172.17.150.161|444" '*** Valeur de clé de registre de référence ***'
sKeyPath = "HKEY_LOCAL_MACHINE\SOFTWARE\Network Associates\ePolicy Orchestrator\Agent\ePOServerList" '*** Path de la clé de registre ***'
sProgPath = "\\Server1\FramePkg_4.6.exe" '*** Path de l'exécutable ***'
sProgOptions = "/install=agent /forceinstall" '*** Options de l'exécutable ***'
DQ = Chr(34)
 
 
'**** Déclaration des objets ****'
Set oFso = CreateObject("Scripting.FileSystemObject")
Set oWsh = CreateObject("Wscript.Shell")
Set oWnt = CreateObject("Wscript.Network")
 
 
'**** Création d'un Log en fonction du nom d'ordinateur ***'
If Not oFso.FileExists(sLogPath & "\" & oWnt.ComputerName & ".log") Then
	Set oLog = oFso.OpenTextFile(sLogPath & "\" & oWnt.ComputerName & ".log",2,True)
Else
	Set oLog = oFso.OpenTextFile(sLogPath & "\" & oWnt.ComputerName & ".log",8,True)
End If
 
 
'**** Ecriture du Log ****'
oLog.WriteLine " --- " & Now & " --- "
 
 
'**** Interrogation de la valeur de clé de registre ****'
Err.Clear
sKeyValue = oWsh.RegRead(sKeyPath)
 
 
'**** Comparaison de la clé de registre et action ****'
If Err.Number <> 0 Or UCase(sKeyValue) <> UCase(sReferalValue) Then
 
	'**** Ecriture dans le log en cas d'erreur ****'
	If Err.Number <> 0 Then
		oLog.WriteLine "Clé de registre inexsistante"
	Else
		oLog.WriteLine "Clé de registre non conforme:" & UCase(sKeyValue)
	End If
 
	'**** Exécution du package ****'
	Err.Clear
	oWsh.Run DQ & sProgPath & DQ & " " & sProgOptions,0,False
 
	'**** Ecriture dans le log en cas d'erreur ****'
	If Err.Number <> 0 Then
		oLog.WriteLine "Erreur au lancement du programme"
	Else
		oLog.WriteLine "Lancement du programme effectué avec succès"
	End If
'**** Ecriture dans le log en cas de conformité ****'
Else
	oLog.WriteLine "Clé de registre conforme, Version d'agent OK"
End If
 
'**** Ecriture dans le log de 2 lignes blanches de séparation ****'
oLog.WriteBlankLines 2
oLog.Close