[AC-2003] Comment envoyer état du formulaire actif par mail ?

[seria99]

Bonjour à tous,

Mon problème est assez complexe. Je travaille sur un formulaire assez simple sous Access et je souhaiterai envoyer un état par mail via Outlook, état qui doit correspondre au formulaire actif (et non aux centaines de formulaires complétés). Je cherche seulement à ouvrir Outlook avec mon état en pièce jointe. Le Snapshot paraissait intéressant mais il envoie la totalité des formulaires. J'ai donc pensé au format PDF mais il ne m'est pas proposé. Voici les différentes informations qui me paraissent utiles à une meilleur compréhension :

1) Je travaille sur une machine en réseau et il m'est impossible de changer les caractéristiques du pc. C'est une sorte de zone de travail en commun où les accès sont très limités.

2) Je suis sous XP et Office 2003

3) Impossible d'insérer un fichier .dll comme j'ai pu voir sur certaines discussions

4) J'ai réussi à créer un aperçu sur le formulaire actif (est-il éventuellement utilisable pour l'envoi ?) et à l'imprimer sur une imprimante par défaut (sachant aussi que nous possédons PDFcreator)

5) En résumé comment envoyer l'état de mon formulaire actif à un destinataire inconnu (non fixe du moins) via Outlook sans rentrer dans les entrailles de mon ordinateur?

Merci d'avance pour votre précieuse aide!

[Geache]

Bonjour,

Si tu peux imprimer via ton PDFCreator ton aperçu sur ton imprimante fictive, tu peux normalement également le sauvegarder en format pdf dans un emplacement de ton choix sur ton disque.

Et dés lors, tu peux sélectionner ce fichier pdf pour l'envoyer en pièce jointe.

Par contre, il faut que je retrouve comment. Il y a un tutoriel sur les envois de mail. Je dois retrouver le lien.

Bonne journée.

Edit : Au temps pour moi. C'est dans la FAQ ACCESS que j'avais trouvé mon bonheur. Si tu tapes "Pièce jointe" dans la FAQ, je pense que tu devrais trouver de quoi réaliser ce que tu souhaites faire.

[stigma]

Tu peux aussi créer ton état en pdf directement en VBA. J'ai fait ce truc dans une de mes applis. Dis moi si tu as besoin de détails.

[seria99]

Envoyé par Geache

Bonjour,

Si tu peux imprimer via ton PDFCreator ton aperçu sur ton imprimante fictive, tu peux normalement également le sauvegarder en format pdf dans un emplacement de ton choix sur ton disque.

Et dés lors, tu peux sélectionner ce fichier pdf pour l'envoyer en pièce jointe.

Par contre, il faut que je retrouve comment. Il y a un tutoriel sur les envois de mail. Je dois retrouver le lien.

Bonne journée.

Edit : Au temps pour moi. C'est dans la FAQ ACCESS que j'avais trouvé mon bonheur. Si tu tapes "Pièce jointe" dans la FAQ, je pense que tu devrais trouver de quoi réaliser ce que tu souhaites faire.

Merci pour ta réponse.
Le problème c'est je veux justement éviter de la manipulation au maximum (enregistrer d'abord en pdf puis ouvrir ma boite et joindre mon fichier...) J'en demande peut être trop...

[seria99]

Envoyé par stigma

Tu peux aussi créer ton état en pdf directement en VBA. J'ai fait ce truc dans une de mes applis. Dis moi si tu as besoin de détails.

Oui je veux bien savoir comment on fait ceci. Par contre je re-précise bien que je n'ai pas l'option PDF et que je ne pas rentrer dans le système.
Merci

[stigma]

Voici un module pour faire un état en pdf

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
Option Compare Database
Option Explicit
 
' Ne pas oublier de cocher la bibliothèqe PDFCreator
' dans le menu Outils / Références de Visual Basic Editor
 
' API Windows pour faire une temporisation en millisecondes
Private Declare Sub Sleep Lib "kernel32" (ByVal dwMilliseconds As Long)
 
' Constantes pour les temporisations
Private Const maxTime = 10    ' en secondes
Private Const sleepTime = 250 ' en millisecondes
 
