Utilisation d'une rubrique en COMP-5 SYNC

dvi24 · 28/08/2012, 07h39

Bonjour

Lors d'une lecture en parallèle de deux fichiers, je me heurte au problème suivant :
- les enregistrements contiennent une rubrique de format S9(9) COMP-5 SYNC
- lors de la comparaison rubrique par rubrique de tout l'enregistrement, je détecte des écarts sur celles se trouvant après la rubrique en COMP-5 SYNC
- ces écarts ne sont pas des écarts réels : ils proviennent uniquement d'un décalage de deux caractères, comme si la rubrique en COMP-5 SYNC ne faisait pas systématiquement la longueur qu'elle est censée faire.

Exemple d'enregistrement :
01 GROUPE.
05 RUB-1 PIC X.
05 RUB-2 PIC X(4).
05 RUB-3 PIC X(4).
05 RUB-4 PIC S9(9) COMP-5 SYNC.
05 RUB-5 PIC X(2).
05 RUB-6 PIC X(2).

RUB-5 et RUB-6 apparaissent toujours en écart entre "source" et "cible" car le COMP-5 SYNC semble générer un décalage de deux caractères à la lecture du second fichier.

Avez-vous déjà rencontré ce type de problème ?

Merci par avance pour les informations que vous pourrez me transmettre.

Dvi

===============================================
Précisions : en utilisant un outil de visualisation du contenu du fichier, il apparaît que la valeur de la rubrique en COMP-5 SYNC est rgulièrement la même dans les deux fichiers. Ce serait donc la manipulation de cette donnée dans le programme qui entraînerait ce décalage.
Principe :
- lecture des deux fichiers en positionnant une clé de comparaison en début d'enregistrement (nouvel enregistrement = clé + zone banalisée contenant l'enregistrement d'origine)
- lecture en parallèle des deux fichiers triés avec comparaison des clés créées précédemment puis, sur clés identiques, bascule de la zone banalisée vers la zone standard correspondant à l'enregistrement et comparaison rubrique par rubrique
(c'est dans cette dernière étape que le décalage apparaît)
===============================================

dvi24 · 28/08/2012, 10h52

En travaillant en "zone à zone" plutôt qu'au niveau groupe (lors de l'alimentation de la rubrique puis de sa re-lecture), je ne rencontre plus le problème de décalage.

La solution semble trouvée mais je suis malgré tout preneur d'une explication "officielle" :
- est-ce que le fait de mouvementer un groupe de niveau 05 vers un autre groupe de niveau 10 peut modifier la synchronisation réalisée par la rubrique en COMP-5 SYNC ?

Merci par avance pour vos remarques.

Dvi

Hédhili Jaïdane · 28/08/2012, 13h06

Bonjour.

C'est à cause de la clause SYNC (SYNCHRONIZED) qui ajoute des fillers (Slack bytes) pour aligner la rubrique sur un demi-mot, un mot, un double mot ou un quadruple mot à partir du début de l'enregistrement. Voir, par exemple, ce lien : http://publib.boulder.ibm.com/infoce...39370.htm#sync

Si tu travailles au niveau de la zone, il n'y a aucun problème. Par contre si tu travailles au niveau de groupes qui n'ont pas la même description, y compris le SYNC, là tu vas avoir des problèmes à cause des slack bytes insérés par le compilateur.

Examples :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
01 FIELD-A.
    05 FIELD-B PICTURE X(5).
    05 FIELD-C.
        10 FIELD-D PICTURE XX.
       [10 SLACK-BYTES PICTURE X. INSERTED BY COMPILER]
        10 FIELD-E COMPUTATIONAL PICTURE S9(6) SYNC.

01 COMP-RECORD.
   05 A-1 PICTURE X(5).
   05 A-2 PICTURE X(3).
   05 A-3 PICTURE X(3).
  [05 SLACK-BYTE-1 PICTURE X. INSERTED BY COMPILER]
   05 B-1 PICTURE S9999 USAGE COMP SYNCHRONIZED.
  [05 SLACK-BYTE-2 PICTURE XX. INSERTED BY COMPILER]
   05 B-2 PICTURE S99999 USAGE COMP SYNCHRONIZED.
   05 B-3 PICTURE S9999 USAGE COMP SYNCHRONIZED.

dvi24 · 28/08/2012, 18h59

Merci pour ces informations.

Afin de toucher du doigt le problème, j'ai créé un petit programme pour tenter de voir à quel moment (avec quel type de move) pouvait apparaître un décalage.
Tel que je l'ai écrit, le programme ne fait jamais apparaître de décalage.
Pourrais-tu m'apporter des précisions sur les traitements qui entraîneraient un décalage potentiel, s'il te plaît ? Ou m'indiquer à quel niveau je fais erreur dans mon programme de test ?

Merci

