[XL-2007] couper une partie des données dans une autre colonne [Résolu]

[ivan_isaak]

Bonjour à tous,

Je suis nouveau et totalement débutant en programmation de macro... A vrai dire, au lieu de les programmer, je les enregistre habituellement....

Enfin, cette fois, l'exercice est impossible a effectuer en enregistrement simple...

Voici un extrait de mon tableau sur excel 2007

http://www.casimages.com/img.php?i=1...2945425307.png

J'aimerais pouvoir créer une macro qui détecte automatiquement la parenthèse de la colonne E pour la couper/coller dans la colonne F. De cette manière, il ne resterait que le nom de la ville dans la colonne E.

Si quelqu'un peut m'aider ca serait vraiment sympa...

Merci

[pijaku]

Bonjour,
Déjà, je tiens à dire que ce que tu souhaites et réalisable par formule en passant par une colonne intermédiaire...
Mais bon...
Avec ce code, tu peux réaliser ce que tu souhaites :

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
Sub test()
Dim Lign As Long
Dim Chaine As String
 
With Sheets("Feuil1") ' à adapter ==> le nom de ta feuille
'de la lign 6 à 14 A ADAPTER
For Lign = 6 To 14
    'vérifie la présence d'une parenthèse ouvrante dans la cellule
    If InStr(.Cells(Lign, 5), "(") <> 0 Then
        'on stocke, dans la variable Chaine le contenu de la cellule Col E
        Chaine = .Cells(Lign, 5)
        'on extrait la partie à gauche de (
        .Cells(Lign, 5) = Left(Chaine, InStr(Chaine, "(") - 2)
        'on extrait la partie à droite de (
        .Cells(Lign, 6) = Right(Chaine, Len(Chaine) - InStr(Chaine, "(") + 1)
    End If
'ligne suivante
Next
End With
End Sub

[rvtoulon]

Bonjour,
il faut que tu utilises la fonction split.

Voici un exemple à adapter, notamment le nom de la feuille, dans le code "Feuil1".
le code recherche l'espace entre le nom de la ville et la parenthèse, coupe la chaine de caractère et la met dans un tableau. La première entrée du taleau (mtab(0)) = colonne E, la deuxième entrée (mtab(1)) = colonne F

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
Sub test()
Dim chaine As String, plage As Range
Dim mTab
 
With Sheets("Feuil1")
Set plage = .Range("E6:E" & .Range("E" & .Rows.Count).End(xlUp).Row)
End With
 
For Each c In plage
chaine = c.Value
 
If InStr(1, chaine, " ") <> 0 Then
  mTab = Split(chaine, " ")
  c.Value = mTab(0)
  c.Offset(0, 1).Value = mTab(1)
End If
 
Next c
End Sub

[ivan_isaak]

Les deux codes marchent très bien mais le premier est plus adapté à mes données car j'ai des noms de villes composés et donc avec plusieurs espaces.

Vous m'avez fais gagner un temps précieux !

merci beaucoup