[XL-2003] Macro tri et répartition [Résolu]

[korni184]

Bonjour,

Je suis entrain de developper un code qui me permet de faire un tri automatique.

Un sheet nommée travail, oú je colle l'ensemble des lignes est requise.

Sur ces différentes lignes se trouvent des données, qui vont se différencier par la colonne C.

Exemple :

Colonne A : Objet
Colonne B : Quantité
Colonne C : Pays
Colonne D-H : Données

Résultat attendu :

En donnant une combinaison de touche (ctrl+p), je voudrais à l'aide d'un moteur et d'un compteur qu'il détecte le pays en colonne C et qu'il transfère automatiquement cette ligne dans sa sheet correspondante.

En sachant qu'il y a que 6 pays disponible (Chine, Afrique, France, Italie, USA, Espagne, Belgique).

Un tri de départ me permet de ranger toutes les données par pays :

Exemple :

Ligne 1 à 15 : Afrique
Ligne 16 à 22 : France
....

Donc au final, il faudrait qu'il détecte toutes lignes avec pays d'afrique et qu'il les transfère en une seule fois dans la sheet "Afrique".

Pouvez-vous m'aider ?

Merci d'avance

Bien à toi

[jfontaine]

Bonjour,

Ci dessous une proposition de code qui transfert chaque ligne dans la bonne feuille.
En pré-requis il faut que chaque pays soit reconnu par une feuille qui porte le nom du pays

A exécuter avec la feuille de données Active (Activesheet)

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
Sub TransfereDonnees()
 
Dim i As Long
Dim iCible As Long
Dim shSource As Worksheet
Dim Sh As Worksheet
 
Set shSource = ActiveSheet
 
'Copie les données dans les feuilles Pays
For i = 2 To shSource.Range("A" & Rows.Count).End(xlUp).Row
    Set Sh = Sheets(Range("C" & i).Value)
    iCible = Sh.Range("A" & Rows.Count).End(xlUp).Row + 1
    shSource.Rows(i).Copy Sh.Range("A" & iCible)
    'Vide la ligne Copiée
    shSource.Rows(i).ClearContents
Next i
 
End Sub

[korni184]

Je viens d'utiliser votre code :

Dans la colone A j'ai mis des chiffres aléatoires,
Dans la colone B des données aléatoires,
Dans la colonne C les pays suivants : France Italie Roumanie

La 1ère sheet se nomme "Travail"
La 2ème sheet se nomme "France"
La 3ème sheet se nomme "Italie"
La 4ème sheet se nomme "Roumanie"

Lorsque je fais mon "Ctrl+a" il sélectionne toute la sheet "travail" et ne fait aucun traitement.

Pouvez-vous m'aider ?

Merci d'avance

[jfontaine]

Le code proposé fonctionne sur la base de ton premier post.
Si tu changes l'ordre des colonnes en cours de route, modifie le code pour qu'il prenne en considération tes modifications.

pour info, ctrl + a est un raccourci windows pour tout sélectionner, cela ne pourra pas exécuter la macro.

[korni184]

Je viens de changer le ctrl+a par un ctrl+t.

Concernant les changements, il n'y a rien qui puisse modifier le code.

Les pays sont toujours en colonne C, donc que dois-je faire ?

[jfontaine]

Post un fichier exemple

[korni184]

J'ai ajouté des données dans les colonnes (D à H).

Et çà à fonctionné !

Cependant, je voulais à la base mettre les données dans une sheet nommée "travail".

Si je colle les données dans travail, il transfère toutes les lignes, sauf la premières !

Que dois-je faire ?

[jfontaine]

J'ai ajouté des données dans les colonnes (D à H).

Cependant, je voulais à la base mettre les données dans une sheet nommée "travail".

Comme cela

Code :

Set shSource = Sheets("travail")

Si je colle les données dans travail, il transfère toutes les lignes, sauf la premières !

Le code proposé commence ligne 2 (on considère que la ligne contient les en-tètes)

[korni184]

Tout fonctionne à merveille !

Par contre serait-il possible de ne pas partir de A2 ?
Et de les coller directement sur les lignes A de chaque feuilles ?

Je ne veux pas ajouter de titres

[ZebreLoup]

Je pense que si Jérome ne t'a pas fourni tout de suite la réponse, c'est pour que tu lises un peu le code qu'il t'a fourni et que tu essaies de comprendre comment ça marche.
Un indice : Tu veux partir de la première ligne et non de la deuxième, il faut peut-être changer un 2 en 1 quelque part...

[korni184]

Effectivement je me suis mal exprimé,

J'ai déjà effectué cette modification, c'est lorsqu'il vient coller les données dans les différentes sheets qu'il laisse une ligne de libre....

Peut-on modifier cela ?

[ZebreLoup]

Comme tu peux le voir, il te propose un End(xlUp) qui est l'équivalent d'un Ctrl+flèche haut. Auquel il rajoute 1 pour avoir la ligne vide. Il est vrai que la première fois, quand il n'y a aucune donnée, il remonte jusqu'en haut et descends d'une case, tu pourrais faire :

Code :

1
2
iCible = Sh.Range("A" & Rows.Count).End(xlUp).Row + 1
If iCible = 2 And Sh.Range("A1").Value = "" Then iCible = 1

[MarcelG]

Bonjour à tous,

Jérôme,

pour info, ctrl + a est un raccourci windows pour tout sélectionner, cela ne pourra pas exécuter la macro.

Si je ne me trompe, le fait d'affecter à une procédure un raccourci déjà reconnu par Windows donne la priorité à la procédure.

D'autre part, je pense qu'ici une adaptation de ma - modeste - contribution, que je viens de poster, est envisageable.

