Fréquence de valeurs manquantes [Résolu]

[traersa]

voila mon probleme me semble simple est pourtant je n'y arrive pas, j'ai une table avec 350 variables et j'aimerai donc afin d'evaluer la qualité de la sasie le pourcentage de valeurs manquantes pour chacune de mes variables. j'ai donc essayé avec une proc tabulate,

Le resultat que je voudrais aurait cette forme :
Fréquence de réponse manquante
variable1 X%
Variable2 Y%


J'ai donc f'ait ceci mais comme vous vous en doutez ca ne marche pas

Code :

1
2
3
4
5
6
7
8
proc tabulate DATA= alz.malchro;
	CLASS ETP_I_UF_ACTIVITE /ORDER=DATA;
	CLASS C_Code_Postal /ORDER=DATA;
	CLASS D_Date_Naissance /ORDER=DATA;
TABLE ETP_I_UF_ACTIVITE 
	C_Code_Postal 
         D_Date_Naissance, n Nmiss;
run;

[frajen]

Bonjour,

Si j'ai bien compris ta question, une proc FREQ devrait résoudre ton problème:

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
DATA test;
input x 1-2 y 3-4;
cards;
1 2
3  
4 5
6 7
  8
;run;
 
proc freq DATA=test;
TABLES x y/missing ;
run;

Tu auras pour chaque varaible le pourcentage de chaque modalité et le pourcentage de valeurs manquantes.

Cordialement,
Jérémy NOEL

[traersa]

Bonjour,

Oui c'est ce que j'ai fait en attendant le probleme etant que je sors 1069 pages de rapports car mes modalités sont souvent nombreuses, je ne veux donc pas la repartition des modalités qui me prend trop de place, mais simplement les fréquences de valeurs manquantes, mais je sais pas si c'est faisable, peut etre en ajoutant une close a mon freq, je vais continuer a essayer je posterai la reponse si je trouve.

[olivier.decourt]

Bonjour.
La solution de la proc FREQ est sans doute la plus rapide à coder. TABULATE donnera des dénombrements de valeurs manquantes mais pas de pourcentages. REPORT permettrait de calculer les pourcentages mais il faudrait des tonnes de code.
Par contre, un format pour regrouper toutes les valeurs non manquantes en une ligne t'évitera des pages et des pages de listings inutiles.

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
 
PROC FORMAT ;
  VALUE num
   LOW-HIGH="Renseigné" OTHER="Manquant"
  ;
  VALUE $car
   "" = "Manquant" OTHER = "Renseigné"
  ;
RUN ;
proc freq DATA=test;
TABLES x y/missing ;
FORMAT _NUMERIC_ num. _CHARACTER_ $car. ;
run;

[traersa]

Ah oui j'avoue tres mal connaitre les proc format, cette solution marche tres bien pour toutes mes variables quantitatives donc deja un grand merci, par contre elle considere toutes mes variables qualitatives comme toujours renseignées.

[olivier.decourt]

Comment est codée la valeur inconnue sur tes variables qualitatives ? Par le manquant de SAS (chaîne vide) ou par des points d'interrogation, des points simples ?

[traersa]

ben quand j'ouvre la table il n'y a rien d'affiché donc j'aurais tendance a dire chaine vide... C'est pour ca que je comprends pas bien pourquoi ca marche pas.

[olivier.decourt]

Oups. J'ai oublié de laisser un espace entre les guillemets dans la définition du format.

Code :

1
2
3
4
5
6
7
8
PROC FORMAT ;
  VALUE num
   LOW-HIGH="Renseigné" OTHER="Manquant"
  ;
  VALUE $car
   " " = "Manquant" OTHER = "Renseigné"
  ;
RUN ;

[traersa]

Merci beaucoup pour votre aide ca marche tres bien et ca correspond vraiment a ce que je voulais.
Encore un grand merci pour votre aide qui m'evitera d'avoir a envoyer un rapport de plus de mille pages...