Somme des cellules des lignes multiples de x

[popol333]

Re bonjour a tous!


Est ce qu'il y aurait une fonction EXCEL sans utiliser VBA qui fait la somme de tt les cellules multiples?

ex: C4+C8+C12+C16+...C...=?

Merci beaucoup!

[jfontaine]

Bonjour,

Pas beaucoup d'idée si ce n'est de préciser la liste des lignes dans la fonction Transpose

Code :

=SOMMEPROD((LIGNE($C$1:$C$28)=TRANSPOSE({4;8;12;16;20;24}))*$C$1:$C$28)

EDIT : ou en mettant la liste des lignes dans une colonne (ici de K1 à K5)

Code :

=SOMMEPROD((LIGNE($C$1:$C$28)=TRANSPOSE(K1:K5))*$C$1:$C$28)

Formule Matricielle a valider par CTRL + SHIFT + ENTREE

[popol333]

Merci. J'ai reussi a faire un truc qui s'en rapproche en utilisant somme.si

[Pierre Fauconnier]

Salut.

En validation matricielle (MAJ+CTRL+ENTER)

=SOMME((MOD(LIGNE(C1:C20);4)=0)*C1:C20)

fera la somme de C4;C8;C12;C16 et C20. A toi d'adapter la plage.

[mercatog]

Une autre proposition

Code :

=SOMMEPROD((MOD(LIGNE(C1:C100);4)=0)*C1:C100)

[Pierre Fauconnier]

Envoyé par mercatog

Une autre proposition

Code :

=SOMMEPROD((MOD(LIGNE(C1:C100);4)=0)*C1:C100)

Ce n'est pas faux, mais de mon analyse, c'est moins "exact"...

La syntaxe canonique de SOMMEPROD est la suivante:

SOMMEPROD(matrice1, [matrice2], [matrice3], ...)

et cette fonction calcule la somme des produits de différentes matrices numériques.

L'utilisation de cette fonction, notamment via l'assistant fonctions ou en suivant la syntaxe officielle ne permettra pas d'arriver au résultat obtenu, et ce n'est que par déviation de cette fonction et en utilisant une syntaxe officieuse que le résultat correct sera obtenu.

Je reconnais que cette syntaxe est largement utilisée, ici comme ailleurs, mais lors de mes formations, je prône l'utilisation de la somme validée en matricielle qui permet:

• d'approcher la construction de formules matricielles là où SOMMEPROD ne pourra être utilisée ;
• de ne pas utiliser des syntaxes "parallèles" et donc de pouvoir utiliser les aides à la saisie (infobulle ou assistant fonction).

Ce n'est bien entendu que mon avis. Il serait donc intéressant, si l'on souhaite donner une autre réponse pratiquement identique à une réponse déjà donnée, d'en expliquer les raisons, histoire d'apporter une contribution véritablement pertinente sur le forum .

[mercatog]

Ce n'est pas faux, mais de mon analyse, c'est moins "exact"...

Par contre toute les propositions jusqu'à présent ne sont pas fonctionnelles si au moins une donnée non numérique est dans la plage de données.

[Pierre Fauconnier]

Envoyé par mercatog

[...]
Par contre toute les propositions [...] ne sont pas fonctionnelles si au moins une donnée non numérique est dans la plage de données.

=SOMME(SI(ESTNUM(C1:C20);C1:C20;0)*(MOD(LIGNE(C1:C20);4)=0))

validée en matricielle...

On pourra y arriver avec une "troisième" syntaxe de la fonction SOMMEPROD.

Pour rappel:
- sommeprod(A;B;C) => syntaxe officielle, non fonctionnelle dans le cas présent ;
- sommeprod(A*B*C) proposée, entre autres contributeurs, par Mercatog, non fonctionnelle dans le cas présent;
- sommeprod(A*B;C) => syntaxe illustrée ci-dessous, fonctionnelle dans le cas présent.

=SOMMEPROD((MOD(LIGNE(C1:C20);4)=0)*1;C1:C20)

qui utilise un produit comme première matrice, puis la matrice à sommer comme deuxième matrice.

C'est pourquoi je préfère la somme matricielle à ce que je considère comme des bricolages qui sont malaisés à expliquer à un débutant, là où la limpidité des matricielles parle d'elle-même.

CQFD