Alimenter les feuilles d'un classeur depuis une synthèse

[jfontaine]

Salut MarcelG

Si je ne me trompe, le fait d'affecter à une procédure un raccourci déjà reconnu par Windows donne la priorité à la procédure.

Oui, en effet c'est faisable

Je trouve juste pas adéquat l'utilisation d'un raccourci clavier existant pour faire une tache qui n'a rien a voir avec la tache d'origine (surtout pour les utilisateurs qui utilise beaucoup ces raccourcis)

[korni184]

Hello,

Merci pour vos réponses, le forum est vraiment génial.

Je vais revenir avec mon sujet...mais dans une nouvelle discussion.

Un grand merci à vous tous

[korni184]

Bonjour,

Je sais que le sujet est clôturé, d'ailleurs je ne sais même pas si vous allez recevoir mon message :

Concernant ce code, pouvez-vous me donner le maximum d'explications sur son fonctionnement ? Des phrases pour expliquer chaque actions ? Merci d'avance pour ce point.

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
Sub TransfereDonnees()
 
Dim i As Long
Dim iCible As Long
Dim shSource As Worksheet
Dim Sh As Worksheet
 
Set shSource = Sheets("Fiche de Travail J")
 
'Copie les données dans les feuilles Pays
For i = 1 To shSource.Range("A" & Rows.Count).End(xlUp).Row
    Set Sh = Sheets(Range("C" & i).Value)
    iCible = Sh.Range("A" & Rows.Count).End(xlUp).Row + 1
    if iCible = 2 And Sh.Range("a1").value = "" Then iCible = 1
    shSource.Rows(i).Copy Sh.Range("A" & iCible)
    'Vide la ligne Copiée
    shSource.Rows(i).ClearContents
Next i
 
End Sub

Sinon, juste une deuxième question, vu que j'utilise plusieurs fois la Macro dans la même journée, j'ai rajouter à la suite (tri, ajout de totaux, etc) pour chaque sheet.

Donc le problème c'est que si j'ai seulement dans mes données de l'après-midi des données pour le pays Maroc, je voudrais qu'il aille remplacés ce qu'il y a dans la sheet, Non pas les rajouter à la suite !

Est-ce que c'est possible ?

[jfontaine]

Avec les commentaires sur chaque lignes

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
Sub TransfereDonnees()
 
'Déclaration des variables
Dim i As Long
Dim iCible As Long
Dim shSource As Worksheet
Dim Sh As Worksheet
 
'Onglet ou se trouve les données à ventiler
Set shSource = Sheets("Fiche de Travail J")
 
'Copie les données dans les feuilles Pays
 
'Pour chaque ligne non vide de l'onglet source
For i = 1 To shSource.Range("A" & Rows.Count).End(xlUp).Row
    'Instanciation de la variable avec le nom du pays correspondant à la ligne
    Set Sh = Sheets(Range("C" & i).Value)
    'Trouve la prochaine ligne vide sur l'onglet du pays
    iCible = Sh.Range("A" & Rows.Count).End(xlUp).Row + 1
    'Test si onglet vide, alors on ajoute la ligne sur la ligne 1
    If iCible = 2 And Sh.Range("a1").Value = "" Then iCible = 1
    'Copy de la ligne
    shSource.Rows(i).Copy Sh.Range("A" & iCible)
    'Vide la ligne Copiée
    shSource.Rows(i).ClearContents
Next i
 
End Sub

Donc le problème c'est que si j'ai seulement dans mes données de l'après-midi des données pour le pays Maroc, je voudrais qu'il aille remplacés ce qu'il y a dans la sheet, Non pas les rajouter à la suite !

Cela est possible, mais nécessite d'ajouter une date d'ajout sur la feuille pays.

[korni184]

Comment je peux faire pour ajouter une date d'ajout automatiquement lors ce que je colle mes données ?

J'imagine que lorsque j'active ma macro, il ajoute à chaque ligne une date ? Avec l'heure d'ajout ?

Mais comment je peux caractériser cela au niveau de la macro ?

Cependant j'ai mis ceci sur deux sujets, je devrais peut être clôturer définitivement celui ci ?

[jfontaine]

Je pense que pour le suivi il vaut mieux rester sur celui ci

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
Sub TransfereDonnees()
 
'Déclaration des variables
Dim i As Long
Dim iCible As Long
Dim shSource As Worksheet
Dim Sh As Worksheet
 
'Onglet ou se trouve les données à ventiler
Set shSource = Sheets("Fiche de Travail J")
 
'Copie les données dans les feuilles Pays
 
'Pour chaque ligne non vide de l'onglet source
For i = 1 To shSource.Range("A" & Rows.Count).End(xlUp).Row
    'Instanciation de la variable avec le nom du pays correspondant à la ligne
    Set Sh = Sheets(Range("C" & i).Value)
    'Trouve la prochaine ligne vide sur l'onglet du pays
    iCible = Sh.Range("A" & Rows.Count).End(xlUp).Row + 1
    'Test si onglet vide, alors on ajoute la ligne sur la ligne 1
    If iCible = 2 And Sh.Range("a1").Value = "" Then iCible = 1
    'Copy de la ligne
    shSource.Rows(i).Copy Sh.Range("A" & iCible)
    'Ajoute la date
    Sh.Range("D" & iCible).Value = Date
    'Vide la ligne Copiée
    shSource.Rows(i).ClearContents
Next i
 
End Sub

Pour la partie concernant le contrôle si la donnée existe à cette date, qu'elle est la clé d’unicité d'une ligne sachant que le montant ayant été modifié ne peut être dedans? une ligne par jour par pays ?