[AC-2003] Attacher une table [Résolu]

[AndréPe]

Bonjour,
Je souhaite attacher la table "tabTest" qui se trouve dans la base Db1, à partir de la base dt travail (CurrentdDb)

Code :

1
2
3
4
5
6
7
8
9
10
11
On Error GoTo 0
Dim Db As DAO.Database
Set Db = CurrentDb
Dim MaTabDef As TableDef
Set MaTabDef = Db.CreateTableDef("tabTest")
With MaTabDef
    .Connect = ";DATABASE= C:\Db1.mdb"
    .SourceTableName = "tabTest"
End With
 Db.TableDefs.Append MaTabDef
  DoEvents

Ce code bute sur la ligne 10 : nom de fichier incorrect

Où est l'erreur ?
Merci
Amicalement

[RobiPMS]

Bonjour.

Ne faudrait-il pas, à la ligne 4, mettre

Code :

Dim MaTabDef As DAO.TableDef

Cordialement

[AndréPe]

Malheureusement, ça ne change rien !
Merci tout de même de cette suggestion.
A+

[RobiPMS]

Voici le code que j'utilise. J'y ai seulement remplacé les noms de mes bases et table par les vôtres.

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
    Dim strMotPasse As String
    Dim strCheminBd As String
    Dim strNomTable As String
    Dim strConnect As String
    Dim oDb As DAO.Database
    Dim oTbl As DAO.TableDef
  ' Définit mot passe, nom table, chemin base de données
    strMotPasse = ""
    strCheminBd = "C:\Db1.mdb"
  ' Instancie l'objet Database
    Set oDb = CurrentDb
  ' Définit la chaine de connexion permettant la liaison
    strConnect = "MS Access;pwd=" & strMotPasse & ";DATABASE=" & strCheminBd
  ' Crée un lien vers la table 'tabTest' de Db1
    strNomTable = "tabTest"
    Set oTbl = oDb.CreateTableDef(strNomTable)
    With oTbl
        .Connect = strConnect
        .SourceTableName = strNomTable
    End With
  ' Ajoute la table à la base
    oDb.TableDefs.Append oTbl: oDb.TableDefs.Refresh

Si ça peut vous aider...
Bonne soirée.

[AndréPe]

Merci,
Ca fonctionne bien, mais je ne comprends toujours pas ce qui se passe avec mon code, car je l'ai entièrement réécrit tel qu'il était et lui aussi maintenant fonctionne !
Ce qui est l'essentiel, grâce à l'entraide du forum.
Amicalement