Dvi

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
      ******************************************************************                  
      *          EXEMPLE                                               *                  
      ******************************************************************                  
       IDENTIFICATION DIVISION .                                                          
       PROGRAM-ID .   DVI001 .                                                            
       ENVIRONMENT    DIVISION .                                                          
       CONFIGURATION  SECTION .                                                           
                                                                                         
       SOURCE-COMPUTER .  MF-UNIX .                                                       
       OBJECT-COMPUTER .  MF-UNIX .                                                       
                                                                                         
       INPUT-OUTPUT SECTION .                                                             
       FILE-CONTROL .                                                                     
                                                                                         
       DATA DIVISION.                                                                     

       FILE SECTION.                                                                                                                                                        

       WORKING-STORAGE SECTION.
      
       01  XXPROG-ID                      PIC     X(020)
                                          value   "TstCob_Sync".

       01  AB9X-I1.                                                          
         03 C-AB9X-I1.                                                         
           05 NTYPENR-AB9X-I1             PIC     9(2) COMP-6.
           05 VGRPTRVEDT-AB9X-I1          PIC     X(4).
           05 VGRPTRVTRI-AB9X-I1          PIC     X(4).
           05 LFIL-AB9X-I1                PIC     X(3).
           05 VDBK-INDASU-AB9X-I1         PIC     S9(9) COMP-5 SYNC.
           05 CTRENOM-AB9X-I1             PIC     X.
           05 CSEXIND-AB9X-I1             PIC     X.
           05 LNOMIND-AB9X-I1             PIC     X(25).
           05 LPREIND-AB9X-I1             PIC     X(20).
           05 LNOMMAR-AB9X-I1             PIC     X(25).
           05 CNATDECINF-AB9X-I1          PIC     X.
           05 CNATDECPMT-AB9X-I1          PIC     X.
           05 LNOMUSU-ASU-AB9X-I1         PIC     X(25).
           05 LFIL-AB9X-01-I1             PIC     X(20).

       01  AB9X-I2.                                                          
         03 C-AB9X-I2.                                                         
           05 NTYPENR-AB9X-I2             PIC     9(2) COMP-6.
           05 VGRPTRVEDT-AB9X-I2          PIC     X(4).
           05 VGRPTRVTRI-AB9X-I2          PIC     X(4).
           05 LFIL-AB9X-I2                PIC     X(3).
           05 VDBK-INDASU-AB9X-I2         PIC     S9(9) COMP-5 SYNC.
           05 CTRENOM-AB9X-I2             PIC     X.
           05 CSEXIND-AB9X-I2             PIC     X.
           05 LNOMIND-AB9X-I2             PIC     X(25).
           05 LPREIND-AB9X-I2             PIC     X(20).
           05 LNOMMAR-AB9X-I2             PIC     X(25).
           05 CNATDECINF-AB9X-I2          PIC     X.
           05 CNATDECPMT-AB9X-I2          PIC     X.
           05 LNOMUSU-ASU-AB9X-I2         PIC     X(25).
           05 LFIL-AB9X-01-I2             PIC     X(20).

       01  AB9X-I3.
         03 C-AB9X-I3.
         04 C-AB9X-I3-NIV-04.
           05 NTYPENR-AB9X-I3             PIC     9(2) COMP-6.
           05 VGRPTRVEDT-AB9X-I3          PIC     X(4).
           05 VGRPTRVTRI-AB9X-I3          PIC     X(4).
           05 LFIL-AB9X-I3                PIC     X(3).
           05 VDBK-INDASU-AB9X-I3         PIC     S9(9) COMP-5 SYNC.
           05 CTRENOM-AB9X-I3             PIC     X.
           05 CSEXIND-AB9X-I3             PIC     X.
           05 LNOMIND-AB9X-I3             PIC     X(25).
           05 LPREIND-AB9X-I3             PIC     X(20).
           05 LNOMMAR-AB9X-I3             PIC     X(25).
           05 CNATDECINF-AB9X-I3          PIC     X.
           05 CNATDECPMT-AB9X-I3          PIC     X.
           05 LNOMUSU-ASU-AB9X-I3         PIC     X(25).
           05 LFIL-AB9X-01-I3             PIC     X(20).

       01   AB9X-GROUPE.
         03 AB9X-FILLER                   PIC     X(200).
         03 C-AB9X-I4.
         20 C-AB9X-I4-NIV-04.
           30 NTYPENR-AB9X-I4             PIC     9(2) COMP-6.
           30 VGRPTRVEDT-AB9X-I4          PIC     X(4).
           30 VGRPTRVTRI-AB9X-I4          PIC     X(4).
           30 LFIL-AB9X-I4                PIC     X(3).
           30 VDBK-INDASU-AB9X-I4         PIC     S9(9) COMP-5 SYNC.
           30 CTRENOM-AB9X-I4             PIC     X.
           30 CSEXIND-AB9X-I4             PIC     X.
           30 LNOMIND-AB9X-I4             PIC     X(25).
           30 LPREIND-AB9X-I4             PIC     X(20).
           30 LNOMMAR-AB9X-I4             PIC     X(25).
           30 CNATDECINF-AB9X-I4          PIC     X.
           30 CNATDECPMT-AB9X-I4          PIC     X.
           30 LNOMUSU-ASU-AB9X-I4         PIC     X(25).
           30 LFIL-AB9X-01-I4             PIC     X(20).
          

       PROCEDURE DIVISION.                                                                
      ******************************************************************                  
      *                   TRAITEMENT PRINCIPAL                                            
      ******************************************************************                  
                                                                                         
       PRINCIPAL SECTION.                                                                 
       PR-000.                                                                              

           INITIALIZE                        C-AB9X-I1.
           MOVE 25                        TO NTYPENR-AB9X-I1.    
           MOVE "1***"                    TO VGRPTRVEDT-AB9X-I1. 
           MOVE "2***"                    TO VGRPTRVTRI-AB9X-I1. 
           MOVE "FIL"                     TO LFIL-AB9X-I1.       
           MOVE +0530004408               TO VDBK-INDASU-AB9X-I1.
           MOVE "1"                       TO CTRENOM-AB9X-I1.    
           MOVE "2"                       TO CSEXIND-AB9X-I1.    
           MOVE "PLATH"                   TO LNOMIND-AB9X-I1.    
           MOVE "SYLVIA"                  TO LPREIND-AB9X-I1.    
           MOVE "HUGUES"                  TO LNOMMAR-AB9X-I1.    
           MOVE "A"                       TO CNATDECINF-AB9X-I1.
           MOVE "B"                       TO CNATDECPMT-AB9X-I1.
           MOVE "SYVY"                    TO LNOMUSU-ASU-AB9X-I1.
           MOVE "FILLER-2"                TO LFIL-AB9X-01-I1.    

           DISPLAY "NTYPENR-AB9X-I1     : " NTYPENR-AB9X-I1.
           DISPLAY "VGRPTRVEDT-AB9X-I1  : " VGRPTRVEDT-AB9X-I1.
           DISPLAY "VGRPTRVTRI-AB9X-I1  : " VGRPTRVTRI-AB9X-I1.
           DISPLAY "LFIL-AB9X-I1        : " LFIL-AB9X-I1.
           DISPLAY "VDBK-INDASU-AB9X-I1 : " VDBK-INDASU-AB9X-I1.
           DISPLAY "CTRENOM-AB9X-I1     : " CTRENOM-AB9X-I1.
           DISPLAY "CSEXIND-AB9X-I1     : " CSEXIND-AB9X-I1.
           DISPLAY "LNOMIND-AB9X-I1     : " LNOMIND-AB9X-I1.
           DISPLAY "LPREIND-AB9X-I1     : " LPREIND-AB9X-I1.
           DISPLAY "LNOMMAR-AB9X-I1     : " LNOMMAR-AB9X-I1.
           DISPLAY "CNATDECINF-AB9X-I1  : " CNATDECINF-AB9X-I1.
           DISPLAY "CNATDECPMT-AB9X-I1  : " CNATDECPMT-AB9X-I1.
           DISPLAY "LNOMUSU-ASU-AB9X-I1 : " LNOMUSU-ASU-AB9X-I1.
           DISPLAY "LFIL-AB9X-01-I1     : " LFIL-AB9X-01-I1.

      * Premier MOVE
           MOVE C-AB9X-I1                 TO C-AB9X-I2.

           DISPLAY "NTYPENR-AB9X-I2     : " NTYPENR-AB9X-I2.
           DISPLAY "VGRPTRVEDT-AB9X-I2  : " VGRPTRVEDT-AB9X-I2.
           DISPLAY "VGRPTRVTRI-AB9X-I2  : " VGRPTRVTRI-AB9X-I2.
           DISPLAY "LFIL-AB9X-I2        : " LFIL-AB9X-I2.
           DISPLAY "VDBK-INDASU-AB9X-I2 : " VDBK-INDASU-AB9X-I2.
           DISPLAY "CTRENOM-AB9X-I2     : " CTRENOM-AB9X-I2.
           DISPLAY "CSEXIND-AB9X-I2     : " CSEXIND-AB9X-I2.
           DISPLAY "LNOMIND-AB9X-I2     : " LNOMIND-AB9X-I2.
           DISPLAY "LPREIND-AB9X-I2     : " LPREIND-AB9X-I2.
           DISPLAY "LNOMMAR-AB9X-I2     : " LNOMMAR-AB9X-I2.
           DISPLAY "CNATDECINF-AB9X-I2  : " CNATDECINF-AB9X-I2.
           DISPLAY "CNATDECPMT-AB9X-I2  : " CNATDECPMT-AB9X-I2.
           DISPLAY "LNOMUSU-ASU-AB9X-I2 : " LNOMUSU-ASU-AB9X-I2.
           DISPLAY "LFIL-AB9X-01-I2     : " LFIL-AB9X-01-I2.

      * Second MOVE
           MOVE C-AB9X-I1                 TO C-AB9X-I3.

           DISPLAY "NTYPENR-AB9X-I3     : " NTYPENR-AB9X-I3.
           DISPLAY "VGRPTRVEDT-AB9X-I3  : " VGRPTRVEDT-AB9X-I3.
           DISPLAY "VGRPTRVTRI-AB9X-I3  : " VGRPTRVTRI-AB9X-I3.
           DISPLAY "LFIL-AB9X-I3        : " LFIL-AB9X-I3.
           DISPLAY "VDBK-INDASU-AB9X-I3 : " VDBK-INDASU-AB9X-I3.
           DISPLAY "CTRENOM-AB9X-I3     : " CTRENOM-AB9X-I3.
           DISPLAY "CSEXIND-AB9X-I3     : " CSEXIND-AB9X-I3.
           DISPLAY "LNOMIND-AB9X-I3     : " LNOMIND-AB9X-I3.
           DISPLAY "LPREIND-AB9X-I3     : " LPREIND-AB9X-I3.
           DISPLAY "LNOMMAR-AB9X-I3     : " LNOMMAR-AB9X-I3.
           DISPLAY "CNATDECINF-AB9X-I3  : " CNATDECINF-AB9X-I3.
           DISPLAY "CNATDECPMT-AB9X-I3  : " CNATDECPMT-AB9X-I3.
           DISPLAY "LNOMUSU-ASU-AB9X-I3 : " LNOMUSU-ASU-AB9X-I3.
           DISPLAY "LFIL-AB9X-01-I3     : " LFIL-AB9X-01-I3.

      * Troisieme MOVE
           INITIALIZE                        AB9X-GROUPE.
           MOVE C-AB9X-I1                 TO AB9X-FILLER.
           MOVE AB9X-FILLER               TO C-AB9X-I4-NIV-04.

           DISPLAY "NTYPENR-AB9X-I4     : " NTYPENR-AB9X-I4.
           DISPLAY "VGRPTRVEDT-AB9X-I4  : " VGRPTRVEDT-AB9X-I4.
           DISPLAY "VGRPTRVTRI-AB9X-I4  : " VGRPTRVTRI-AB9X-I4.
           DISPLAY "LFIL-AB9X-I4        : " LFIL-AB9X-I4.
           DISPLAY "VDBK-INDASU-AB9X-I4 : " VDBK-INDASU-AB9X-I4.
           DISPLAY "CTRENOM-AB9X-I4     : " CTRENOM-AB9X-I4.
           DISPLAY "CSEXIND-AB9X-I4     : " CSEXIND-AB9X-I4.
           DISPLAY "LNOMIND-AB9X-I4     : " LNOMIND-AB9X-I4.
           DISPLAY "LPREIND-AB9X-I4     : " LPREIND-AB9X-I4.
           DISPLAY "LNOMMAR-AB9X-I4     : " LNOMMAR-AB9X-I4.
           DISPLAY "CNATDECINF-AB9X-I4  : " CNATDECINF-AB9X-I4.
           DISPLAY "CNATDECPMT-AB9X-I4  : " CNATDECPMT-AB9X-I4.
           DISPLAY "LNOMUSU-ASU-AB9X-I4 : " LNOMUSU-ASU-AB9X-I4.
           DISPLAY "LFIL-AB9X-01-I4     : " LFIL-AB9X-01-I4.

       PR-888.                                                                                        
           STOP RUN.
           
       PR-999.                                                                            
           EXIT.

