[XL-2003] Répéter une macro, réaliser une boucle [Résolu]

[zazrun]

Bonjour,

Je souhaiterai répéter une macro toute simple sur plusieurs lignes. Voici la macro en question :

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
Sub Impress_oui()
 
If Not IsEmpty(Range("b5")) Then
Range("a5") = "oui"
Else
Range("a5") = ""
End If
 
If Not IsEmpty(Range("b6")) Then
Range("a6") = "oui"
Else
Range("a6") = ""
End If
 
....
 
If Not IsEmpty(Range("b50")) Then
Range("a50") = "oui"
Else
Range("a50") = ""
End If
 
End Sub

Je voudrai faire la même chose pour les cellules b7 et a7... et cela jusqu'à la ligne 50. Comment le faire en évitant de taper 50 fois le même code ? Merci d'avance pour votre aide.

Xavier.

[tedo01]

Bonjour,

Voici une proposition de boucle :

Code :

1
2
3
4
5
6
7
8
9
10
 
Dim intLigne as Integer
 
For intLigne = 5 to 50
    If Not IsEmpty(Range("b" & intLigne)) Then
        Range("a" & intLigne) = "oui"
    Else
        Range("a" & intLigne) = ""
    End If
Next intLigne

[casefayere]

Bonjour,

autre façon (histoire d'apprendre) :
Sub essai()

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
Dim derlg As Integer, plage As Range, cel As Range
 
derlg = Range("B" & Rows.Count).End(xlUp).Row
Set plage = Range("b5:b" & derlg)
For Each cel In plage
  If Not IsEmpty(cel) Then
    cel(1, 0) = "oui"
  Else
    cel(1, 0) = ""
    End If
Next cel
 
End Sub

[patricktoulon]

bonjour

et dans son plus simple apareil

Code :

1
2
3
4
5
6
7
8
9
10
 
Sub truc()
dim i as long
For i = 5 To 50
If Cells(i, "b") <> "" Then
Cells(i, "b").Offset(0, -1) = "oui"
Else: Cells(i, "b").Offset(0, -1) = ""
End If
Next
End Sub

que dije!!! encore plus simple puisque l'on connais les limites basse et haute (de 5 a 50)nous n'avons pas besoins de connaitre plus de données

Code :

1
2
3
4
5
6
7
8
 
Sub truc()
Dim i As Long
For i = 5 To 50
'si la cellule ligne i "b" est différente de rien  alors 
If Cells(i, "b") <> "" Then Cells(i, "a") = "oui" 'on ne continuera pas la condition avec "else" puisque la condition est basée sur la présence de quelque chose dans la cellule ou pas 
Next
End Sub

au plaisir

[tedo01]

Bonjour,
Attention au dérapage, Patrick

If Cells(i, "b") <> "" Then Cells(i, "a") = "oui" 'on ne continuera pas la condition avec "else" puisque la condition est basée sur la présence de quelque chose dans la cellule ou pas

On remplit la cellule en colonne A par rapport à la présence de quelquechose dans la colonne B... donc il faut maintenir Cells(i, "a") = "" si la colonne B est vide.

[patricktoulon]

Envoyé par tedo01

Bonjour,
Attention au dérapage, Patrick

On remplit la cellule en colonne A par rapport à la présence de quelque chose dans la colonne B... donc il faut maintenir Cells(i, "a") = "" si la colonne B est vide.

je n'ai pas insisté sur ce point car j'ai penser que remplacer quelque chose dans la cellule en colonne "a" par rien était dangereux car la condition de base est basé sur rien en colonne b donc si il n'y a rien en colonne b mais qu'il y a quelque chose en colonne "a" il ne veut peut être pas l'enlever

Dérappage controlé j'adore drifter
au plaisir