VBA Excel - Modification du menu contextuel [Résolu]

[FreeZf]

Bonjour,

je cherche à créer et gérer des menus contextuels en macro VBA sous Excel.

J'arrive à modifier le menu contextuel (créer/ajouter des champs), mais je ne parviens pas à ajouter un menu dans ce menu.

Pour être plus clair :

Code :

   ShortcutMenus(xlWorksheetCell).MenuItems.AddMenu Caption:="TOTO", before:=1

Me crée bien un menu "TOTO" dans le menu contextuel, mais comment faire pour modifier ce nouveau menu et y ajouter/supprimer des choses ?

Merci à tous ceux qui pourrons m'aider.

[ctac_]

Bonjour,

Un petit exemple

Code :

1
2
3
4
5
6
7
8
9
10
Sub test()
    Dim LeMenu As Menu
    Set LeMenu = ShortcutMenus(xlWorksheetCell).MenuItems.AddMenu(Caption:="TOTO", before:=1)
    LeMenu.MenuItems.Add "TRUC", "LeCouCou"
    Set LeMenu = Nothing
End Sub
 
Sub LeCouCou()
    MsgBox "CouCou"
End Sub

Cordialement

ctac

[patricktoulon]

bonjour

je n'ai pas bien compris ton besoins alors je t'ai fait deux exemple

le premier ajoute un bouton nommé "toto" dans le menu contextuel des cellules

et le 2 eme ajoute un popup "menu toto"avec plusieurs boutons

voici les codes

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
 
'exemple pour créer unbouton  dans le menu contextuel des cellules
Sub Creation_d_un_bouton_simple__dans_menu_contextuel()
    resetmenu
    Dim Cbut As CommandBarButton
    Dim MaBarre As CommandBar
    resetmenu
    'on détermine la command bar que l'on veux modifier
    Set MaBarre = Application.CommandBars("cell")
    'on y ajoute un bouton "toto"
    Set Cbut = MaBarre.Controls.Add(Type:=msoControlButton)
    With Cbut
        .FaceId = 326    '<-- bouton avec icône + texte
        .Caption = "TOTO 1"    '<-- label du bouton
        .OnAction = "macro_simple_1"    ' appel a sa macro associée
    End With
 
End Sub

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
 
'***************************************************************************
'***************************************************************************
'exemple pour créer un menu avec plusieur item dans le menu contextuel des cellules
 
Sub Creation_menu_popup_avec_plusieurs_boutons_dans_menu_contextuel()
    resetmenu
    Dim Cpop1 As CommandBarPopup
    Dim Cbut As CommandBarButton
    Dim MaBarre As CommandBar
    resetmenu
 
    Set MaBarre = Application.CommandBars("cell")
    'on ajoute le popup qui va comporté tout les boutons
    Set Cpop1 = MaBarre.Controls.Add(msoControlPopup)
    With Cpop1
        ' on nomme le popup
        .Caption = "MENU DE TOTO"    '<-- label du sous-menu
 
    End With
 
    ' on ajoute le bouton au popup
    Set Cbut = Cpop1.Controls.Add(Type:=msoControlButton)
    With Cbut
        .FaceId = 326    '<-- bouton avec icône + texte
        .Caption = "TOTO 1"    '<-- label du bouton
        .OnAction = "MACROTOTO_1"    ' appel a la macro associée
    End With
 
    'on repete l'operation ----((with cbut end with)))---- autant de fois que l'on veut de boutons
 
    Set Cbut = Cpop1.Controls.Add(Type:=msoControlButton)
    With Cbut
        .FaceId = 326    '<-- bouton avec icône + texte
        .Caption = "TOTO 2"    '<-- label du bouton
        .OnAction = "MACROTOTO_2"
    End With
 
 
End Sub

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
 
'ici les macros associées
Sub macro_simple_1()
    MsgBox "vous venez de " & vbCrLf & "cliquer sur le  bouton toto du menu simple"
 
End Sub
 
 
Sub MACROTOTO_1()
    MsgBox "vous venez de " & vbCrLf & "cliquer sur le 1 er  bouton du menu TOTO"
 
End Sub
 
Sub MACROTOTO_2()
    MsgBox "vous venez de " & vbCrLf & "cliquer sur le 2 eme bouton du menu TOTO"
End Sub
 
 
 
'on remet le menu contextuel d'origine .faire apel a cette macro a la fermeture du fichier
Sub resetmenu()
    Application.CommandBars("cell").Reset
End Sub

voila cela devrait faire ton boheur

au plaisir

[FreeZf]

Merci pour vos réponses, c'est parfait !