[Toutes versions] Barre de deplacement en VBA [Résolu]

[Dutchou]

Bonjour à tous,

Existe-t-il une commande afin de remonter la barre de déplacement vertical d'un formulaire?

Je voudrais installer un bouton de commande à la fin d'un formulaire afin d'aider l'utilisateur à remonter plus rapidement. Mais je n'ai pas trouvé comment... A part donner le focus à un contrôle placé au début.

Merci d'avance

[LedZeppII]

Bonjour,

Je ne connais pas de moyen offert par Access pour manipuler les barres de défilement.

Pour un formulaire principal (pas un sous-formulaire), on peut passer par l'API Windows.

Exemple de code placé dans le module de code du formulaire.

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
Option Compare Database
Option Explicit
 
' --- Début déclarations pour SendMessage de l'API Windows -----
' constante pour argument msg de SendMessage
Const WM_VSCROLL As Long = &H115
' constantes associées à WM_VSCROLL pour argument wParam
Const SB_PAGEUP As Long = 2
Const SB_PAGEDOWN As Long = 3
Const SB_TOP As Long = 6
Const SB_BOTTOM As Long = 7
' Fonction SendMessage
Private Declare Function SendMessage Lib "user32.dll" _
                  Alias "SendMessageA" _
        (ByVal hWnd As Long, ByVal msg As Long, _
         wParam As Long, lParam As Any) As Long
' --- Fin délcarations API -------------------------------------
 
Private Sub cmdDefilerToutEnHaut_Click()
Dim hWnd As Long, rval As Long
hWnd = Me.hWnd
rval = SendMessage(hWnd, WM_VSCROLL, ByVal SB_TOP, ByVal 0)
End Sub
 
Private Sub cmdDefilerToutEnBas_Click()
Dim hWnd As Long, rval As Long
hWnd = Me.hWnd
rval = SendMessage(hWnd, WM_VSCROLL, ByVal SB_BOTTOM, ByVal 0)
End Sub

cmdDefilerToutEnHaut est un bouton pour positionner le curseur de la barre de défilement verticale tout en haut.
cmdDefilerToutEnBas est un bouton pour positionner le curseur de la barre de défilement verticale tout en bas.

A+

[Dutchou]

Merci pour ta réponse