Hédhili Jaïdane · 28/08/2012, 23h36

En fait c'est à toi de nous dire si ça marche ou non et dans ce cas quelle est l'erreur et où.

Grossièrement, la règle est la suivante : à chaque fois que le compilateur rencontre un SYNC, il insère, juste devant et avec le même niveau, un filler de telle façon que la taille totale de toutes les zones précédentes la zone en SYNC, y compris les éventuelles insertions précédant dues au SYNC, et ce à partir du niveau 01, soit multiple de 4 (dans ton cas).

Donc si ta zone en SYNC occupe le même emplacement à partir du niveau 01 et est précédée des mêmes zones en taille (et en type éventuellement).

Dans le programme que tu donnes, les 3 premiers groupes sont définis de la même façon, donc le MOVE de groupes ou des zones élémentaires ne devrait pas poser de problèmes.

Le 4è groupe est différent, même si ses groupes sont identiques, la taille du slack-bytes inséré sera donc différente puisqu'on commence à totaliser les longueurs à partir du niveau 01. Sauf que là, tu as de la chance puisque 200 est multiple de 4. Ton 3è MOVE doit donc marcher.

Fais des DISPLAY de tes niveaux 01 et tu verras les alignements des zones.

Regarde aussi ton listing de compilation, il devrait contenir les insertions du compilateur.

