[XL-2003] Utilisation fonction SOMMEPROD [Résolu]

[sevy1]

Bonjour
Je voudrais utiliser la fonction sommeprod pour calculer le pourcentage des valeurs dont le TYPE A ET C est inférieur ou égal à 5 et le TYPE B inférieur ou égal à 30 pour l'année 2011. (Le résultat attendu devrait être (3/6=50%), mais je ne sais pas comment joindre ces conditions dans la même formule.
TYPE VALEUR ANNEE
A 5 2011
A 10 2011
A 2 2010
B 31 2011
B 25 2011
C 10 2011
C 2 2011
Merci pour votre aide

[jfontaine]

Bonjour,

Je n'arrive pas à faire le lien entre :

- Tes explications
- Les données en exemple
- Le résultat Attendu

3 Lignes avec Type A et C sont inférieur ou égal à 5
1 Ligne avec Type B est inférieur ou égal à 30

Comment peux t'on avoir un résultat de 3/6

[gFZT82]

Bonjour,

J’ai placé tes données dans la plage A1:C8 (avec en-tête).

En détaillant les conditions :

Nombre de TYPE A inférieur ou égal à 5 pour l'année 2011.

Code :

=SOMMEPROD((A2:A8="A")*(B2:B8<=5)*(C2:C8=2011))

Nombre de TYPE C inférieur ou égal à 5 pour l'année 2011.

Code :

=SOMMEPROD((A2:A8="C")*(B2:B8<=5)*(C2:C8=2011))

Nombre de TYPE B inférieur ou égal à 30 pour l'année 2011.

Code :

=SOMMEPROD((A2:A8="B")*(B2:B8<=30)*(C2:C8=2011))

Nombre de TYPE pour l'année 2011.

Code :

=SOMMEPROD((C2:C8=2011)*1)

Et en regroupant ces conditions :

Code :

=SOMMEPROD((((A2:A8="A")+(A2:A8="C"))*(B2:B8<=5)+((A2:A8="B")*(B2:B8<=30)))*(C2:C8=2011))/SOMMEPROD((C2:C8=2011)*1)

Cordialement.

[sevy1]

Bonjour
Merci ça marche