transparence sur perte focus [Résolu]

[lakhdar16]

Bonjour,

je voulais appliquer la transparence sur mon formulaire lors de perte focus mais ca marche pas ??? mais si je fais le même code sur ouverture par exemple, ça marche, pourriez-vous m'aider s'il vous plait?

déclarations:

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Private Const WS_EX_LAYERED = &H80000
Private Const LWA_ALPHA = &H2
Private Const GWL_EXSTYLE = &HFFEC
Private Declare Function SetWindowLong Lib "user32" Alias "SetWindowLongA" _
(ByVal hwnd As Long, _
ByVal lngWinIdx As Long, _
ByVal dwNewLong As Long) As Long
 
Private Declare Function GetWindowLong Lib "user32" Alias "GetWindowLongA" _
(ByVal hwnd As Long, _
ByVal lngWinIdx As Long) As Long
 
Private Declare Function SetLayeredWindowAttributes Lib "user32" _
(ByVal hwnd As Long, _
ByVal crKey As Integer, _
ByVal bAlpha As Integer, _
ByVal dwFlags As Long) As Long

sur perte Focus:

Code :

1
2
3
4
5
6
Private Sub Form_LostFocus()
Dim lAlpha As Long
lAlpha = 255 * (20 / 100)
    SetWindowLong Me.hwnd, GWL_EXSTYLE, GetWindowLong(Me.hwnd, GWL_EXSTYLE) Or WS_EX_LAYERED
    SetLayeredWindowAttributes Me.hwnd, 0, lAlpha, LWA_ALPHA
End Sub

j'ajoute que le formulaire est en fenêtre indépendante.

merci à vous.

[Access Newbie]

Bonjour,

Quel est le but recherché ? pourquoi voulez-vous mettre le formulaire en transparence ? Est-ce pour empecher l'utilisateur de quitter la fenetre tant que la saisie n'est pas validée ? autre chose ?

[lakhdar16]

Bonjour,

le formulaire principale fait appel à d'autres formulaires indépendants, le but c'est plutôt esthétique , je veux, quand j'appelle un formulaire, le formulaire principal devient transparent et inaccessible (perte focus).

merci.

[Domi2]

Tu as vérifié que l'événement sur Perte focus se produit ?

Simplement en essayant d'afficher un message.

[lakhdar16]

Bonjour,

si j'ai vérifié, et ca marche pas, mais si je fais le même code sur ouverture par exemple il marche?? la j'ai pas compris.

merci.

[Domi2]

Je ne suis pas sûr d'avoir bien compris.

Tu as un formulaire ouvert et tu en ouvres un deuxième, en voulant que le premier devienne transparent, c'est ça ?

[lakhdar16]

Bonjour,

oui c'est exactement ça, et sur réception focus il redeviens normal

Code :

lAlpha = 255 * (100/ 100)

merci.

[Domi2]

Je ne suis toujours pas convaincu que l'événement Sur perte focus se produise (et je ne peux pas tester).

D'autre part, Me.hwnd est le descripteur de la fenêtre active, et ton premier formulaire ne l'est probablement plus.

Il faudrait peut-être essayer de récupérer la valeur dans une variable globale et essayer de la passer comme ça aux fonctions.

Ce n'est qu'une idée.

[lakhdar16]

Excusez moi, pourriez-vous être plus clair ? là, je suis perdu.

Merci.

[Domi2]

Ayant retrouvé un poste de travail avec Access, j'ai pu faire quelques tests.

Tu n'as certainement pas bien vérifié tes événements, j'ai tout essayé, je n'arrive pas à faire survenir l'événement Sur perte focus du premier formulaire.

J'ai donc fait comme ceci :

Propriété Fen indépendante des 2 formulaires = Oui

Dans l'entête d'un module standard et non celui d'un formulaire, on déclare les 3 constantes et on met les 3 fonctions, le tout comme Public et non Private.

On déclare également une variable publique supplémentaire, lngDescripteur.

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
 
Option Compare Database
Option Explicit
 
Public Const WS_EX_LAYERED = &H80000
Public Const LWA_ALPHA = &H2
Public Const GWL_EXSTYLE = &HFFEC
 
Public Declare Function SetWindowLong Lib "user32" Alias "SetWindowLongA" _
(ByVal hwnd As Long, _
ByVal lngWinIdx As Long, _
ByVal dwNewLong As Long) As Long
 
Public Declare Function GetWindowLong Lib "user32" Alias "GetWindowLongA" _
(ByVal hwnd As Long, _
ByVal lngWinIdx As Long) As Long
 
Public Declare Function SetLayeredWindowAttributes Lib "user32" _
(ByVal hwnd As Long, _
ByVal crKey As Integer, _
ByVal bAlpha As Integer, _
ByVal dwFlags As Long) As Long
 
Public lngDescripteur As Long

Dans l'événement Sur chargement du formulaire 1, on récupère le descripteur de sa fenêtre et on l'affecte à la variable lngDescripteur.

Code :

1
2
3
4
5
Private Sub Form_Load()
 
    lngDescripteur = Me.hwnd
 
End Sub

Dans l'événement Sur ouverture du formulaire 2, on fait appel aux fonctions en passant non pas le descripteur de la fenêtre active, mais celui du formulaire 1.

Code :

1
2
3
4
5
6
7
8
9
Private Sub Form_Open(Cancel As Integer)
 
    Dim lAlpha As Long
 
    lAlpha = 255 * (50 / 100)
    SetWindowLong lngDescripteur, GWL_EXSTYLE, GetWindowLong(lngDescripteur, GWL_EXSTYLE) Or WS_EX_LAYERED
    SetLayeredWindowAttributes lngDescripteur, 0, lAlpha, LWA_ALPHA
 
End Sub

Et la même chose dans l'événement Sur fermeture du formulaire 2, en supprimant la transparence.

Code :

1
2
3
4
5
6
7
8
9
Private Sub Form_Close()
 
    Dim lAlpha As Long
 
    lAlpha = 255 * (100 / 100)
    SetWindowLong lngDescripteur, GWL_EXSTYLE, GetWindowLong(lngDescripteur, GWL_EXSTYLE) Or WS_EX_LAYERED
    SetLayeredWindowAttributes lngDescripteur, 0, lAlpha, LWA_ALPHA
 
End Sub

Très bel effet !

[lakhdar16]

waaaaaaaawwwwwwwwww c'est EXCELLENTTTTTTT

ça marche nickel et chui trés heureux , un grand merci pour vous Domi2

Je vais mettre Résolu afin que d'autres personnes peuvent l'utiliser.

mes respects.

merci encore