En récap :
- dans les 3 premiers groupes : 13/4 = 3 , reste = 1, donc on insère un filler de 3 octets (4 - 1 = 3)
- dans le 4è groupe : 213/4 = 53, reste = 1 donc pareil, on insère un filler de 3 octets. Change ta zone de 200 en 199 et tu verras le décalage.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
05 FILLER                      PIC     XXX.
05 VDBK-INDASU-AB9X-I1         PIC     S9(9) COMP-5 SYNC.

Remarque : Ces insertions sont faites par le compilateur.

dvi24 · 29/08/2012, 23h05

Effectivement, j'ai fait en sorte de ne plus avoir un multiple de quatre avant le groupe AB9X et le décalage est apparu.
Je posterai le mini-prog et le résultat au plus tôt, pour permettre à ce que ça intéresse d'imager ma question.

Par contre, je n'arrive pas à avoir un résultat de compil dans lequel apparaissent les fameux filler ajoutés ... Faut-il une option de compil particulière ?

Hédhili Jaïdane · 30/08/2012, 10h12

Citation:

Envoyé par dvi24

...Par contre, je n'arrive pas à avoir un résultat de compil dans lequel apparaissent les fameux filler ajoutés ... Faut-il une option de compil particulière ?

T'en fais pas trop, ton compilo ne doit pas générer les slack bytes dans le listing de compilation, mais il en tient compte dans la génération du dictionnaire des données et dans le calcul des offsets.

