MoveNext ne fonctionne pas ! [Résolu]

[filtep]

Bonsoir à tous,
je suis en train de faire des tests pour utiliser MySQL depuis Excel en VBA
Pour afficher les enregistrements de ma BD (j'en ai mis 5 pour le test):

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
 
Public bd As New ADODB.Connection
Public enr As New ADODB.Recordset
 
 
 
Sub chargement()
 
chaine = "DRIVER={MySQL ODBC 5.1 Driver};SERVER=localhost;DATABASE=connexion_excel;USER='root';PASSWORD='';OPTION=3;"
bd.Open chaine
 
enr.activeConnection = bd
 
li = 16
col = 5
For x = 1 To 5
On Error Resume Next
  With enr
    .Close
    On Error GoTo 0
    .CursorLocation = adUseServer
    .CursorType = adOpenKeyset
    .LockType = adLockOptimistic
 
     .Open "SELECT * FROM table_test"
  End With
 
Cells(li + x, 5) = enr("id")
Cells(li + x, 6) = enr("nom")
Cells(li + x, 7) = enr("prenom")
Cells(li + x, 8) = enr("DN")
Cells(li + x, 9) = enr("commentaire")
 
 
enr.MoveNext
Next
 
bd.Close
 
End Sub

Sauf que le résultat n'est pas OK: ça m'affiche 5 fois de suite le 1er enregistrement !

Ou est l'erreur ?

Merci d'avance pour votre aide.

Philippe

[Daniel.C]

Bonjour,

Tu devrais tester EOF, non ?

[ZebreLoup]

C'est surtout qu'il ne faut pas inclure la requête dans la boucle ! Tu la fais une fois et ensuite tu boucles sur les enregistrements.
Et comme dis Daniel, mieux faire un While en testant EOF, plutôt que penser connaitre à l'avance le nombre d'enregistrements.

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
Sub chargement()
 
chaine = "DRIVER={MySQL ODBC 5.1 Driver};SERVER=localhost;DATABASE=connexion_excel;USER='root';PASSWORD='';OPTION=3;"
bd.Open chaine
 
enr.activeConnection = bd
 
li = 16
col = 5
 
On Error Resume Next
  With enr
    .Close
    On Error GoTo 0
    .CursorLocation = adUseServer
    .CursorType = adOpenKeyset
    .LockType = adLockOptimistic
 
     .Open "SELECT * FROM table_test"
  End With
Do While Not enr.EOF
Cells(li, 5) = enr("id")
Cells(li, 6) = enr("nom")
Cells(li, 7) = enr("prenom")
Cells(li, 8) = enr("DN")
Cells(li, 9) = enr("commentaire")
 
li = li + 1
enr.MoveNext
Loop
 
bd.Close
 
End Sub

là je ne l'ai pas fait, mais pense à déclarer tes variables !

[filtep]

Merci beaucoup pour ces réponses,
ma BD est sur mon PC perso à la maison, là je suis au W
Je teste dès ce soir.

Merci de m'avoir carrément écrit le code

A+
Philippe

[filtep]

J'ai donc testé, ça marche au poil (je n'en doutais pas 1 seconde !)

Merci encore

A+
Philippe