[XL-2007] Problème avec Evaluate [Résolu]

[issoram]

Bonsoir,

Je n'arrive pas à faire fonctionner la fonction Evaluate avec la fonction Array:
Pour simplifier cela se résume à l'exemple si dessous:

Code :

1
2
3
Dim temp As Variant
temp = Evaluate("Array(1,2)")
Debug.Print UBound(temp)

J'obtiens l'erreur 2029 et l'aide microsoft sur ce type d'erreur ne correspond pas à mon problème.

Merci d'avance de votre aide.

[jfontaine]

Bonjour,

Utiliser evaluate comme cela
je ne pense pas que ce soit possible.

Quel est la finalité de ton code?

Peut être quelque chose comme cela

Code :

1
2
3
4
5
6
7
8
Dim Temp() As String
Dim str As String
 
str = "10,20,30"
 
Temp = Split(str, ",")
 
MsgBox Temp(2)

[issoram]

Merci de ta réponse jfontaine,

Effectivement je me prends tellement le chou sur evaluate que je n'ai pas pensé à split qui peut être une bonne alternative.

Utiliser evaluate comme cela
je ne pense pas que ce soit possible.

C'est ce que j'aimerais bien savoir, car par exemple ceci fonctionne:

Code :

1
2
3
Dim temp As Variant
temp = Evaluate("Exp(1)")
Debug.Print temp

Si quelqu'un a la réponse je suis preneur.

[ZebreLoup]

Evaluate sert à récupérer en VBA un objet Excel. Dans l'exemple que tu prends, EXP correspond à la fonction Excel (qui par hasard, est la même dans VBA cette fois). ARRAY n'est pas une fonction ou un objet Excel.

[issoram]

Merci Zebreloup,

Y a-t-il alors une autre fonction que "evaluate" pour effectuer ce traitement?

Cordialement.

[ZebreLoup]

Quel traitement ? Tu veux faire quoi ?
Pour ton premier code,

Code :

1
2
3
Dim temp As Variant
temp = Array(1, 2)
Debug.Print UBound(temp)

fonctionne très bien

[issoram]

Pour évaluer une fonction passée sous forme d'une chaine de caractères, de manière générale.

L'equivalent de

Code :

fonction(argument)

sous forme:

Code :

fonction_eval("fonction(argument)")

Le split proposé par jfontaine est pertinent pour mon problème. Je pose la question plus pour ma culture perso.

Cordialement.

[ZebreLoup]

Du coup j'ai creusé un peu en me disant que les fonctions VBA étaient aussi en fait des objets Excel et le code suivant fonctionne

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
Option Explicit
 
Public Function donneNombre1() As Integer
    donneNombre1 = 8
End Function
Public Function donneNombre2() As Integer
    donneNombre2 = 15
End Function
 
Public Sub test()
    Dim indexTest As Integer
 
    indexTest = 1
    MsgBox Evaluate("donneNombre" & indexTest & "()")
 
    indexTest = 2
    MsgBox Evaluate("donneNombre" & indexTest & "()")
End Sub

Ca doit même marcher avec des variables globales publiques.

Je n'ai jamais eu besoin de travailler de cette manière, mais je le garde dans un coin de ma tête on ne sait jamais. D'ailleurs, ça me fait penser que ça pourrait être la solution à un post que j'ai vu il y a quelques jours, je vais essayer de le retrouver...

EDIT : Ça ne fonctionne pas avec les variables globales publiques, ce n'est pas un vrai équivalent du eval de certains langages.

[issoram]

EDIT : Ça ne fonctionne pas avec les variables globales publiques, ce n'est pas un vrai équivalent du eval de certains langages.

Mais du coup on peut feinter un peu!

Code :

1
2
3
4
5
6
7
8
9
10
11
Function Array_bis(a As Variant, b As Variant) As Variant
    Array_bis = Array(a, b)
End Function
 
Sub test()
    Dim temp As Variant
    temp = Evaluate("Array(1,2)")       'plante...
    Debug.Print TypeName(temp)          'affiche Error
    temp = Evaluate("Array_bis(1, 2)")  'fonctionne!!
    Debug.Print TypeName(temp)          'affiche Variant()
End Sub

Merci pour tes recherches en tous cas ZebreLoup!