[XL-2010] Somme conditionnelle ne fonctionne pas

[superloupiot]

Bonjour,

J'ai attaché un fichier excel dans lequel on trouve l'exemple que je n'arrive pas à faire fonctionner.
Dans la feuille, il y a deux tableaux : Tableau1 et Tableau2
Dans le Tableau2, je désire réaliser une somme des champs 0% à 21% du Tableau 1 si les imputations correspondent.
J'utilise donc la formule : =SOMME.SI(Tableau1[Imputation];[@Imputation];Tableau1[[0%]:[21%]])
Je constate qu'excel ne somme que les valeur du champ [0%] (voir fichier Excel attaché).
Je ne comprend pas pourquoi il ne somme pas les valeurs des champs de [0%] à [21%]?

[grard]

Bonjour,

Essaie avec:

Code :

=SOMMEPROD((E7:E10=D14)*(F7:I10))

Cordialement.

[gFZT82]

Bonjour,

Tu peux également utiliser la combinaison des fonctions SOMME et SI sous la forme matricielle (avec CTRL+MAJ+ENTRÉE).

Code :

{=SOMME(SI(Tableau1[Imputation]=Tableau2[[#Cette ligne];[Imputation]];Tableau1[[0%]:[21%]]))}

Cordialement.

[superloupiot]

Envoyé par grard

Bonjour,

Essaie avec:

Code :

=SOMMEPROD((E7:E10=D14)*(F7:I10))

Cordialement.

Merci grard,

Je préfère utiliser les références structurées pour deux raisons:
1) Mon tableau n'a pas un nombre fixe de lignes, en utilisant les références structurées, je ne doit pas m'occuper des indices maximum et minimum.
2) Je trouve que le concept est beau et puisque Excel le supporte, autant essayer de l'utiliser.

[superloupiot]

Envoyé par gFZT82

Bonjour,

Tu peux également utiliser la combinaison des fonctions SOMME et SI sous la forme matricielle (avec CTRL+MAJ+ENTRÉE).

Code :

{=SOMME(SI(Tableau1[Imputation]=Tableau2[[#Cette ligne];[Imputation]];Tableau1[[0%]:[21%]]))}

Cordialement.

Salut gFZT82,

Je ne connaissais pas ce concept de forme matricielle.
J'ai essayé ce que tu proposes et cela fonctionne.

Par contre, j'aimerais tout de même comprendre pourquoi
=SOMME.SI(Tableau1[Imputation];[@Imputation];Tableau1[[0%]:[21%]]) retourne la somme des valeurs dans le champ [0%] uniquement alors que
=SOMME(Tableau1[[0%]:[21%]]) retourne bien la somme des valeurs des champs compris entre [0%] et [21%] et que
=SOMME.SI.ENS(Tableau1[[0%]:[21%]];Tableau1[Imputation];[@Imputation]) retourne #VALEUR!

Merci.

[gFZT82]

Bonjour,

Par contre, j'aimerais tout de même comprendre pourquoi
=SOMME.SI(Tableau1[Imputation];[@Imputation];Tableau1[[0%]:[21%]]) retourne la somme des valeurs dans le champ [0%] uniquement

L’aide pour la fonction SOMME.SI , indique : Les cellules effectivement additionnées sont déterminées en utilisant la cellule supérieure gauche de l’argument plage_somme comme cellule de début, puis en incluant les cellules dont la taille et la forme correspondent à l’argument plage.
Cela explique la prise en compte d’une seule colonne dans ton cas.

J'en profite pour te confirmer que la solution de grard avec SOMMEPROD convient tout aussi bien.

Code :

 =SOMMEPROD((Tableau1[Imputation]=Tableau2[[#Cette ligne];[Imputation]])*(Tableau1[[0%]:[21%]]))

Cordialement.