Contrastes dans une régression logistique

cladoo · 13/12/2011, 16h08

Bonjour,

je suis tombé sur cet article qui traite d'une régression logistique selon un modèle additif : y = x1 + x2 avec x1 et x2 des variables catégorielles de 3 niveaux (1 à 3) et y la variable de réponse binaire.

L'article traite de contrastes, mais honnêtement je n'arrive pas à comprendre les 3 exemples de contrastes, pouvez-vous m'aider ?

Exemple :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
 
proc logistic DATA = logit_sim DESC;
class x1 (ref = '1') x2 (ref = '1') / param=ref;
model y = x1 x2;
contrast 'x1 = 1 x2 1 v 2' x2 1    /e estimate = parm;
contrast 'x1 = 1 x2 1 v 3' x2 0 1  /e estimate = parm;
contrast 'x1 = 1 x2 2 v 3' x2 1 -1 /e estimate = parm;
run;

Personnellement j'aurai écris :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
proc logistic data = logit_sim desc;
class x1 (ref = '1') x2 (ref = '1') / param=ref;
model y = x1 x2;
contrast 'x1 = 1 x2 1 v 2' x1 1 0 0 x2 1 -1 0   /e estimate = parm;
contrast 'x1 = 1 x2 1 v 3' x1 1 0 0 x2 1 0 -1  /e estimate = parm;
contrast 'x1 = 1 x2 2 v 3' x1 1 0 0 x2 0 1 -1 /e estimate = parm;
run;

Mon code est-il faux ? Si oui pourquoi ?
Merci beaucoup!!

ci-après les data :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

olivier.decourt · 13/12/2011, 17h15

Bonjour.
Oui, ton idée est correcte ; mais non, ton code serait faux.
C'est assez fourbe, ça tient à la manière dont SAS code en interne ses coefficients. Car CONTRAST est une série de pondérations à appliquer au tableau des coefficients du modèle : la rédaction du CONTRAST dépend donc beaucoup de la forme de ce tableau de coeffs.
Avec PARAM=REF, la modalité de référence est omise dans le tableau des coefficients. D'un point de vue CONTRAST, elle n'existe donc pas. La variable X2, qui vaut 1 (référence), 2 ou 3 n'a que 2 pondérations possibles en CONTRAST, sur la valeur 2 ou la 3.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

contrast 'x1 = 1 x2 1 v 2' x2 1  ;

nous raconte l'histoire suivante : on ne donne aucun poids à X1 --> donc X1 est à sa valeur de référence (1) et on donne un poids de 1 au 1er coefficient affiché de X2, c'est à dire le coeff de X2=2. Comme il est défini par écart à la référence, ce coeff de X2 est la différence entre moyenne(Y|X2=2) et moyenne(Y|X2=1). D'où le libellé du CONTRAST.
Tous les autres suivent la même logique.

