Nom de fichier en fonction des fichiers déjà existants [Résolu]

[glc29]

Bonjour à tous,

Je souhaite savoir s'il est possible de créer, à partir d'une macro dans une feuille excel, un fichier Word dont le nom est une incrémentation des noms de fichiers déjà présent dans le repertoire d'enregistrement.

Mon idée est de créer une macro sous excel. Quand on clique sur un bouton du userform, on donne l'instruction d'ouvrir un Modèle Word préparamétré (.dotx).
Là, je vois bien une macro Word qui défini le nom du nouveau document et qui l'enregistre au bon endroit (toujours le même)
Le modèle word s'enregistrera alors automatiquement sous le nom KMiii-XXXX, avec iii un nombre et XXX l'année de création.

Le nombre iii doit être en fonction du dernier nombre apparut dans le repertoir d'enregistrement.
Par exemple, si le répertoire contient
KM001-2012
KM002-2012
KM003-2012

alors le fichier à créer sera enregistré sous le nom KM004-2012

Encore plus difficile : il faudrait que le fichier Excel récupère le chemin d'accès du fichier word qui vient d'être créé !

Pouvez-vous me dire si c'est faisable, et si oui pouvez vous m'aiguiller sur le code associé?

Merci d'avance

[mercatog]

Voici un début de réponse avec une fonction qui donne le nom de fichier disponible dans un répertoire.
Le fichier cherché et sous forme de PréfixeXXX-YYYY.docx

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
'Str: Préfixe
'Chemin: Chemin du réprtoire où chercher
Function NomFich(ByVal Str As String, Chemin As String) As String
Dim i As Integer
Dim Fichier As String
 
Do
    i = i + 1
    Fichier = Str & Format(i, "000") & "-" & Format(Date, "yyyy")
    If Dir(Chemin & Fichier & ".docx") = "" Then Exit Do
Loop
NomFich = Fichier
End Function

Exemple d'utilisation

Code :

1
2
3
4
5
6
 
 
Sub Test()
 
Msgbox NomFich("KM", "C:\Users\user\Desktop\")
End Sub

[glc29]

Merci mercatog pour ta réponse rapide !

Cependant, lorsque j'envoie ce code, la msgbox me renvoie systématiquement KM001-2012
Saurais-tu pourquoi?

[bbil]

ben il existe ce fichier "KM001-2012.docx" ?

[glc29]

Si le repertoire comporte
KM001-2012.docx
KM002-2012.docx
KM003-2012.docx
KM004-2012.docx
la macro devrait renvoyer KM005-2012

Or ici il me renvoie KM001-2012

ça marche chez vous? C'est peut-être moi qui ai mal nommé mes fichiers, mais ça n'a pas l'air d'etre ça.

[mercatog]

As tu adapté le chemin?
"C:\Users\user\Desktop\"

[glc29]

Désolé, j'avais oublié un \ à la fin de mon chemin !

Merci beaucoup.

Donc on a une partie du code OK.

Maintenant pourriez vous m'aiguiller sur la façon de récupérer le nom du docx (qu'on vient de créer) vers la macro d'excel ?

J'avais dans l'idée de récupérer l'adresse du docx en cours (c'est à dire celui dont la page est ouverte). On peut faire ça, ou y-a-t-il plus simple?

[mercatog]

Il faudra être précis: Tu veux piloter Word à partir d'Excel.
Les codes sont dans Excel seulement ou aussi dans ton document Word.

[glc29]

J'utilise en tache principale un fichier excel, qui gere de nombreux documents.
Sur ce fichier, j'ai une macro avec une userform qui comportera un bouton "Nouveau Rapport". Je souhaite que quand l'utilisateur appuie sur Nouveau Rapport, un nouveau document word apparaisse, paramétré par un modèle de document.
Grace au code que tu viens de me donner, je pourrai écrire un code pour enregistrer automatiquement ce nouveau rapport avec le bon nom (incrémenté).

C'est ce nom (et son chemin) que je veux récupérer dans mon fichier excel, afin de pouvoir renseigner ma pseudo base de données sur la création de ce nouveau document, devant lequel on pourra mettre des informations à propos du document (observations, sujet, validité, etc...)

En fin de compte, chaque ligne de la feuille excel comportera un lien vers un document, en regard desquels seront indiquées de nombreuses informations.

Je sais, c'est pas vraiment claire, donc n'hésites pas à me demander plus de détails.

[bbil]

Montre nous le code que tu utilise pour créer ton fichier word.

[mercatog]

Exemple d'ouverture et d'enregistrement de document Word à partir d'Excel

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
Sub GenerationDoc()
Dim Model As String, Rep As String, NouvNom As String
Dim App As Object, Doc As Object
Dim NewLig As Long
 
 
Application.ScreenUpdating = False
Model = "C:\Users\user\Desktop\MonmodèleWord.dotx"    'Rep complet du model word
Rep = "C:\Users\user\Desktop\ESSAI\"          'Répertoire des fichiers word
 
Set App = CreateObject("Word.Application")
App.Visible = True
Set Doc = App.Documents.Open(Filename:=Model)
 
'Travail avec Doc: le document word ouvert à partir du modèle
'....
 
NouvNom = NomFich("KM", Rep)
Doc.SaveAs2 Filename:=Rep & NouvNom, FileFormat:=12
Doc.Close
Set Doc = Nothing
App.Quit
Set App = Nothing
 
'ici on enregistre en Feuil1 les infos sur le fichier Word
With ThisWorkbook.Worksheets("Feuil1")
    NewLig = .Cells(.Rows.Count, "A").End(xlUp).Row + 1
 
    .Range("A" & NewLig).Value = NouvNom
    .Range("B" & NewLig).Value = Date
    .Hyperlinks.Add Anchor:=.Range("C" & NewLig), Address:=Rep & NouvNom & ".docx", TextToDisplay:="Lien vers fichier " & NouvNom 'création de lien hypertexte vers le fichier
    '.....
    'Autres infos
End With
End Sub
 
 
'Str: Préfixe
'Chemin: Chemin du réprtoire où chercher
Function NomFich(ByVal Str As String, Chemin As String) As String
Dim i As Integer
Dim Fichier As String
 
If Right(Chemin, 1) <> "\" Then Chemin = Chemin & "\"
Do
    i = i + 1
    Fichier = Str & Format(i, "000") & "-" & Format(Date, "yyyy")
    If Dir(Chemin & Fichier & ".docx") = "" Then Exit Do
Loop
NomFich = Fichier
End Function

[glc29]

ça marche très bien !

Merci beaucoup mercatog !