dvi24 · 31/08/2012, 14h26

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
      ******************************************************************                  
      *          EXEMPLE                                               *                  
      ******************************************************************                  
       IDENTIFICATION DIVISION .                                                          
       PROGRAM-ID .   DVI001 .                                                            
       ENVIRONMENT    DIVISION .                                                          
       CONFIGURATION  SECTION .                                                           
                                                                                         
       SOURCE-COMPUTER .  MF-UNIX .                                                       
       OBJECT-COMPUTER .  MF-UNIX .                                                       
                                                                                         
       INPUT-OUTPUT SECTION .                                                             
       FILE-CONTROL .                                                                     
                                                                                         
       DATA DIVISION.                                                                     

       FILE SECTION.                                                                                                                                                        

       WORKING-STORAGE SECTION.
      
       01  XXPROG-ID                      PIC     X(020)
                                          value   "TstCob_Sync".

       01  AB9X-I1.                                                          
         03 C-AB9X-I1.                                                         
           05 NTYPENR-AB9X-I1             PIC     9(2) COMP-6.
           05 VGRPTRVEDT-AB9X-I1          PIC     X(4).
           05 VGRPTRVTRI-AB9X-I1          PIC     X(4).
           05 LFIL-AB9X-I1                PIC     X(3).
           05 VDBK-INDASU-AB9X-I1         PIC     S9(9) COMP-5 SYNC.
           05 CTRENOM-AB9X-I1             PIC     X.
           05 CSEXIND-AB9X-I1             PIC     X.
           05 LNOMIND-AB9X-I1             PIC     X(25).
           05 LPREIND-AB9X-I1             PIC     X(20).
           05 LNOMMAR-AB9X-I1             PIC     X(25).
           05 CNATDECINF-AB9X-I1          PIC     X.
           05 CNATDECPMT-AB9X-I1          PIC     X.
           05 LNOMUSU-ASU-AB9X-I1         PIC     X(25).
           05 LFIL-AB9X-01-I1             PIC     X(20).

       01  AB9X-I2.                                                          
         03 C-AB9X-I2.                                                         
           05 NTYPENR-AB9X-I2             PIC     9(2) COMP-6.
           05 VGRPTRVEDT-AB9X-I2          PIC     X(4).
           05 VGRPTRVTRI-AB9X-I2          PIC     X(4).
           05 LFIL-AB9X-I2                PIC     X(3).
           05 VDBK-INDASU-AB9X-I2         PIC     S9(9) COMP-5 SYNC.
           05 CTRENOM-AB9X-I2             PIC     X.
           05 CSEXIND-AB9X-I2             PIC     X.
           05 LNOMIND-AB9X-I2             PIC     X(25).
           05 LPREIND-AB9X-I2             PIC     X(20).
           05 LNOMMAR-AB9X-I2             PIC     X(25).
           05 CNATDECINF-AB9X-I2          PIC     X.
           05 CNATDECPMT-AB9X-I2          PIC     X.
           05 LNOMUSU-ASU-AB9X-I2         PIC     X(25).
           05 LFIL-AB9X-01-I2             PIC     X(20).

       01  AB9X-I3.
         03 C-AB9X-I3.
         04 C-AB9X-I3-NIV-04.
           05 NTYPENR-AB9X-I3             PIC     9(2) COMP-6.
           05 VGRPTRVEDT-AB9X-I3          PIC     X(4).
           05 VGRPTRVTRI-AB9X-I3          PIC     X(4).
           05 LFIL-AB9X-I3                PIC     X(3).
           05 VDBK-INDASU-AB9X-I3         PIC     S9(9) COMP-5 SYNC.
           05 CTRENOM-AB9X-I3             PIC     X.
           05 CSEXIND-AB9X-I3             PIC     X.
           05 LNOMIND-AB9X-I3             PIC     X(25).
           05 LPREIND-AB9X-I3             PIC     X(20).
           05 LNOMMAR-AB9X-I3             PIC     X(25).
           05 CNATDECINF-AB9X-I3          PIC     X.
           05 CNATDECPMT-AB9X-I3          PIC     X.
           05 LNOMUSU-ASU-AB9X-I3         PIC     X(25).
           05 LFIL-AB9X-01-I3             PIC     X(20).

       01   AB9X-GROUPE-MULTIPLE-DE-4.
         03 AB9X-FILLER                   PIC     X(200).
         03 C-AB9X-I4.
         20 C-AB9X-I4-NIV-04.
           30 NTYPENR-AB9X-I4             PIC     9(2) COMP-6.
           30 VGRPTRVEDT-AB9X-I4          PIC     X(4).
           30 VGRPTRVTRI-AB9X-I4          PIC     X(4).
           30 LFIL-AB9X-I4                PIC     X(3).
           30 VDBK-INDASU-AB9X-I4         PIC     S9(9) COMP-5 SYNC.
           30 CTRENOM-AB9X-I4             PIC     X.
           30 CSEXIND-AB9X-I4             PIC     X.
           30 LNOMIND-AB9X-I4             PIC     X(25).
           30 LPREIND-AB9X-I4             PIC     X(20).
           30 LNOMMAR-AB9X-I4             PIC     X(25).
           30 CNATDECINF-AB9X-I4          PIC     X.
           30 CNATDECPMT-AB9X-I4          PIC     X.
           30 LNOMUSU-ASU-AB9X-I4         PIC     X(25).
           30 LFIL-AB9X-01-I4             PIC     X(20).
          
       01   AB9X-GROUPE-NON-MULTIPLE-DE-4.
         03 AB9X-FILLER-GNMD4             PIC     X(199).
         03 C-AB9X-I5.
         20 C-AB9X-I5-NIV-04.
           30 NTYPENR-AB9X-I5             PIC     9(2) COMP-6.
           30 VGRPTRVEDT-AB9X-I5          PIC     X(4).
           30 VGRPTRVTRI-AB9X-I5          PIC     X(4).
           30 LFIL-AB9X-I5                PIC     X(3).
           30 VDBK-INDASU-AB9X-I5         PIC     S9(9) COMP-5 SYNC.
           30 CTRENOM-AB9X-I5             PIC     X.
           30 CSEXIND-AB9X-I5             PIC     X.
           30 LNOMIND-AB9X-I5             PIC     X(25).
           30 LPREIND-AB9X-I5             PIC     X(20).
           30 LNOMMAR-AB9X-I5             PIC     X(25).
           30 CNATDECINF-AB9X-I5          PIC     X.
           30 CNATDECPMT-AB9X-I5          PIC     X.
           30 LNOMUSU-ASU-AB9X-I5         PIC     X(25).
           30 LFIL-AB9X-01-I5             PIC     X(20).

       PROCEDURE DIVISION.                                                                
      ******************************************************************                  
      *                   TRAITEMENT PRINCIPAL                                            
      ******************************************************************                  
                                                                                         
       PRINCIPAL SECTION.                                                                 
       PR-000.                                                                              

           INITIALIZE                        C-AB9X-I1.
           MOVE 25                        TO NTYPENR-AB9X-I1.    
           MOVE "1***"                    TO VGRPTRVEDT-AB9X-I1. 
           MOVE "2***"                    TO VGRPTRVTRI-AB9X-I1. 
           MOVE "FIL"                     TO LFIL-AB9X-I1.       
           MOVE +0530004408               TO VDBK-INDASU-AB9X-I1.
           MOVE "1"                       TO CTRENOM-AB9X-I1.    
           MOVE "2"                       TO CSEXIND-AB9X-I1.    
           MOVE "PLATH"                   TO LNOMIND-AB9X-I1.    
           MOVE "SYLVIA"                  TO LPREIND-AB9X-I1.    
           MOVE "HUGUES"                  TO LNOMMAR-AB9X-I1.    
           MOVE "A"                       TO CNATDECINF-AB9X-I1.
           MOVE "B"                       TO CNATDECPMT-AB9X-I1.
           MOVE "SYVY"                    TO LNOMUSU-ASU-AB9X-I1.
           MOVE "FILLER-2"                TO LFIL-AB9X-01-I1.    

           DISPLAY "NTYPENR-AB9X-I1     : " NTYPENR-AB9X-I1.
           DISPLAY "VGRPTRVEDT-AB9X-I1  : " VGRPTRVEDT-AB9X-I1.
           DISPLAY "VGRPTRVTRI-AB9X-I1  : " VGRPTRVTRI-AB9X-I1.
           DISPLAY "LFIL-AB9X-I1        : " LFIL-AB9X-I1.
           DISPLAY "VDBK-INDASU-AB9X-I1 : " VDBK-INDASU-AB9X-I1.
           DISPLAY "CTRENOM-AB9X-I1     : " CTRENOM-AB9X-I1.
           DISPLAY "CSEXIND-AB9X-I1     : " CSEXIND-AB9X-I1.
           DISPLAY "LNOMIND-AB9X-I1     : " LNOMIND-AB9X-I1.
           DISPLAY "LPREIND-AB9X-I1     : " LPREIND-AB9X-I1.
           DISPLAY "LNOMMAR-AB9X-I1     : " LNOMMAR-AB9X-I1.
           DISPLAY "CNATDECINF-AB9X-I1  : " CNATDECINF-AB9X-I1.
           DISPLAY "CNATDECPMT-AB9X-I1  : " CNATDECPMT-AB9X-I1.
           DISPLAY "LNOMUSU-ASU-AB9X-I1 : " LNOMUSU-ASU-AB9X-I1.
           DISPLAY "LFIL-AB9X-01-I1     : " LFIL-AB9X-01-I1.

      * Premier MOVE
           MOVE C-AB9X-I1                 TO C-AB9X-I2.

           DISPLAY "NTYPENR-AB9X-I2     : " NTYPENR-AB9X-I2.
           DISPLAY "VGRPTRVEDT-AB9X-I2  : " VGRPTRVEDT-AB9X-I2.
           DISPLAY "VGRPTRVTRI-AB9X-I2  : " VGRPTRVTRI-AB9X-I2.
           DISPLAY "LFIL-AB9X-I2        : " LFIL-AB9X-I2.
           DISPLAY "VDBK-INDASU-AB9X-I2 : " VDBK-INDASU-AB9X-I2.
           DISPLAY "CTRENOM-AB9X-I2     : " CTRENOM-AB9X-I2.
           DISPLAY "CSEXIND-AB9X-I2     : " CSEXIND-AB9X-I2.
           DISPLAY "LNOMIND-AB9X-I2     : " LNOMIND-AB9X-I2.
           DISPLAY "LPREIND-AB9X-I2     : " LPREIND-AB9X-I2.
           DISPLAY "LNOMMAR-AB9X-I2     : " LNOMMAR-AB9X-I2.
           DISPLAY "CNATDECINF-AB9X-I2  : " CNATDECINF-AB9X-I2.
           DISPLAY "CNATDECPMT-AB9X-I2  : " CNATDECPMT-AB9X-I2.
           DISPLAY "LNOMUSU-ASU-AB9X-I2 : " LNOMUSU-ASU-AB9X-I2.
           DISPLAY "LFIL-AB9X-01-I2     : " LFIL-AB9X-01-I2.

      * Second MOVE
           MOVE C-AB9X-I1                 TO C-AB9X-I3.

           DISPLAY "NTYPENR-AB9X-I3     : " NTYPENR-AB9X-I3.
           DISPLAY "VGRPTRVEDT-AB9X-I3  : " VGRPTRVEDT-AB9X-I3.
           DISPLAY "VGRPTRVTRI-AB9X-I3  : " VGRPTRVTRI-AB9X-I3.
           DISPLAY "LFIL-AB9X-I3        : " LFIL-AB9X-I3.
           DISPLAY "VDBK-INDASU-AB9X-I3 : " VDBK-INDASU-AB9X-I3.
           DISPLAY "CTRENOM-AB9X-I3     : " CTRENOM-AB9X-I3.
           DISPLAY "CSEXIND-AB9X-I3     : " CSEXIND-AB9X-I3.
           DISPLAY "LNOMIND-AB9X-I3     : " LNOMIND-AB9X-I3.
           DISPLAY "LPREIND-AB9X-I3     : " LPREIND-AB9X-I3.
           DISPLAY "LNOMMAR-AB9X-I3     : " LNOMMAR-AB9X-I3.
           DISPLAY "CNATDECINF-AB9X-I3  : " CNATDECINF-AB9X-I3.
           DISPLAY "CNATDECPMT-AB9X-I3  : " CNATDECPMT-AB9X-I3.
           DISPLAY "LNOMUSU-ASU-AB9X-I3 : " LNOMUSU-ASU-AB9X-I3.
           DISPLAY "LFIL-AB9X-01-I3     : " LFIL-AB9X-01-I3.

      * Troisieme MOVE (avec zone précédente multiple de 4)
           INITIALIZE                        AB9X-GROUPE-MULTIPLE-DE-4.
           MOVE C-AB9X-I1                 TO AB9X-FILLER.
           MOVE AB9X-FILLER               TO C-AB9X-I4-NIV-04.

           DISPLAY "NTYPENR-AB9X-I4     : " NTYPENR-AB9X-I4.
           DISPLAY "VGRPTRVEDT-AB9X-I4  : " VGRPTRVEDT-AB9X-I4.
           DISPLAY "VGRPTRVTRI-AB9X-I4  : " VGRPTRVTRI-AB9X-I4.
           DISPLAY "LFIL-AB9X-I4        : " LFIL-AB9X-I4.
           DISPLAY "VDBK-INDASU-AB9X-I4 : " VDBK-INDASU-AB9X-I4.
           DISPLAY "CTRENOM-AB9X-I4     : " CTRENOM-AB9X-I4.
           DISPLAY "CSEXIND-AB9X-I4     : " CSEXIND-AB9X-I4.
           DISPLAY "LNOMIND-AB9X-I4     : " LNOMIND-AB9X-I4.
           DISPLAY "LPREIND-AB9X-I4     : " LPREIND-AB9X-I4.
           DISPLAY "LNOMMAR-AB9X-I4     : " LNOMMAR-AB9X-I4.
           DISPLAY "CNATDECINF-AB9X-I4  : " CNATDECINF-AB9X-I4.
           DISPLAY "CNATDECPMT-AB9X-I4  : " CNATDECPMT-AB9X-I4.
           DISPLAY "LNOMUSU-ASU-AB9X-I4 : " LNOMUSU-ASU-AB9X-I4.
           DISPLAY "LFIL-AB9X-01-I4     : " LFIL-AB9X-01-I4.

      * Quatrième MOVE (avec zone précédente non multiple de 4)
           INITIALIZE                     AB9X-GROUPE-NON-MULTIPLE-DE-4.
           MOVE C-AB9X-I1                 TO AB9X-FILLER-GNMD4.
           MOVE AB9X-FILLER-GNMD4         TO C-AB9X-I5-NIV-04.

           DISPLAY "NTYPENR-AB9X-I5     : " NTYPENR-AB9X-I5.
           DISPLAY "VGRPTRVEDT-AB9X-I5  : " VGRPTRVEDT-AB9X-I5.
           DISPLAY "VGRPTRVTRI-AB9X-I5  : " VGRPTRVTRI-AB9X-I5.
           DISPLAY "LFIL-AB9X-I5        : " LFIL-AB9X-I5.
           DISPLAY "VDBK-INDASU-AB9X-I5 : " VDBK-INDASU-AB9X-I5.
           DISPLAY "CTRENOM-AB9X-I5     : " CTRENOM-AB9X-I5.
           DISPLAY "CSEXIND-AB9X-I5     : " CSEXIND-AB9X-I5.
           DISPLAY "LNOMIND-AB9X-I5     : " LNOMIND-AB9X-I5.
           DISPLAY "LPREIND-AB9X-I5     : " LPREIND-AB9X-I5.
           DISPLAY "LNOMMAR-AB9X-I5     : " LNOMMAR-AB9X-I5.
           DISPLAY "CNATDECINF-AB9X-I5  : " CNATDECINF-AB9X-I5.
           DISPLAY "CNATDECPMT-AB9X-I5  : " CNATDECPMT-AB9X-I5.
           DISPLAY "LNOMUSU-ASU-AB9X-I5 : " LNOMUSU-ASU-AB9X-I5.
           DISPLAY "LFIL-AB9X-01-I5     : " LFIL-AB9X-01-I5.

       PR-888.                                                                                        
           STOP RUN.
           
       PR-999.                                                                            
           EXIT.

