[XL-2007] Comparaison de Dates [Résolu]

[chris09300]

Bonjour
J'ai un tableau de U3 a X67, et je souhaiterais si la differences entre les dates qui se trouvent dans les colonnes X et W
si X3 - W3 = 7 mettre la cellule U3 en jaune
si X3 - W3 = 14 mettre la cellule U3 en vert
si X3 - W3 = 21 mettre la cellule U3 en bleu clair
si X3 - W3 = 28 mettre la cellule U3 en gris.
et puis passer a la ligne suivante dans le tableau, jusqu'a la derniere ligne.

j'ai joint un fichier pour mieux comprendre
cris

[mercatog]

Fais une Mise en forme conditionnelle.
en U3
MFC
Utiliser formule...
=X3-W3<=7 Choisir la couleur 1
=X3-W3<=14 Choisir la couleur 2
=X3-W3<=21 Choisir la couleur 3
=X3-W3<=28 Choisir la couleur 4

[chris09300]

bonjour mercatog
avec cette methode je ne fait que sur les cellules X3 et W3
et non sur tout mon tableau
cris

[mercatog]

à l'aide du pinceau, tu copie la mise en forme jusqu'au bas

[chris09300]

pas possible de passer par un code

[mercatog]

Et pourquoi tu veux absolument passer par un code?
Si tu mets ton MFC sur la colonne entière en changeant la formule comme ceci

Code :

=ET(X3-W3<=7;X3<>"";W3<>"")

Code :

=ET(X3-W3<=14;X3<>"";W3<>"")

....

Sinon, tu as une méthode, tu n'as qu'à utiliser l'enregistreur de macro

[chris09300]

mais je souhaiterais faire de meme pour X4 - W4 X5 - W5 et cela dans tout le tableau.
c'est pour cela que je parlais de code, je pense qu'il faudrais une boucle,
c'est pour cela que j'ai joint un fichier
j'ai du mal avec les boucles , si tu as un exemple, je regarderais pour apprendre a decortiquer la methode
cris

[mercatog]

Envoyé par mercatog

à l'aide du pinceau, tu copie la mise en forme jusqu'au bas

[chris09300]

ok ca fonctionne
merci beaucoup
cordialement
cris

cela fonctionne bien avec la mise en forme conditionnelle, mais j'ai le probleme suivant:
et c'est pour cela que je souhaiterais passe par un code.
je voudrais me servir justement de ces cellules colorees pour alimenter un autre tableau a gauche dans le fichier joint, et avec la mise en forme conditionnelle ca marche pas

cris

[mercatog]

Donne toi du temps pour expliquer tes difficultés au lieu de bombarder le forum avec tes fichiers à chaque post.

[chris09300]

j'ai joint un fichier car sur le premier que j'avais mis il n'y avait pas l'autre tableau.
ce que je souhaiterais faire ci dessous
J'ai un tableau de U3 a X67, et je souhaiterais si la differences entre les dates qui se trouvent dans les colonnes X et W
si X3 - W3 = 7 mettre la cellule U3 en jaune
si X3 - W3 = 14 mettre la cellule U3 en vert
si X3 - W3 = 21 mettre la cellule U3 en bleu clair
si X3 - W3 = 28 mettre la cellule U3 en gris.
et puis passer a la ligne suivante dans le tableau, jusqu'a la derniere ligne de ce tableau.

[mercatog]

C'est ce que fais la MFC

[chris09300]

je suis d'accord avec toi, regarde le fichier que j'ai joint il y a la mise en forme conditionnelle,mais quand je clique sur mon bouton mise en forme de couleur rose,tu verras que ilne prend pas en compte le code que j'ai attribue a ce bouton.
si tu met sur la cellule ex: 7102 et que tu lui attribue la couleur jaune ,en cliquant sur le bouton tu verras la difference.

[mercatog]

Enlève la MFC
Adapte ce code pour ton fichier

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
Sub TEST()
Dim Klr As Long
Dim c As Range
Dim d As Integer
 
With Worksheets("Feuil1")                       ' A adapter
    For Each c In .Range("U3:U100")
        If IsDate(c.Offset(0, 2)) And IsDate(c.Offset(0, 3)) Then
            d = DateDiff("d", c.Offset(0, 2), c.Offset(0, 3))
            Select Case d
                Case 7: Klr = 3
                Case 14: Klr = 6
                Case 21: Klr = 13
                Case 28: Klr = 14
                Case Else: Klr = xlNone
            End Select
        End If
        c.Interior.ColorIndex = Klr
        Klr = xlNone
    Next c
End With
End Sub

La sub Test sera lancée par un bouton, sinon tu peux regarder du côté de WorkSheet_Change

[chris09300]

je n'est pas tout compris le code, mais ca fonctionne tres bien.
je vais eplucher le code pour bien le comprendre
merci beaucoup a toi
cordialement
cris

[mercatog]

Avec explication

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
Sub TEST()
Dim Klr As Long
Dim c As Range
Dim d As Integer
 
With Worksheets("Feuil1")                       ' A adapter
    'On parcour la plage U3:U100
    For Each c In .Range("U3:U100")
        'Si pour chaque cellule U on a une date en W et en X
        If IsDate(c.Offset(0, 2)) And IsDate(c.Offset(0, 3)) Then
            'd: différence en jours entre W et X
            d = DateDiff("d", c.Offset(0, 2), c.Offset(0, 3))
            'on fonction de cette différence d, on obtient la couleur dans Klr
            Select Case d
                Case 7: Klr = 3
                Case 14: Klr = 6
                Case 21: Klr = 13
                Case 28: Klr = 14
                Case Else: Klr = xlNone
            End Select
        End If
        c.Interior.ColorIndex = Klr
        'on annule la couleur et on poursuit la boucle
        Klr = xlNone
    Next c
End With
End Sub

[chris09300]

tu est vraiment super, j'ai bien compris maintenant.
cordialement
cris