[ODS] PROC REPORT : Mise en forme des résultats [Résolu]

[foxrol]

Bonjour j'ai un petit problème de mise en forme et j'espères que vous allez m'aider à le résourder.
En effet (voir fichier joint), j'ai une table issue d'un proc report avec le code ci-dessous:

Code sas :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
 
proc report DATA=TABLE.Ref_pdtcode1 split="~"  missing;
	COLUMN Famcat GROUPE SOUS_GROUPE FAMSTAT pdtcode Bestp  Sales_&an. Evol_sales nb_cust_&an. Evol_cust qty_&an. Evol_qty Margin_&an. Evol_margin  Sales_&an1. nb_cust_&an1. qty_&an1. Margin_&an1. ;
	define Famcat 		/ 'FAMCAT' GROUP ORDER LEFT style(COLUMN)=&style_column_famcat. style(header)=&style_header_famcat.;
	define GROUPE 		/  GROUP ORDER RIGHT style(COLUMN)=&style_column_famcat. style(header)=&style_header_famcat.;
	define SOUS_GROUPE 	/  GROUP ORDER RIGHT style(COLUMN)=&style_column_famcat. style(header)=&style_header_famcat.;
	define FAMSTAT 		/  GROUP ORDER RIGHT style(COLUMN)=&style_column_famcat. style(header)=&style_header_famcat.;
	define pdtcode 		/ 'No.' GROUP ORDER LEFT style(COLUMN)=&style_column_famcat. style(header)=&style_header_famcat.;
	define Bestp 		/ 'BP' GROUP ORDER RIGHT style(COLUMN)=&style_column_famcat. style(header)=&style_header_famcat.;
	define Sales_&an. 	/ 'Sales Y' analysis sum  style(COLUMN)=&style_sales. style(header)=&style_header_famcat.;
	define Evol_sales 	/ 'Evol.Sales' computed  style(COLUMN)=&style_column_famcat. style(header)=&style_header_famcat.;
	define nb_cust_&an. / 'Cust Y'   style(COLUMN)=&style_cust. style(header)=&style_header_var.;
	define Evol_cust 	/ 'Evol.Cust' computed style(COLUMN)=&style_cust. style(header)=&style_header_var.;
	define qty_&an. 	/ 'Qty Y' analysis sum  style(COLUMN)=&style_cust. style(header)=&style_header_famcat.;
	define Evol_qty 	/ 'Evol Qty' computed  style(COLUMN)=&style_column_famcat. style(header)=&style_header_famcat.;
	define Margin_&an. 	/ 'Gros Margin ~ Y' analysis sum  style(COLUMN)=&style_sales. style(header)=&style_header_famcat.;
	define Sales_&an1. 	/ 'Sales Y-1' analysis sum  style(COLUMN)=&style_sales. style(header)=&style_header_famcat.;
	define nb_cust_&an1./ 'Cust Y-1' style(COLUMN)=&style_cust. style(header)=&style_header_var.;
	define qty_&an1. 	/ 'Qty Y-1' analysis sum style(COLUMN)=&style_cust. style(header)=&style_header_var.;
	define Margin_&an1. / 'Gros Margin ~ Y-1' analysis sum style(COLUMN)=&style_sales. style(header)=&style_header_var.;
	break after FAMSTAT /ol skip summarize;
run;

Mon problème se situe donc au niveau du:

Code sas :

1
2
 
break after FAMSTAT /ol skip summarize;

, je voudrais avoir la somme sur la colonne Sales Y mais pas sur la colonne Cust Y(je voudrais en fait qu'elle soit vide), je ne l'ai pourtant pas définie en analysis sum comme les autres et pourtant la somme est tout de même effectuée.

Merci pour votre aide.

[olivier.decourt]

Bonjour.
Toutes les variables numériques sont par défaut en rôle ANALYSIS SUM. C'est pour cela que ta colonne "CUST Y" est gérée ainsi, même si tu ne l'indiques pas.
Tu peux ajouter un bloc COMPUTE pour vider les cases que tu ne souhaites pas voir calculées au moment de tes sous-totaux.

Code :

1
2
3
4
5
6
7
8
9
10
11
PROC REPORT DATA=sashelp.class NOWD ;
  COLUMNS age sex weight height ;
  DEFINE age / GROUP ;
  DEFINE sex / GROUP ;
  DEFINE weight / ANALYSIS MEAN ;
  DEFINE height / ANALYSIS MEAN ;
  BREAK AFTER age / SUMMARIZE OL SKIP ;
  COMPUTE AFTER age ;
    height.mean = . ;
  ENDCOMP ;
RUN ;

Bon courage.
Olivier

[foxrol]

Merci Olivier.