[PPT-2007] Combox imbriqués dépendants [Résolu]

[LeSkwal]

Bonjour le forum

Voilà ma demande.

Soit un premier combox incluant 2 académies (Créteil, Versailles) et un deuxième; les départements.

Quand je sélectionne Versailles je souhaite voir apparaitre dans le deuxième combox les départements, 78, 92, 95, 91 et quand je sélectionne Créteil, je souhaite voir apparaitre dans le deuxième combox les départements, 93, 94, 77.

En fonction de cela en validant je vais sur les diapositives concernées.

Espérant avoir été clair.

Très cordialement et merci d'avance pour vos réponses.

Joyeux Noël

Pascal

[Philippe JOCHMANS]

Bonjour

J'imagine que c'est dans une diapositive que tu as ces combobox, est-ce le cas ?

Pour les départements, donc la deuxième combobox, y a-t-il une diapositive par département ?

Philippe

[LeSkwal]

Bonjour,
désolé de n'avoir pu te répondre plus rapidement.
En effet, les 2 combox se trouvent sur une même diapo et pour chaque département correspondra
une diapo.
Très bonne journée et... pas trop d'excès ...

Pascal

[Philippe JOCHMANS]

Bonjour

Désolé pour le retard, planning chargé.

Personnellement je n'aime pas les contrôles dans les Diapositives, ils ont un comportement bizarre, je préfère passer par un UserForm.

En pièce jointe une présentation à compléter.

Un userform avec deux listes (cboAcademie et cboDepartement) avec le code suivant :

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
Option Explicit
 
Private Sub cboAcademie_DropButtonClick()
    ' on rempli la liste des académies
    If Me.cboAcademie.ListCount = 0 Then
        With Me.cboAcademie
            .AddItem "Créteil"
            .AddItem "Versailles"
        End With
    End If
 
End Sub
Private Sub cboDepartement_Change()
      ' affichage de la diapositive après la sélection
    Select Case Me.cboDepartement.Value
        Case "93"
            Application.SlideShowWindows(1).View.GotoSlide 2
        Case "94"
            Application.SlideShowWindows(1).View.GotoSlide 3
        Case Else
    End Select
 
    Call Fermeture
End Sub
 
Private Sub cboDepartement_Enter()
     ' affiche des départements en fonction de l'académie
    ' on vide la liste
    Me.cboDepartement.Clear
 
    ' contrôle de sélection de l'académie
    If Me.cboAcademie.Value = "" Then
        MsgBox "Vous devez sélectionner une académie."
        Exit Sub
    End If
 
    ' remplissage de la liste en fonction de l'académie
    Select Case Me.cboAcademie.Value
        Case "Créteil"
           With Me.cboDepartement
                .AddItem "93"
                .AddItem "94"
                .AddItem "77"
            End With
        Case "Versailles"
            With Me.cboDepartement
                .AddItem "78"
                .AddItem "91"
                .AddItem "92"
                .AddItem "95"
            End With
    End Select
End Sub
 
 
Public Sub Fermeture()
    Unload Me
End Sub

Une forme sur la première slide qui lance cette routine :

Code :

1
2
3
Public Sub AffichageUserForm()
    UserForm1.Show vbModeless
End Sub

Tout est dans le zip, a compléter.

Philippe

[LeSkwal]

Un grand MERCI

J'essaie cela.

Cordialement

Pascal

[LeSkwal]

Impeccable, ça marche.

ReMERCI et Joyeuses fêtes

Pascal