[XL-2007] Copier des données d'une feuille vers une autre feuille [Résolu]

[chris09300]

Bonsoir
je souhaiterais copier des donnees d'une feuille(masia) vers une feuille (AR_Base).
je voudrais lister les valeurs dans la colonne A qui va de A1 a A.....
Chaque fois qu'une des valeurs se trouvent dans la feuille(AR-Base) dans la colonne U copier les valeurs des colonnes suivantes dans la feuille (AR_Base) fichier ci joint
cris
---------------------------------
Fichier joint dans vos discussions
-----------------------------------

[mercatog]

Essaies quelque chose comme ceci

Code :

1
2
3
4
5
6
7
8
9
10
11
Dim Code As String
Dim c As Range
 
Code = Me.combobox1.Value
If Code <> "" Then
    Set c = Worksheets("MASIA").Range("A:A").Find(Code, LookIn:=xlavlues, lookat:=xlWhole)
    If Not c Is Nothing Then
        Worksheets("AR-Base").Range("V" & Me.combobox1.ListIndex + 3).Resize(1, 4) = c.Offset(0, 1).Resize(1, 4)
        Set c = Nothing
    End If
End If

[chris09300]

excuse moi mercatog,je me suis un peu embrouille dans ma premiere demande.
j'ai donc modifie mon post.
fichier joint
merci
cris

[mercatog]

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
Sub Remplissage()
Dim c As Range, v As Range
 
Application.ScreenUpdating = False
With Worksheets("AR-Base")
    'On parcour les cellules de la colonne U de la feuille AR-Base
    For Each v In .Range("U3:U" & .Cells(.Rows.Count, "U").End(xlUp).Row)
        'Si la cellule v n'est pas vide
        If v.Value <> "" Then
            'on recherche la cellule dans la colonne A de la feuille MASIA
            Set c = Worksheets("MASIA").Range("A:A").Find(v.Value, LookIn:=xlValues, lookat:=xlWhole)
            'Si on trouve la cellule c, on transfère les valeurs des 4 cellules à droite de v vers les 4 cellules à droite de v
            If Not c Is Nothing Then
                v.Offset(0, 1).Resize(1, 4).Value = c.Offset(0, 1).Resize(1, 4).Value
                Set c = Nothing
                'Si on ne trouve pas de cellule c, On efface les 4 cellules à droite de v
            Else
                v.Offset(0, 1).Resize(1, 4).ClearContents
            End If
        End If
    Next v
End With
End Sub

[chris09300]

merci mercatog
tu est un as.
cris