dvi24 · 31/08/2012, 14h28

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
NTYPENR-AB9X-I1     : 25
VGRPTRVEDT-AB9X-I1  : 1***
VGRPTRVTRI-AB9X-I1  : 2***
LFIL-AB9X-I1        : FIL
VDBK-INDASU-AB9X-I1 : +0530004408
CTRENOM-AB9X-I1     : 1
CSEXIND-AB9X-I1     : 2
LNOMIND-AB9X-I1     : PLATH                    
LPREIND-AB9X-I1     : SYLVIA              
LNOMMAR-AB9X-I1     : HUGUES                   
CNATDECINF-AB9X-I1  : A
CNATDECPMT-AB9X-I1  : B
LNOMUSU-ASU-AB9X-I1 : SYVY                     
LFIL-AB9X-01-I1     : FILLER-2            

NTYPENR-AB9X-I2     : 25
VGRPTRVEDT-AB9X-I2  : 1***
VGRPTRVTRI-AB9X-I2  : 2***
LFIL-AB9X-I2        : FIL
VDBK-INDASU-AB9X-I2 : +0530004408
CTRENOM-AB9X-I2     : 1
CSEXIND-AB9X-I2     : 2
LNOMIND-AB9X-I2     : PLATH                    
LPREIND-AB9X-I2     : SYLVIA              
LNOMMAR-AB9X-I2     : HUGUES                   
CNATDECINF-AB9X-I2  : A
CNATDECPMT-AB9X-I2  : B
LNOMUSU-ASU-AB9X-I2 : SYVY                     
LFIL-AB9X-01-I2     : FILLER-2            

