transformer tableau heure en plage horaire

[calyze]

Bonjour à tous,

Voila mon problème :
j'ai un tableau avec des colonnes horaires (de 6h00 à 23h00 / par demi-heure).
il est rempli avec une valeur (0,5) pour la présence d'un employé et rien si pas là.
ce tableau me permet de calculer le nombre d'heure par jour.

ce tableau est rempli pour 7 personnes, et sur 7 semaines.

je souhaiterais faire un récapitulatif et avoir pour chaque employé l'affichage de ses plages horaires (genre 8h00 à 17h30).

exemple vendredi 13 janvier
6h 6h30 7h 7h30 8h 8h30 9h 9h30 10h 10h30 11h 11h30 12h .... total
0,5 0,5 0,5 0,5 0 0 0 0 0,5 0,5 0,5 0,5 ....4 heures

je voudrais implémenter automatiquement :
vendredi 13 janvier 6h / 8h et 10h/12h

est-ce possible et si oui comment.
je me prends la tête dessus depuis quelques jours et je tourne en rond.

merci par avance

[mercatog]

Je suppose que ton tableau initial est en feuille DATA en A1:AIxx avec colonne 1: nom des personnes et ligne 1: heures de début (xx étant le nombres de lignes du tableau)

Le résultat est copiée en feuille RESULTAT

Code à adapter

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
Sub Cumul()
Dim j As Integer, Compt As Integer, S As Integer
Dim Tb As Variant, Res As Variant
Dim LastLig As Long, i As Long
Dim Str As String
Dim R As Boolean
 
Application.ScreenUpdating = False
With Worksheets("DATA")
    LastLig = .Cells(.Rows.Count, "A").End(xlUp).Row
    Tb = .Range("B1:AI" & LastLig)
    Res = .Range("A2:C" & LastLig)
    For i = 2 To LastLig
        For j = 1 To 34
            If Tb(i, j) <> "" And Not R Then
                R = True
                Str = IIf(Str = "", "", Str & " | ") & Format(Tb(1, j), "hh:mm")
                Compt = j
            ElseIf Tb(i, j) = "" And R Then
                R = False
                Str = Str & "-" & Format(Tb(1, j), "hh:mm")
                Compt = j - Compt
                S = S + Compt
            End If
        Next j
        Res(i - 1, 2) = Str
        Str = ""
        Res(i - 1, 3) = S / 2
        S = 0
    Next i
End With
Worksheets("RESULTAT").Range("A2").Resize(LastLig - 1, 3) = Res
End Sub

[jfontaine]

Bonjour,

Une solution en créant une fonction personnalisée

A mettre dans un module

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
Function HTravail(Plage As Range, Titre As Range) As String
 
Dim str As String
Dim Rg As Range
Dim bol As Boolean
 
bol = False
 
For Each Rg In Plage
    If Rg.Value = 0.5 And bol = False Then
        If str <> "" Then str = str & " / "
        str = str & Titre(1, Rg.Column).Value
        bol = True
    End If
 
    If Rg.Value = 0 And bol = True Then
        str = str & "-" & Titre(1, Rg.Column).Value
        bol = False
    End If
Next Rg
 
HTravail = str
 
End Function

Puis a appeler comme suit dans la feuille

Code :

=HTravail(A2:M2;A1:M1)

[calyze]

Merci tout d'abord de prendre du temps pour mon problème

Je vais essayer d'être plus clair

Jour X employé Y

C1=6h
D1=6h30
E1=7h
F1=7h30
G1=8h
H1=8h30
I1=9h
J1=9h30
...
AL1=total

ligne2
les valeurs sont entrées manuellement :
0,5 inscrit lorsque l'employé est présent
exemple :
C2=0,5
D2=0,5
E2=0,5
F2=
G2=
H2=0,5
I2=0,5
J2=0,5
...
AL2=3

ce que je souhaiterais, c'est l'affichage automatique du résultat suivant :

jour X employé Y : 6h-7h et 8h30-9h30

A savoir que je suis une novice qui sait travailler sur les formules mais pas les macro ou module.

Merci

[jfontaine]

A part les adresses de la formule proposée qui changent, le reste est toujours valable.

Code :

=HTravail(C2:AK2;C1:AK1)

Si tu bloques sur la mise en place, dis nous où?

[calyze]

C'est nickel exactement ce que je voulais.

mille fois merci pour ton aide précieuse.

Re-bonjour,

j'ai un autre problème, la formule marche parfaitement dans un fichier ou il y a qu'une seule feuille.

j'ai essayé de l'intégrer à un autre fichier où il existe déjà d'autre feuille et module et là j'ai un problème :

il me dit que le nom de la formule n'est pas valide.

pourtant j'ai fait la même chose, créé un module dans vb.