[XL-2010] Lignes vides qui ne le sont pas [Résolu]

[Sobas]

Bonjour a vous tous,

J'ai ce fichier ci joint qui à partir de la lignes 39 semble vide mais ne l'ai pas!!!!
Comment je peut faire pour les supprimer par ce que je me retrouve avec un fichier très volumineux

Merci a vous.

[Kaera]

Salut Sobas,

Je pense que le topic suivant (résolu) devrait t'aider :

http://www.developpez.net/forums/d48...-lignes-vides/

Kaera*

[Sobas]

Merci pour l'info mais en fait pour moi il ne s'agit pas d'une erreur d'excel (car en ouvrant un nouveau fichier, cela fonctionne correctement), mais il doit y avoir une ligne dans ma macro qui fait ça.

J'imagine que c'est l'action sélectionner tout...
Mais dans se cas comment faire pour sélectionner toutes les lignes qui se sont pas vide pour ne pas faire ctrl+A.

Si non si je les sélectionnes et que je fais clique droit et que je supprime sa fonctionne, mais là encore il faudrait que la sélection soit faite après ou la dernière cellule pleine. Dans mon cas elle contient le symbole "/"

[Kaera]

Salut Sobas,

Voici une suggestion, à tester et peut-être remodeler :

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
Sub test_ctrlA()
 
Dim TheCell As Range
Dim R As Range
 
Sheets("nomdetafeuille").Activate 'pas nécessaire si tu n'as qu'une feuille
Application.ScreenUpdating = False
Set R = Range("A:A")
    For Each TheCell In R
        If Not IsEmpty(TheCell) = True Then
            TheCell.EntireRow.Select
            'ici ton traitement
        End If
    Next TheCell
 
Application.ScreenUpdating = True
 
End Sub

Ce code permet de sélectionner toutes les lignes dont la cellule en colonne A est non vide (encore une fois, fonction de ton fichier exemple donc après, à toi d'adapter à ton cas).

J'espère ne pas avoir répondu à côté !

Kaera*

[MarcelG]

Bonjour Kaera, Sobas, Bonjour le Forum,

Si je peux me permettre,

Code :

Set R = Range("A:A")

Tester tout une colonne peut parfois être lourd. Mieux vaut sélectionner les lignes (ou colonnes) informées après en avoir détecté la dernière. Voir sur ce forum les différentes discussions à ce sujet.

Code :

For Each TheCell In R

Comme déjà signifié, sélectionner cellule par cellule un champ donné de valeurs, n'est qu'une solution de dernier recours. Mieux vaut privilégier les méthodes SpecialCells et Find.

Code :

Not IsEmpty(TheCell) = True

Ici, la propriété = True n'est pas nécessaire, mais c'est une question de choix.

Code :

TheCell.EntireRow.Select

Il n'est pas nécessaire de sélectionner un objet Range pour lui affecter une méthode ou une propriété. Ce genre de ligne alourdit le code.

Maintenant, j'en viens au problème de l'ami Sobas.
Ce phénomène est connu.
Voici un code de Laurent Longre qui te permettra d'y remédier, et que j'ai déjà mentionné dans une précédente discussion.

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
Sub NettoieEtDerniereCellule()     ' Laurent Longre
  Dim Sht As Worksheet, DCell As Range, Calc As Long, Rien As String
  On Error Resume Next
  Calc = Application.Calculation
  With Application
    .Calculation = xlCalculationManual
    .StatusBar = "Nettoyage en cours..."
    .EnableCancelKey = xlErrorHandler
    .ScreenUpdating = False
  End With
  For Each Sht In Worksheets
    If Sht.UsedRange.Address <> "$A$1" Or Not IsEmpty(Sht.[A1]) Then
      Set DCell = Sht.Cells.Find("*", , , , xlByRows, xlPrevious)(2)
      If Not DCell Is Nothing Then
        Sht.Range(DCell, Sht.Cells([A:A].Count, 1)).EntireRow.Clear
        Set DCell = Nothing
        Set DCell = Sht.Cells.Find("*", , , , xlByColumns, xlPrevious)(, 2)
        If Not DCell Is Nothing Then _
 Sht.Range(DCell, Sht.[IV1]).EntireColumn.Clear
      End If
      Rien = Sht.UsedRange.Address
    End If
  Next Sht
  Application.StatusBar = False
  Application.Calculation = Calc
End Sub

[Sobas]

Parfais, je vous remercie a tout les deux de votre aide.

C'est vraiment super, vous m’enlevai une épine du pied.

[Kaera]

MarcelG, Sobas,

De toute évidence, je ne suis pas prête à répondre aux questions des membres !
En tout cas merci de ta correction Marcel, j'en prends note.


Kaera*

[MarcelG]

Salut Kaera,

De toute évidence, je ne suis pas prête à répondre aux questions des membres !

Que non! D'autant qu'il n'y a rien de faux dans ton code!

Pardon si j'évoque ma propre expérience.
L'iune des premières choses que l'on apprend dans ce genre de forum est l'absolue nécessité de mettre son orgueuil de côté.

Proposer une résolution, c'est certes aider celui qui pose une question, mais c'est aussi s'exposer aux remarques des autres membres.
Il y 3 facteurs de progression à mon sens :
- la recherche par tous les moyens possibles de la réponse à ses questions
- la recherche d'une réponse aux questions posées par les autres en "creusant" ses propres acquis.
- l'amélioration de nos codes par la prise en compte des remarques des autres membres.

A moins d'avoir acquis la technicité d'un mercatog ou d'un Fontaine, dans ces conditions, nous avons tous une marge de progression.

En conclusion : continue !

[Kaera]

Re salut MarcelG,

Envoyé par MarcelG

L'une des premières choses que l'on apprend dans ce genre de forum est l'absolue nécessité de mettre son orgueuil de côté.
Proposer une résolution, c'est certes aider celui qui pose une question, mais c'est aussi s'exposer aux remarques des autres membres.

Tout à fait d'accord ! Dans mon message précédent, j'ai remarqué après coup qu'il pouvait être mal interprété mais c'était un sincère remerciement car j'ai bien conscience que ce sont les remarques des utilisateurs confirmés qui me feront progresser.

Il y 3 facteurs de progression à mon sens :
- la recherche par tous les moyens possibles de la réponse à ses questions
- la recherche d'une réponse aux questions posées par les autres en "creusant" ses propres acquis.
- l'amélioration de nos codes par la prise en compte des remarques des autres membres.
En conclusion : continue !

Toujours entièrement d'accord avec toi.
Je te remercie pour tes conseils et tes encouragements MarcelG, ça donne envie de s'y mettre plus encore !

Kaera*