Fusion fichier avec Merge : Variable numed has been defined as both character and numeric [Résolu]

[5natacha]

Bonjour à tous,
je suis une nouvelle utilisatrice de SAS et je souhaite fusionner 2 fichiers, j'ai donc fais un merge.
Mais e probleme est que j'ai une erreur : " Variable numed has been defined as both character and numeric" et je ne comprends pas.
Faut il que ma variable identique soit numérique?
J'ai verifié la variable identique est au meme format dans les 2 fichiers.
Je vous remercie pas avance pour vos suggestions.
Natacha

[s_a_m]

Hello et bienvenue;


pour répondre à cette question

Code :

1
2
 
Faut il que ma variable identique soit numérique?

la réponse est : ou bien que la variable soit numérique dans les deux tables ou bien qu'elle soit caractère dans les deux table.


Sinon peux-tu poster ton code ? afin qu'on puisse t'aider?

[5natacha]

Voila mon code

Code :

1
2
3
4
5
6
Proc sort DATA=sasuser.cohortes2;BY idet ;run;
Proc sort DATA=sasuser.Cohortes1;BY idet;run;
DATA sasuser.Cohortes3;
merge sasuser.cohortes2 sasuser.Cohortes1;
BY idet;
run;

Je ne comprends pas la variable est caractere dans les 2 tables.
Merci d'avance.

[s_a_m]

Bon le code à l'aire bon,
est ce que tu peux faire ceci :

Code :

1
2
3
4
5
 
 
proc sql;
DESCRIBE TABLE sasuser.cohortes1;
DESCRIBE TABLE sasuser.cohortes2;

et regarder le résultat dans la log pour s'assurer que ta variable idet est caractère dans les deux tables?

[olivier.decourt]

Envoyé par 5natacha

" Variable numed has been defined as both character and numeric"

Bonjour Natacha.
Ce n'est pas IDET qui pose problème, mais NUMED, comme l'indique le message. Attention dans MERGE, si des variables (autre que la clé IDET) portent le même nom, SAS essaye d'écraser les valeurs de la 1e table par celles de la 2e table en cas de correspondance.
Si tu veux conserver toutes les variables, il faudrait renommer celles qui sont identiques avant la jointure.
Bon courage.
Olivier

[5natacha]

Merci beaucoup,
Olivier a raison mon problème vient du fait que mes variables ont le même nom entre les 2 tables.
Comment fait t-on pour renommer des variables de manière automatique .
Ex: on rajoute "_06".
Bonne journée et merci d'avance.
Natacha

[olivier.decourt]

Bonjour.
A ma connaissance, pas de solution vraiment totalement simple. Un peu de macro-langage est nécessaire : on liste les variables de la table (sauf l'identifiant) avec une proc CONTENTS et ensuite on construit les couples ancien nom = nouveau nom avec _06 à la fin. On stocke ces couples dans une macro-variable qui sert ensuite à faire le RENAME nécessaire.

Code :

1
2
3
4
5
6
7
8
9
10
11
Proc CONTENTS DATA=sasuser.cohortes2 (DROP=idet)
          NOPRINT OUT=work.dico2 ;
run;
PROC SQL NOPRINT ;
  SELECT CATS(name,"=","name","_06")
    INTO : listeRename SEPARATED BY " "
  FROM work.dico2 ;
QUIT ;
PROC SORT DATA=sasuser.cohortes2 (RENAME=(&listeRename)) ;
  BY idet ;
RUN ;

Bon courage.
Olivier

[5natacha]

Merci beaucoup pour le code car j'avoue que c'est pas très simple.
Mais j'ai compris le principe.
Encore merci bonne journée.
Natacha

[olivier.decourt]

Je rectifie mon code posté un peu vite : pas de guillemets autour de NAME dans les formules.

Code :

1
2
3
4
5
PROC SQL NOPRINT ;
  SELECT CATS(name,"=",name,"_06")
    INTO : listeRename SEPARATED BY " "
  FROM work.dico2 ;
QUIT ;

[5natacha]

Olivier, j'ai effectué ton code c'est génial cela fonctionne mais en fait je voudrais que dans ma nouvelle table cohorte3, les variable de la table cohorte2 soient visibles grace à "_06". Et en fait avec ton code j'arrive à faire un merge et cela fonctionne mais je ne distingue plus le "_06".
Je ne sais pas si je suis très claire!!
Merci d'avance

[olivier.decourt]

J'imagine que c'est parce que les labels, eux, sont restés les mêmes. Si tu vas dans le menu VIEW > COLUMN NAMES tu devrais avoir les noms de variables en tête de colonne (je suppose que tu n'es pas dans SAS Enterprise Guide).
Est-ce que c'est ça le problème ? Sinon je ne vois pas.

[5natacha]

Bonjour,
c'est exactement ça , le "name" a été modifié mais pas le "label".
J'ai tenté de remplacer le "name" par "label" dans ton code mais dommage ça fonctionne pas! Trop simple.
Merci d'avance.
Natacha

[olivier.decourt]

Voici donc la nouvelle version qui changer aussi les labels en mettant "2006" au début de ceux-ci.

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
Proc CONTENTS DATA=sasuser.cohortes2 (DROP=idet)
          NOPRINT OUT=work.dico2 ;
run;
PROC SQL NOPRINT ;
  SELECT CATS(name,"=",name,"_06"),
             CATS(name,"_06 = ")!!QUOTE(CATS("2006 : ", COALESCE(label,name)))
    INTO : listeRename SEPARATED BY " ",
           : listeLabels  SEPARATED BY " "
  FROM work.dico2 ;
QUIT ;
PROC SORT DATA=sasuser.cohortes2 (RENAME=(&listeRename)) ;
  BY idet ;
  LABEL &listeLabels ;
RUN ;

Un peu plus tordu, surtout que j'ai voulu prévoir le cas où la variable n'avait pas de label (d'où le COALESCE).
J'espère que ça fera ce que tu veux.
Olivier

[5natacha]

Merci beaucoup ça fonctionne.
Bonne apres midi.
Natacha