extraction chaine et multiplier la valeur restante suivant la partie extraite

[djam68]

Bonjour,

je vous expose mon problème j'ai une colonne avec des cellules qui contiennent des valeurs comme le tableau suivant
99.28ppm
1.2448wt%
8.49
mon but etant si la cellule contient ppm multiplier la valeur par 10 et supprimer ppm
si la valeur contient wt% multiplier la valeur par 100 et supprimer wt%
si la cellule ne contient ni wt% ni ppm passer a la suivante

merci pour votre aide

[Runsh63]

Bonjour djam68,

Dans l'hypothèse où ta première donnée se trouve en A1, alors tape en B1 :

Code :

=SI(DROITE(A1;3)="ppm";10*GAUCHE(A1;NBCAR(A1)-3);SI(DROITE(A1;3)="wt%";100*GAUCHE(A1;NBCAR(A1)-3);""))

Ca fonctionnera si ton séparateur de décimale est bien le "."
J'ai fait le test en changeant les "." par des "," puisque mon séparateur de décimale est la ",".

Tiens-moi au courant.

[jfontaine]

Bonjour,

Une autre solution

Code :

=SI(ESTERREUR(TROUVE("ppm";A1));SI(ESTERREUR(TROUVE("wt%";A1));A1;GAUCHE(A1;TROUVE("wt%";A1)-1)*100);GAUCHE(A1;TROUVE("ppm";A1)-1)*10)

[smar6ty4]

Hello,
J'avais réfléchi ... un peu plus compliqué pour avoir un résultat en format nombre ce qui donnait avec la première donnée en A2:

Code :

SI(DROITE(A2;3)="ppm";CNUM(GAUCHE(A2;NBCAR(A2)-3))*10;SI(DROITE(A2;3)="wt%";CNUM(GAUCHE(A2;NBCAR(A2)-3))*100;CNUM(A2)))

Formule à tirer vers le bas.

++
Smar6ty4

[Runsh63]

Une formule pour éviter le #VALEUR du éventuellement au "." comme séparateur de décimal :

Code :

=SI(DROITE(A1;3)="ppm";10*GAUCHE(SUBSTITUE(A1;".";",");NBCAR(A1)-3);SI(DROITE(A1;3)="wt%";100*GAUCHE(SUBSTITUE(A1;".";",");NBCAR(A1)-3);""))