NTYPENR-AB9X-I3     : 25
VGRPTRVEDT-AB9X-I3  : 1***
VGRPTRVTRI-AB9X-I3  : 2***
LFIL-AB9X-I3        : FIL
VDBK-INDASU-AB9X-I3 : +0530004408
CTRENOM-AB9X-I3     : 1
CSEXIND-AB9X-I3     : 2
LNOMIND-AB9X-I3     : PLATH                    
LPREIND-AB9X-I3     : SYLVIA              
LNOMMAR-AB9X-I3     : HUGUES                   
CNATDECINF-AB9X-I3  : A
CNATDECPMT-AB9X-I3  : B
LNOMUSU-ASU-AB9X-I3 : SYVY                     
LFIL-AB9X-01-I3     : FILLER-2            

NTYPENR-AB9X-I4     : 25
VGRPTRVEDT-AB9X-I4  : 1***
VGRPTRVTRI-AB9X-I4  : 2***
LFIL-AB9X-I4        : FIL
VDBK-INDASU-AB9X-I4 : +0530004408
CTRENOM-AB9X-I4     : 1
CSEXIND-AB9X-I4     : 2
LNOMIND-AB9X-I4     : PLATH                    
LPREIND-AB9X-I4     : SYLVIA              
LNOMMAR-AB9X-I4     : HUGUES                   
CNATDECINF-AB9X-I4  : A
CNATDECPMT-AB9X-I4  : B
LNOMUSU-ASU-AB9X-I4 : SYVY                     
LFIL-AB9X-01-I4     : FILLER-2            

