[XL-2003] Exporter chaque feuille d'un classeur au format texte [Résolu]

[domiq44]

Bonjour,

Je suis en train d'écrire une macro dans une classeur Excel outils appelé "outils.xls".

Il faut savoir aussi que je suis une bille en Excel

Cette macro est codée dans l'évènement "Workbook_Open()".

Cette feuille sera placée dans le répertoire où se trouvera un classeur contenant plusieurs onglets contenant des données indépendantes.

Le but de cette macro est de sauver les données de chaque feuille au format texte. En double-cliquant sur la feuille Excel "outils.xls", ça créera un fichier texte par feuille.

Voilà ce que j'ai fait :

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
 
Private Sub Workbook_Open()
 
    Dim repertoire As String
    Dim classeur As String
    Dim feuille As Object
 
    repertoire = "C:\temp\"
    classeur = "datas.xls"
 
    Set appExcel = CreateObject("Excel.Application")
    appExcel.Workbooks.Open Filename:=repertoire + classeur
 
    For Each feuille In appExcel.Sheets
        'MsgBox feuille.Name
 
        feuille.Select
        feuille.Copy
 
        Application.DisplayAlerts = False
        ActiveWorkbook.SaveAs Filename:=repertoire + feuille.Name, FileFormat:=xlText, CreateBackup:=False
        Application.DisplayAlerts = True
 
        feuille.Activate
    Next feuille
 
    appExcel.Workbooks.Close
 
End Sub

Hélas, ça ne fonctionne pas

Ca créé bien des fichiers texte, mais vides
Et en plus, ça ouvre autant de classeurs que de feuille, contenant les données ?

Quelque'un peut-il m'aider ?

Merci.

[ZebreLoup]

Le problème est que ActiveWorkbook est ton classeur "outils.xls". Je corrige ton code et t'envoie ça.

[ZebreLoup]

Voilà, essaie voir si ça marche :

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
Private Sub Workbook_Open()
    Dim repertoire As String
    Dim classeur As String
    Dim feuille As Worksheet
 
    repertoire = "C:\temp\"
    classeur = "datas.xls"
 
    Set appexcel = CreateObject("Excel.Application")
    appexcel.Workbooks.Open Filename:=repertoire + classeur
 
    For Each feuille In appexcel.Workbooks.Sheets
        Application.DisplayAlerts = False
        feuille.SaveAs Filename:=repertoire + feuille.Name, FileFormat:=xlText, CreateBackup:=False
        Application.DisplayAlerts = True
    Next feuille
 
    appexcel.Workbooks.Close
    Set appexcel = Nothing
End Sub

[Access Newbie]

bonjour,

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
Sub test()
 
    Dim repertoire As String
    Dim classeur As String
    Dim feuille As Object
 
    repertoire = "c:\temp\"
 
    For Each feuille In Sheets
        'MsgBox feuille.Name
 
        feuille.Select
 
        Application.DisplayAlerts = False
        ActiveWorkbook.SaveAs Filename:=repertoire + feuille.Name & ".txt", FileFormat:=xlText, CreateBackup:=False
        Application.DisplayAlerts = True
 
    Next feuille
 
End Sub

Ce code exporte chaque feuille du classeur actif, je vous laisse l'adapter si besoin.

Bonne journée.

[mercatog]

Pourquoi créer une nouvelle instance Excel?
Aussi, le mieux de travailler avec la variable Wbk

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Dim Repertoire As String, Classeur As String
Dim Feuille As Worksheet
Dim Wbk As Workbook
 
Repertoire = "C:\temp\"
Classeur = "datas.xls"
Application.ScreenUpdating = False
Set Wbk = Workbooks.Open(Filename:=Repertoire & Classeur)
For Each Feuille In Wbk.Worksheets
    Feuille.Copy
    Application.DisplayAlerts = False
    ActiveWorkbook.SaveAs Filename:=Repertoire & Feuille.Name, FileFormat:=xlText, CreateBackup:=False
    Application.DisplayAlerts = True
    ActiveWorkbook.Close False
Next Feuille
Wbk.Close False
Set Wbk = Nothing

[ZebreLoup]

Oui, d'accord avec Mercatog, tu peux utiliser l'instance courante d'Excel sans problème.
Mais du coup, il vaut peut-être mieux utiliser wbk au lieu de activeWorkbook et ne pas le fermer dans la boucle, non ?
Un Select plutôt qu'un copie suffirait également.
Et pour faire encore plus simple, comme dans mon code plus haut, il me semble qu'on peut utiliser saveas directement sur l'objet worksheet

[mercatog]

Non

Quand on fait

Code :

Feuille.Copy

un nouveau classeur se crée et devient le classeur active qu'on sauvegarde au format text et on ferme

Le code fait ceci

à l'ouverture d'un classeur (où est écrit le code), un 2ème classeur est ouvert (datas.xls), instancié dans la variable Wbk.
On parcourt toutes les feuilles de Wbk

Code :

For Each Feuille In Wbk.Worksheets

On copie chaque feuille

Code :

Feuille.Copy

Cette ligne nous crée un 3ème classeur qui devient actif qu'on enregistre au format texte et on ferme et repart vers la feuille suivante.

J'ai des redondances dans l'explication mais essaie de faire le pas à pas (F8) tu sauras.

[domiq44]

Envoyé par mercatog

Pourquoi créer une nouvelle instance Excel?
Aussi, le mieux de travailler avec la variable Wbk

Merci mercatog, ça fonctionne parfaitement

Voici le code final :

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
 
Private Sub Workbook_Open()
 
Dim Repertoire As String, Classeur As String
Dim Feuille As Worksheet
Dim Wbk As Workbook
 
Repertoire = "C:\temp\"
Classeur = "datas.xls"
 
Application.ScreenUpdating = False
Set Wbk = Workbooks.Open(Filename:=Repertoire & Classeur)
 
For Each Feuille In Wbk.Worksheets
    Feuille.Copy
    Application.DisplayAlerts = False
    ActiveWorkbook.SaveAs Filename:=Repertoire & Feuille.Name, FileFormat:=xlText, CreateBackup:=False
    Application.DisplayAlerts = True
    ActiveWorkbook.Close False
Next Feuille
 
Wbk.Close False
Set Wbk = Nothing
 
End Sub

Merci aussi à ZebreLoup et à Access Newbie pour votre aide

[domiq44]

Bonjour,

Le poste est bien résolu mais j'ai encore une toute dernière chose à vous demander.

Je voudrais que le classeur "outils.xsl" se ferme après traitement.
J'ai donc ajouté ceci

Code :

1
2
3
4
5
6
7
 
...
Wbk.Close False
Set Wbk = Nothing
Workbooks.Close
 
End Sub

Le classeur est bien fermé, mais Excel est toujours ouvert.

Y a-t-il un moyen pour que Excel se ferme aussi?
Merci.

[domiq44]

Je crois avoir trouvé

Il ne faut pas fermer le classeur "outils" car sinon, la macro ne tourne plus.

Je ferme donc toutr simplement Excel en faisant comme ceci à la fin de la fonction:

Code :

1
2
3
4
5
6
7
 
...
Wbk.Close False
Set Wbk = Nothing
 
' On ferme Excel
Application.Quit