' ---
' IMPRESSION D'UN ETAT EN PDF
' ---
' Entrée : strReportName <- Nom de l'état à imprimer en PDF
'          strWhere      <- Clause WHERE filtrant l'état (facultatif)
'          strPDFName    <- Nom du fichier PDF à générer (facultatif)
'          strDirectory  <- Chemin de stockage du fichier PDF (facultatif)
'
Public Sub SaveAsPDF( _
      ByVal strReportName As String, _
      Optional ByVal strWhere As String = "", _
      Optional ByVal strPDFName As String = "", _
      Optional ByVal strDirectory As String = "")
 
      On Error GoTo ErrPDF
 
      ' Quelques variables...
      Dim pdfc As PDFCreator.clsPDFCreator
      Dim DefaultPrinter As String
      Dim c As Long
      Dim OutputFilename As String
      ' Instancier un nouvel objet PDFCreator
      Set pdfc = New clsPDFCreator
     ' Paramétrer l'objet PDFCreator
      With pdfc
        .cStart "/NoProcessingAtStartup"
        .cOption("UseAutosave") = 1
        .cOption("UseAutosaveDirectory") = 1
 
        ' Chemin de destination
        ' Par défaut : dossier 'Mes documents' de l'utilisateur
        If strDirectory = "" Then
          strDirectory = Environ("USERPROFILE") & "\Mes documents\"
        End If
        .cOption("AutosaveDirectory") = strDirectory
 
        ' Nom du fichier PDF à générer
        .cOption("AutosaveFilename") = _
          IIf(strPDFName = "", strReportName, strPDFName)
 
        ' Format de sauvegarde (0 = PDF)
        .cOption("AutosaveFormat") = 0
 
        ' Mémoriser l'imprimante par défaut
        ' et définir PDFCreator à la place
        DefaultPrinter = .cDefaultPrinter
        .cDefaultPrinter = "PDFCreator"
        .cClearCache
 
        ' Imprimer l'état
        DoCmd.OpenReport strReportName, acViewNormal, , strWhere
        .cPrinterStop = False
      End With
 
      ' Temporisation
      c = 0
      Do While (pdfc.cOutputFilename = "") And (c < (maxTime * 1000 / sleepTime))
        c = c + 1
        Sleep 200
      Loop
 
      ' Nom du fichier PDF produit
      OutputFilename = pdfc.cOutputFilename
 
      ' Réinstaller l'imprimante d'origine
      With pdfc
        .cDefaultPrinter = DefaultPrinter
        Sleep 200
        .cClose
      End With
 
      ' Attendre jusqu'à ce que PDFCreator soit supprimé de la mémoire
      Sleep 2000
 
      ' Vérifier si le fichier a été créé
      If OutputFilename = "" Then
        MsgBox "Création du fichier PDF." & vbCrLf & vbCrLf & _
          "Une erreur s'est produite : temps écoulé !", vbExclamation + vbSystemModal
      End If
 
FinErrPDF:
    Exit Sub
ErrPDF:
    MsgBox Error$
    Call Erreurs("Module PDF", "Sub SaveAsPDF", Error$)
    Resume FinErrPDF
End Sub

[seria99]

Merci Stigma!

Le VBA n'est pas ma seconde langue et je débute à peine donc j'ai quelques questions par rapport à ce code :
- je souhaite associer ce code à un bouton qui, lorsqu'on clique dessus, active la commande PDF avec le code que vous m'avez donné. Or je ne maitrise pas vraiment le "mixage" de code. Où dois je insérer ce code? Sous "Option Compare Database" directement? Comment va t -il comprendre que c'est avec le bouton "envoyer_etat" qu'il faut agir?

- quand vous dites "strReportName est le nom de mon état", que faut-il changer? strenvoyer_etat? strReportenvoyer_etat? je suis perdue dès qu'il faut changer quelque chose...

Le reste du code reste du chinois pour moi...je verrai bien à l'utilisation pour le reste.

Merci d'avance pour vos réponse

[stigma]

oui, tu mets ton code sous "Option Compare Database"
Tu crées un bouton et dans l'évènement click de ce bouton, tu appelles ton code.
Mais si tu n'es pas habituée au VBA (langage extrêmement simple), je te conseille de regarder les divers tutos ici : http://access.developpez.com/cours/?...gevba#vbabases

[seria99]

Merci pour ces informations.
Je vais étudier tout ça et tenter de régler mon problème.
A bientôt si je bloque!

Merci!