Cependant, je trouve ta syntaxe bien plus naturelle, et c'est celle qu'on trouverait si le tableau des coefficients mentionnait bien toutes les modalités : c'est l'option PARAM=GLM. Mais (si c'était aussi simple ce ne serait pas vraiment du SAS) avec PARAM=GLM les options (REF=) sont ignorées. Il faudrait bricoler (format, option DESC dans CLASS) pour qu'au lieu d'être 3 par défaut, la valeur de référence devienne 1. Et il faudrait alors faire attention à l'ordre des coefficients dans le tableau. Par exemple, si tu fais

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
  CLASS x1 
  	    x2  / PARAM=GLM DESC ;
  MODEL y = x1 x2 ;
  CONTRAST "x1=1 x2=2 vs x2=1"
  	x2 0 1 -1 / E ESTIMATE=PARM ;

car les coefficients de X2 sont désormais affichés par valeur décroissante (3 puis 2 puis 1) à cause de l'option DESC.

Mais (ouf, reprenons nos esprits) si tu te moques du tableau de coeffs (tu as raison puisqu'on peut faire des CONTRASTs, justement), tu mets PARAM=GLM et tu suis ton idée.
Par contre, inclure X1 dans le CONTRAST alors qu'il n'y a pas d'effet croisé X1*X2, je ne vois pas l'intérêt. Sans interaction, X1 et X2 sont supposées indépendantes, le modèle les a traitées comme telles, et du coup, ton CONTRAST sur X2 est le même quelle que soit la valeur de X1.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
PROC LOGISTIC DATA=work.test ;
  CLASS x1 
  	    x2  / PARAM=GLM ;
  MODEL y = x1 x2 ;
  CONTRAST "x1=1 x2=2 vs x2=1"
  	x2 -1 1 0 / E ESTIMATE=PARM ;
RUN ;

Bon courage en tout cas, le CONTRAST est un monde en soi.

cladoo · 13/12/2011, 17h40

Bonjour Olivier, merci pour ces explications plus que claires, c'est vraiment appréciable !

Pour le cas

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

contrast 'x1 = 1 x2 2 v 3' x2 1 -1 /e estimate = parm;

Puisque on a utilisé l'option ref la modalité 1 est donc référence, hors on applique des contraintes a x2 sur 2 et 3, sans s'occuper de la variable de référence, dans mon esprit c'est un peu comme si on adressait un contraste

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1 1 -1

ce qui en soit ne veut rien dire, je me trompe ?

Si on va plus loin dans l'article, on a les contrastes suivants sur un modèle interactif (et là pour le coup je n'y comprends rien

)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
proc logistic data = logit_sim desc;
class x1 (ref = '1') x2 (ref = '1') / param=ref;
model y = x1 x2 x1*x2;
contrast 'x1 = 1 x2 1 v 2' x2 1    /estimate = parm;
contrast 'x1 = 1 x2 1 v 3' x2 0 1  /estimate = parm;
contrast 'x1 = 1 x2 2 v 3' x2 1 -1 /estimate = parm;

contrast 'x1 = 2 x2 1 v 2' x2 1    x1*x2 1    /estimate = parm;
contrast 'x1 = 2 x2 1 v 3' x2 0 1  x1*x2 0 1  /estimate = parm;
contrast 'x1 = 2 x2 2 v 3' x2 1 -1 x1*x2 1 -1 /estimate = parm;

contrast 'x1 = 3 x2 1 v 2' x2 1    x1*x2 0 0 1    /estimate = parm;
contrast 'x1 = 3 x2 1 v 3' x2 0 1  x1*x2 0 0 0  1 /estimate = parm;
contrast 'x1 = 3 x2 2 v 3' x2 1 -1 x1*x2 0 0 1 -1 /estimate = parm;
run;

Qu'en pensez-vous ?

olivier.decourt · 14/12/2011, 07h35

Pour le CONTRAST de x2=2 vs x2=3, il y a un peu de maths à faire. On cherche l'écart de moyennes de Y entre les profils X2=2 et X2=3.
Or coeff(X2=2) = moy(Y|X2=2)-moy(Y|X2=1) et coeff(X2=3) = moy(Y|X2=3)-moy(Y|X2=1), puisque X2=1 est la référence : les coefficients des autres modalités traduisent l'écart à la référence.
Note aux puristes : oui, j'ai omis la transformation logit pour simplifier les formules, et faire ressortir l'idée.
Donc moy(Y|X2=3)-moy(Y|X2=2) = l'écart que l'on cherche = coeff(X2=3) - coeff(X2=2).
D'où un CONTRAST qui serait 0 -1 1 si on avait l'option PARAM=GLM, et -1 1 avec PARAM=REF.

J'y ai repensé cette nuit, et ta vision initiale pourrait se coder si tu mettais à la fois les options PARAM=GLM et NOINT (pas de constante). Tous les coefficients traduisent alors les moyennes conditionnelles de Y pour leur modalité, et on retrouve bien des écritures plus "naturelles".

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
PROC LOGISTIC DATA=work.test ;
  CLASS x1 (REF="1") x2 (REF="1") / PARAM=GLM ;
  MODEL y = x1 x2 / NOINT ;
  CONTRAST "x2 1 vs 3" x2 1 0 -1 / E ESTIMATE=PARM ;
RUN ;

(Bon, je reprends mon souffle et un café.

)
Avec les interactions, la logique reste toujours la même, il faut avoir bien en tête le tableau de coefficients. Dans le modèle X1 X2 X1*X2 il est organisé comme ceci, avec PARAM=REF :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
Parameter        DF    Estimate
-------------------------------------
Intercept         1      0.2007
x1        2       1      0.6947
x1        3       1     -0.0403
x2        2       1     -1.0961
x2        3       1      0.2889
x1*x2     2*2     1      0.3610
x1*x2     2*3     1     -0.2398
x1*x2     3*2     1     -0.3299
x1*x2     3*3     1      0.4952

Ce qui veut dire que les moyennes conditionnelles quand X2=1 sont dans les coefficients de X1=2 et X1=3, que les moyennes conditionnelles quand X1=1 sont dans X2=2 et X2=3.
C'est la présentation du modèle qui est un peu alambiquée, les CONTRASTs sont logiques comparés à cela !
Si on prend

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

contrast 'x1 = 3 x2 1 v 2' x2 1    x1*x2 0 0 1    /estimate = parm;

on veut comparer les moyennes conditionnes de Y quand on a (X1,X2) qui vaut (3,1) ou (3,2). On les obtient en additionnant les coefficients de X2=2 (poids 1 et 0 pour X2 seul), sous-entendu X1 vaut n'importe quoi, donc pourquoi pas 3 et de X1*X2=3*2 (spécifiquement la paire de valeurs (3,2)).
Mais en relisant ce paragraphe, je ne me trouve pas clair du tout, donc probablement pas convainquant du tout.
Si tu dois écrire des contrastes "intuitifs"

dans le modèle avec interaction, essaye donc avec PARAM=GLM, NOINT et pas d'effets simples dans le modèle. Le CONTRAST "X1=3, X2=1 vs 2" s'écrit alors :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
PROC LOGISTIC DATA=work.test ;
  CLASS x1 (REF="1") x2 (REF="1") / PARAM=GLM ;
  MODEL y = x1*x2 / NOINT ;
  CONTRAST 'x1 = 3 x2 1 v 2' x1*x2 
                                   0  0  0 /* X1=1 donc pas d'intérêt pour le CONTRAST */
                                   0  0  0 /* idem, X1=2 donc pas concerné */
                                   1 -1  0 /* on compare, quand X1=3, les cas X2=1 et X2=2 */
     / E ESTIMATE=PARM ;
RUN ;

ce qui me semble moins tiré par les cheveux (et donne la même réponse que le code précédent. C'est déjà ça).

Euh... j'ai déjà dit "bon courage", non ?

Olivier

cladoo · 14/12/2011, 09h05

Bonjour Olivier. Déjà, merci beaucoup pour le temps que vous passez à me répondre, ça m'aide énormément!

Ensuite, j'ai quelques questions (en bleu dans le texte)

Citation:

Envoyé par olivier.decourt

J'y ai repensé cette nuit, et ta vision initiale pourrait se coder si tu mettais à la fois les options PARAM=GLM et NOINT (pas de constante). Tous les coefficients traduisent alors les moyennes conditionnelles de Y pour leur modalité, et on retrouve bien des écritures plus "naturelles".

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
PROC LOGISTIC DATA=work.test ;
  CLASS x1 (REF="1") x2 (REF="1") / PARAM=GLM ;
  MODEL y = x1 x2 / NOINT ;
  CONTRAST "x2 1 vs 3" x2 1 0 -1 / E ESTIMATE=PARM ;
RUN ;

Je ne savais pas qu'on pouvait "mixer" /PARAM=GLM (dernière modalité comme référence) et (REF="1") dans l'option CLASS, dans ce cas là, on n'a plus besoin de /PARAM=REF et on construit effectivement les contrastes de manière plus 'intuitive', mais dans ce cas, puisqu'on ne fait 'que' dire à SAS que la modalité de référence devient 1 et plus 3, pourquoi dois-je retirer l'intercept de mon modèle ? => dans ma logique, on se retrouve avec un cas comparable à /PARAM=GLM et une option DESC, non ?

Citation:

Envoyé par olivier.decourt

Si tu dois écrire des contrastes "intuitifs"

dans le modèle avec interaction, essaye donc avec PARAM=GLM, NOINT et pas d'effets simples dans le modèle. Le CONTRAST "X1=3, X2=1 vs 2" s'écrit alors :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
PROC LOGISTIC DATA=work.test ;
  CLASS x1 (REF="1") x2 (REF="1") / PARAM=GLM ;
  MODEL y = x1*x2 / NOINT ;
  CONTRAST 'x1 = 3 x2 1 v 2' x1*x2 
                                   0  0  0 /* X1=1 donc pas d'intérêt pour le CONTRAST */
                                   0  0  0 /* idem, X1=2 donc pas concerné */
                                   1 -1  0 /* on compare, quand X1=3, les cas X2=1 et X2=2 */
     / E ESTIMATE=PARM ;
RUN ;

ce qui me semble moins tiré par les cheveux (et donne la même réponse que le code précédent. C'est déjà ça).

En spécifiant MODEL y = x1*x2 on ne sous entend pas MODEL y = x1 + x2 + x1*x2 comme sous R ? On ne teste que l'interaction et pas les effets principaux ?
Si oui je comprends le contrastes, mais si c'est le modèle "parapluie' qui est sous-entendu, dans ce cas le contraste ne devrait-il pas être :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
PROC LOGISTIC DATA=work.test ;
  CLASS x1 (REF="1") x2 (REF="1") / PARAM=GLM ;
  MODEL y = x1*x2 / NOINT ; /*sous entendu x1 + x2 + x1*x2 ? */
  CONTRAST 'x1 = 3 x2 1 v 2' x1 0 0 1 x1*x2 
                                   0  0  0 /* X1=1 donc pas d'intérêt pour le CONTRAST */
                                   0  0  0 /* idem, X1=2 donc pas concerné */
                                   1 -1  0 /* on compare, quand X1=3, les cas X2=1 et X2=2 */
     / E ESTIMATE=PARM ;
RUN ;

?

Pour les interactions, la matrice de contrastes est-elle toujours construite de la même manière ?
Par exemple si je parle de l'interaction x1*x2, on a la matrice de coefficient suivante (arrêtez moi si je dis une bêtise)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
 
(x1=1 * x2=1) (x1=1 * x2=2) (x1=1 * x2=3)
(x1=2 * x2=1) (x1=2 * x2=2) (x1=2 * x2=3)
(x1=3 * x2=1) (x1=3 * x2=2) (x1=3 * x2=3)

que devient cette matrice si j'ai une interaction de niveau 3 (avec 3 facteurs de 3 niveaux chacun x1*x2*x3) ?

Finalement n'est-il pas plus simple de coder les variables catégorielles directement en indicatrices de classes dans une étape DATA puis d'intégrer ces indicatrices de classe dans le modèle ?
Exemple :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
 
DATA test;
SET test;
x1_2= (x1=2);
x1_3= (x1=3);
 
x2_2= (x2=2);
x2_3= (x2=3);
run;

Arrêtez moi si je me trompe, mais :
dans ce cas précis, chaque indicatrice est comparée à la référence désirée non ? Si je souhaite tester une interaction, il faudrait construire des variables dans l'étape DATA (exemple : x1=2 VS x2=3 impliquerait la création d'une variable x1_2_x2_3 = x1_2*x2_3 qu'il faudrait ajouter au modèle.
Est-ce que ce raisonnement tient la route et surtout est-il limitant par rapport aux méthodes 'classiques' discutées plus haut ?

Merci encore de votre aide, j'avance bien. Mais je pense que le param=REF est trop obscure pour moi...

olivier.decourt · 14/12/2011, 09h30

Bon, alors déjà une boulette pour moi : j'ai laissé traîner les (REF=) en copiant/collant. Ils sont ignorés avec PARAM=GLM.
L'idée c'était qu'avec PARAM=GLM et NOINT, chaque coefficient traduit directement une moyenne conditionnelle de Y, comme dans un LSMEANS.

Citation:

En spécifiant MODEL y = x1*x2 on ne sous entend pas MODEL y = x1 + x2 + x1*x2 comme sous R ? On ne teste que l'interaction et pas les effets principaux ?

Là encore, tout dépend du paramétrage (PARAM=REF, PARAM=GLM, constante ou NOINT). Avec PARAM=GLM + NOINT, le modèle X1*X2 suffit car X1 X2 X1*X2 est sur-paramétré. On le voit en enlevant NOINT avec tout de suite une série de coefficients qui sont contraints à zéro.
Ce n'est qu'une question d'écriture, il y a de toute façon très souvent trop de coefficients, d'où des forçages à zéro et des choix arbitraires de modalités de référence.

Citation:

Pour les interactions, la matrice de contrastes est-elle toujours construite de la même manière ?
Par exemple si je parle de l'interaction x1*x2, on a la matrice de coefficient suivante (arrêtez moi si je dis une bêtise)

Là encore, tout dépend du paramétrage choisi. Avec NOINT, PARAM=GLM et le modèle X1*X2, oui. Sinon, il faut adapter en fonction du tableau de coefficients du modèle. Toujours s'y référer pour rédiger un CONTRAST, et essayer de garder aussi en tête à quelle moyenne conditionnelle ou différence de moyennes conditionnelles correspond chaque coefficient.

Je pense que le plus crispant dans cette histoire c'est qu'il y a toujours plusieurs manières de rédiger le même modèle et les mêmes comparaisons. Donc on ne peut tirer aucune "recette" générale (en tout cas je n'en trouve pas et pour les CONTRASTs je travaille au feeling, ce qui ne fait pas très professionnel).

cladoo · 14/12/2011, 15h20

Merci, je vais continuer à potasser ça

14/12/2011, 15h20	#7
cladoo Futur Membre du Club Inscription : mars 2007 Messages : 101 Détails du profil Informations forums : Inscription : mars 2007 Messages : 101 Points : 15 Points : 15	Merci, je vais continuer à potasser ça
	00

Outils de la discussion
Afficher une version imprimable Envoyer un lien vers cette page par email