NTYPENR-AB9X-I5     : 25
VGRPTRVEDT-AB9X-I5  : 1***
VGRPTRVTRI-AB9X-I5  : 2***
LFIL-AB9X-I5        : FIL
VDBK-INDASU-AB9X-I5 : -1757824975
CTRENOM-AB9X-I5     : 2
CSEXIND-AB9X-I5     : P
LNOMIND-AB9X-I5     : LATH                    S
LPREIND-AB9X-I5     : YLVIA              H
LNOMMAR-AB9X-I5     : UGUES                   A
CNATDECINF-AB9X-I5  : B
CNATDECPMT-AB9X-I5  : S
LNOMUSU-ASU-AB9X-I5 : YVY                     F
LFIL-AB9X-01-I5     : ILLER-2

28/08/2012, 07h39	#1
dvi24 Invité régulier Inscription : septembre 2007 Messages : 38 Détails du profil Informations forums : Inscription : septembre 2007 Messages : 38 Points : 6 Points : 6	Utilisation d'une rubrique en COMP-5 SYNC Bonjour Lors d'une lecture en parallèle de deux fichiers, je me heurte au problème suivant : - les enregistrements contiennent une rubrique de format S9(9) COMP-5 SYNC - lors de la comparaison rubrique par rubrique de tout l'enregistrement, je détecte des écarts sur celles se trouvant après la rubrique en COMP-5 SYNC - ces écarts ne sont pas des écarts réels : ils proviennent uniquement d'un décalage de deux caractères, comme si la rubrique en COMP-5 SYNC ne faisait pas systématiquement la longueur qu'elle est censée faire. Exemple d'enregistrement : 01 GROUPE. 05 RUB-1 PIC X. 05 RUB-2 PIC X(4). 05 RUB-3 PIC X(4). 05 RUB-4 PIC S9(9) COMP-5 SYNC. 05 RUB-5 PIC X(2). 05 RUB-6 PIC X(2). RUB-5 et RUB-6 apparaissent toujours en écart entre "source" et "cible" car le COMP-5 SYNC semble générer un décalage de deux caractères à la lecture du second fichier. Avez-vous déjà rencontré ce type de problème ? Merci par avance pour les informations que vous pourrez me transmettre. Dvi =============================================== Précisions : en utilisant un outil de visualisation du contenu du fichier, il apparaît que la valeur de la rubrique en COMP-5 SYNC est rgulièrement la même dans les deux fichiers. Ce serait donc la manipulation de cette donnée dans le programme qui entraînerait ce décalage. Principe : - lecture des deux fichiers en positionnant une clé de comparaison en début d'enregistrement (nouvel enregistrement = clé + zone banalisée contenant l'enregistrement d'origine) - lecture en parallèle des deux fichiers triés avec comparaison des clés créées précédemment puis, sur clés identiques, bascule de la zone banalisée vers la zone standard correspondant à l'enregistrement et comparaison rubrique par rubrique (c'est dans cette dernière étape que le décalage apparaît) ===============================================
	00

28/08/2012, 10h52	#2
dvi24 Invité régulier Inscription : septembre 2007 Messages : 38 Détails du profil Informations forums : Inscription : septembre 2007 Messages : 38 Points : 6 Points : 6	Evolution réalisée En travaillant en "zone à zone" plutôt qu'au niveau groupe (lors de l'alimentation de la rubrique puis de sa re-lecture), je ne rencontre plus le problème de décalage. La solution semble trouvée mais je suis malgré tout preneur d'une explication "officielle" : - est-ce que le fait de mouvementer un groupe de niveau 05 vers un autre groupe de niveau 10 peut modifier la synchronisation réalisée par la rubrique en COMP-5 SYNC ? Merci par avance pour vos remarques. Dvi
	00

29/08/2012, 23h05	#6
dvi24 Invité régulier Inscription : septembre 2007 Messages : 38 Détails du profil Informations forums : Inscription : septembre 2007 Messages : 38 Points : 6 Points : 6	Effectivement, j'ai fait en sorte de ne plus avoir un multiple de quatre avant le groupe AB9X et le décalage est apparu. Je posterai le mini-prog et le résultat au plus tôt, pour permettre à ce que ça intéresse d'imager ma question. Par contre, je n'arrive pas à avoir un résultat de compil dans lequel apparaissent les fameux filler ajoutés ... Faut-il une option de compil particulière ?
	00

Outils de la discussion
Afficher une version imprimable Envoyer un lien vers cette page par email