[XL-2010] Vérifier classeur ouvert [Résolu]

[tompom3108]

Bonjour à tous et bonne année!

bon je la commence bien j'ai un petit problème avec un bout de code,
je voudrais vérifier qu'un classeur est fermé avant de sauvegarder des données dedans voilà ce que j'ai écrit :

Code :

1
2
3
4
Dim Wdest As Workbook
Set Wdest = Workbooks("CC2011T.xlsx")
If Ouvert(Wdest) Then MsgBox "Attention le classeur d'archivage est ouvert veuillez le fermer pour sauvegarder le devis"
Exit Sub

Manque de pot ça ne marche pas donc vu que c est facile à résoudre pour un pro j'imagine qu'une âme charitable pourra m' aider merci d'avance.!

[MarcelG]

Bonjour,

Le test concerne-t-il l'ouverture dans la même session d'Excel (utilisteur), ou bien une ouverture quelque soit la session (autre utilisateur)?

[tompom3108]

Bonjour,
c'est quelque soit la session (autres utilisateurs)
les classeurs sont en réseaux donc faudrait pas qu'un opérateur du premier
ouvre une session et sauvegarde pendant qu'un autre du second l'utilise...
même s'il ya le message d'excel "ouvrir en lecture seule" j'aimerai quand même un message d'avertissement avant toute sauvegarde.
C compliqué?

[MarcelG]

C compliqué?

Non, avec cette fonction à intégrer dans un module standard.

Code :

1
2
3
4
5
6
7
8
9
10
11
Function FichierEstOuvert(ByRef FichierTeste As Variant) As Boolean
    Dim FICHIER As Long
    On Error GoTo Erreur
    FICHIER = FreeFile
    Open FichierTeste For Input Lock Read As #FICHIER
    Close #FICHIER
    FichierEstOuvert = False
    Exit Function
Erreur:
    FichierEstOuvert = True
End Function

Utilisation :

Code :

1
2
If FichierEstOuvert(FichierTeste) = True Then _
    MsgBox "Désolé, ce fichier est ouvert.", vbOKOnly, "Alerte"

Remarque imortante. Ici, en lieu et place de "FichierTeste", tu dois écrire le chemin complet (répertoire avec "antislash") suivi du nom du classeur et de son extension.

Un modeste conseil. Evite le langage SMS. Ecrire "Est-ce" au lieu de "C" n'est pas bien compliqué.

Reviens si nécessaire.

[tompom3108]

Merci MarcelG pour ta réponse et ton petit avertissement sur mon français peu académique (ma femme et ma mère étant prof de français elles te féliciteraient de ton engagement à l'égard de la nation ).

Cependant, je ne suis pas sûr d'avoir bien écrit la fonction car je n'ai pas de résultat à part le fait qu'il me propose de sauvegarder une copie ce qui n'est pas mon but. voici le bout de code adapté :

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
 Function FichierEstOuvert(ByRef FichierTeste As Variant) As Boolean
 
     Dim FICHIER As Long
    Set FichierTeste = "Z:\Gestion entreprise\VBA\Atest\CC2011T.xlsx"
   On Error GoTo Erreur
   FICHIER = FreeFile
    Open FichierTeste For Input Lock Read As #FICHIER
   Close #FICHIER
   FichierEstOuvert = False
  Exit Function
Erreur:
   FichierEstOuvert = True
End Function

Manque-t-il un je-ne-sais-quoi?

J'aimerai que l'opérateur soit averti par un message que le classeur C2011T est ouvert et que du coup la sauvegarde est annulée.

[Ormonth]

Bonjour,



http://www.developpez.net/forums/d10...oste-instance/

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
Sub Testeur()
Dim wbkAtester As Workbook
Dim strChemin As String
Dim strNom As String
'********************* rajouter pour si macro dans cible : Application.EnableEvents = False / True
strNom = "Fichier a tester.xls"
On Error Resume Next
Set wbkAtester = Workbooks(strNom) 'Si le classeur n'est pas ouvertdans cette instance, on affecte à la variable Objet un objet qui n'existe pas dans l'Application. Le on Error Resume next passe à la lignee suivante, wbkAtester est donc resté à Nothing.
On Error GoTo 0
If wbkAtester Is Nothing Then
    MsgBox "Ce Classeur n'est pas ouvert dans cette instance d'Excel"
Else
    MsgBox "Déjà Ouvert dans cette instance d'Excel!"
    Set wbkAtester = Nothing
    Exit Sub
End If
 
strChemin = "E:\+ Cliparts\"
'strChemin = "\\Toto-PC\Users\Public\Documents\"
Set wbkAtester = Workbooks.Open(strChemin & strNom)
    If wbkAtester.ReadOnly Then
        MsgBox "Déjà Ouvert sur un autre poste ou dans une autre instance"
        wbkAtester.Close
    Else
        MsgBox "Ce Classeur n'est pas ouvert sur un autre poste ou dans une autre instance !"
        wbkAtester.Close 'ligne à activer ou non selon le test voulu classeur reste ouvert ou non
    End If
End Sub

Cordialement,

Ps : si le côté technique de la réponse = OK ou pas => pensez à cliquer sur les pouces et quand question résolue à la taguer résolue, et chaque action vous rapporte des points

Didier

[tompom3108]

Merci pour ta réponse Ormonth et désolé j'avais fait une recherche qui ne m'a pas amené sur ton lien ou alors elle a du m'échapper.

Ps: Le langage SMS est définitivement banni de ma pratique du clavier. (Sans quoi je sens que je serai brûlé ...)

[MarcelG]

Salut Didier,

Sinon, en ce qui concerne la version que j'utilise.

Le code de la fonction doit rester intact.

C'est dans la procédure Sub faisant appel à elle qu'il faut informer le chemin complet.

Code :

If FichierEstOuvert(chemincomplet\nomdufichier.extension) Then

Cette information sera l'argument de ta fonction.

Bon week-end à tous.

[tompom3108]

D'accord MarcelG et merci pour tes réponses