[DATA] FORMAT + HLO='O' et LABEL='ERROR' [Résolu]

Bonjour tout le monde;
quelqu'un peut m'expliquer HLO='O' et LABEL='ERROE' et son usage ?

Code :

1
2
3
4
5
6
7
8
9
10
11
data le_format;
             set tab ( rename=(var1=START var2=LABEL)) end=eof;
             retain FMTNAME "formats" type 'C';
             output;
             if eof then do;
             hlo='O';
             label='ERROR';
                output;
             end;
run   ;

il me place le 'O' et 'ERROR' en dernière ligne. mais je ne comprends pas trop son usage.

[jerome_pdv2]

Bonjour,

il me semble que c'est pour tenir compte des modalités non prévue dans ton format.

Par exemple si tu as une variable SEXE codé en 1 pour 'Homme' et 2 pour 'Femme'

Dans Tab tu aura sans doute fait en sorte que 1 corresponde à 'Homme' et 2 à 'Femme'.

Si il rencontre 3 il va mettre 'ERROR' dans ta variable au lieu de laisser 3 dans le cadre d'un format normal où les modalité non prévues sont laissées telle quelle.

Celà correspond à 'OTHER' dans les formats 'manuels'

Enfin j'espère être clair dans mon explication...

Bonjour jérome;
merci pour ta réponse, malheureusement , je viens de faire ce test et le résultat ne correspond pas à ce que tu m'as expliqué.

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
 
DATA test;
format fm $5.;
SET sashelp.class;
IF sex='M' then fm='1';else fm='2';
IF _n_ =19 then sex='A';
run;
 
DATA le_format (keep=start label hlo) ;
             SET test(    RENAME=(sex=START fm=LABEL)) end=eof;
             retain FMTNAME "formats" type 'C';
             output;
             IF eof then do;
             hlo='O';
             label='ERROR';
                output;
             end;
run   ;

[olivier.decourt]

Bonjour Julie.
L'analyse de Jérôme est la bonne : HLO=O indique que tu es sur l'équivalent d'un OTHER dans une proc FORMAT. Ca permet de faire un cas "ramasse-miettes" qui correspond à toutes les situations non traitées explicitement.
La table en entrée de ton étape DATA ne contient pas des données brutes (pas comme ton dernier exemple), mais le codage avec (je reste sur l'exemple sexe) :
1 ligne pour 1=Homme
1 ligne pour 2=Femme
Ce que rajoute ton étape DATA, c'est une 3e ligne pour autres=Erreur.
La table produite par l'étape DATA ne sera pas plaquée non plus directement sur les données : elle servira en entrée d'une proc FORMAT CNTLIN. C'est à dire que le contenu de la table remplacera une instruction VALUE.
Au lieu d'écrire

Code :

1
2
3
4
5
6
7
PROC FORMAT ;
VALUE $sexe
"F" = "Filles"
"M" = "Garçons"
OTHER = "Erreur"
;
RUN ;

on créera à partir d'une table des codes possibles l'équivalent.
J'espère que c'est plus clair ???

[jerome_pdv2]

Envoyé par rosesansepines

Bonjour jérome;
merci pour ta réponse, malheureusement , je viens de faire ce test et le résultat ne correspond pas à ce que tu m'as expliqué.

Code :

C'est parce que le code n'est pas exactement celui-là.

Voici un code correct en reprenant ton exemple

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
 
/* création d'un fichier d'exemple de label de la variable sexe **/
DATA tab;
var1='M';var2='Garçon';output;
var1='F';var2='Fille';output;
run;
 
 
/*** Préparation de la table de création du format ***/
DATA le_format;
             SET tab ( RENAME=(var1=START var2=LABEL)) end=eof;
             retain FMTNAME "F_SEXE" type 'C';
             output;
             IF eof then do;
             hlo='O';
             label='ERROR';
                output;
             end;
run   ;
/*** création du format ****/
proc format cntlin=le_format;run;
 
/*** exemple d'utilisation du format ***/
DATA test;
SET sashelp.class;
IF _n_ =19 then sex='A';
run;
 
proc print DATA=test;
format sex $F_sexe.;run;

Merci pour ces brillantes explications Messieurs.
Bravo.