Discussion :

[orfeu]

Bonjour à tous,

j'essaye de créer un fichier xml de manière récursive. ca devrait donner quelque chose du genre:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
Public function xmlRecursion(ByVal i as integer) as xmldocument
  Dim res as xmldocument
  Dim xmlAtt As XmlAttribute
  Dim node, cnode As XmlElement
 
  Dim dec As XmlDeclaration = res.CreateXmlDeclaration("1.0", Nothing, Nothing)
  res.AppendChild(dec)
 
  cnode = res.CreateElement("Recursion")
  xmlAtt = res.CreateAttribute("level")
  xmlAtt.Value = i
  cnode.attributes.append(xmlAtt)
  res.AppendChild(cnode)
 
  If i>1 then
    node = xmlRecursion(i-1).DocumentElement
    node = res.OwnerDocument.ImportNode(node, True)
    cnode.AppendChild(node)
  End if
 
  Return res
End function

Ce code ne fonctionne pas, quelqu'un pourrait me filer un coup de main plz.

Merci d'avance

[tomlev]

On a pas de boule de cristal, et on ne lit pas dans les pensées...
Il faudrait donc que tu précises :
- ce que tu cherches à faire exactement ("créer un fichier xml de manière récursive", ça peut vouloir dire tout et n'importe quoi)
- ce que tu entends pas "ne fonctionne pas" (est-ce qu'il se produit une erreur ? si oui, laquelle ? sinon, quel sont le résultat attendu et le résultat obtenu ?)

[orfeu]

Désolé si ma question était incompréhensible, je vais essayer d'être plus clair...

j'essaye d'obtenir un fichier xml du genre

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
<Recursion level=3>
  <Recursion level=2>
    <Recursion level=1 />
  </Recursion>
</Recursion>

et le code du post précédent me renvoie une erreur NullPointerException à l'endroit où je fais l'appel récursif (je l'ai essayé entre temps).

[orfeu]

En fait, je n'étais pas loin de la solution...

au cas où, voici le code:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
Public shared function xmlRecursion(ByVal i as integer) as xmldocument
	Dim res, cxml as new xmldocument
	Dim xmlAtt As XmlAttribute
	Dim node, cnode As XmlElement
 
	Dim dec As XmlDeclaration = res.CreateXmlDeclaration("1.0", Nothing, Nothing)
	res.AppendChild(dec)
 
	cnode = res.CreateElement("Recursion")
	xmlAtt = res.CreateAttribute("level")
	xmlAtt.Value = i
	cnode.attributes.append(xmlAtt)
	res.AppendChild(cnode)
 
	If i>1 then
		cxml = xmlRecursion( i - 1)
		node = cxml.DocumentElement
		node = res.ImportNode(node, True)
		cnode.AppendChild(node)
	End if
	Return res
End function

Merci pour ta réponse et encore désolé pour le manque de claretée...

[tomlev]

me renvoie une erreur NullPointerException

Si tu faisais du Java ce serait possible, mais en .NET ça m'étonnerait... il doit plutôt s'agir d'une NullReferenceException

Par contre, j'ai testé et chez moi c'est à la ligne 6 que ça pète (logique, puisque tu n'as jamais initialisé la variable res). Il faut initialiser res au début :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Dim res as New XmlDocument

De plus, la propriété OwnerDocument renvoie toujours null (Nothing) pour un XmlDocument, il faut donc appeler ImportNode directement sur res :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

node = res.ImportNode(node, True)

Avec ça, ça fonctionne... par contre c'est pas très propre de créer un nouveau XmlDocument à chaque fois... J'aurais plutôt fait comme ça, avec Linq to XML :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
Function XmlRecursion(ByVal level As Integer) As XElement
    If level = 0 Then Return Nothing
    Return new XElement("Recursion", New XAttribute("level", level), XmlRecursion(level - 1))
End Function
 
...
 
Dim doc = new XDocument(XmlRecursion(3))

En plus c'est nettement plus simple

Si tu préfères, tu peux aussi utiliser la syntaxe XML littérale de VB.NET :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
Function XmlRecursion(ByVal level As Integer) As XElement
    If level = 0 Then Return Nothing
    Return <Recursion level=<%= level %>>
                <%= XmlRecursion(level - 1) %>
           </Recursion>
End Function

[orfeu]

Si tu faisais du Java ce serait possible, mais en .NET ça m'étonnerait... il doit plutôt s'agir d'une NullReferenceException

C'est bien vrai que je suis une quiche en VB, j'ai plus l'habitude de coder en java, d'où l'erreur (de toute manière ça correspond à la même chose...)

Merci, ton code mérite le respect! Je savais pas qu'on pouvais faire des choses aussi élégantes avec du VB...