[XL-2003] permettre à l'utilisateur de modifier une variable chemin sans accès au code [Résolu]

[goldfinger13]

bonjour à tous
je vous sollicite car je n'ai pas réussi a trouver la solution à mon problème/
afin de faciliter l'implantation de mon fichier sur différents sites je souhaiterais pouvoir donner la possibilité aux utilisateurs de modifier la variable chemin sans qu'il puisse toutefois accéder au code ( par l'intermédiaire d'une box ?)
quelqu'un peut 'il m'aider à résoudre

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
 
Sub initialiser()
Dim fso As Object, x, y, z As Boolean
Dim chemin As Variant
chemin = "N:\documents\"   'c'est ici que devrait s'opérer le choix
Set fso = CreateObject("Scripting.FileSystemObject")
x = fso.FileExists(chemin & "Export1.xls")
y = fso.FileExists(chemin & "Export2.xls")
z = fso.FileExists(chemin & "Export3.xls")
If x = False Then MsgBox " Le fichier Export1 n'est pas présent dans " & chemin & Chr(10) & Chr(10) & _
"Veuillez le rajouter et recommencer la procédure"
If x = False Then Exit Sub
If y = False Then MsgBox " Le fichier Export2 n'est pas présent dans " & chemin & Chr(10) & Chr(10) & _
"Veuillez le rajouter et recommencer la procédure"
If y = False Then Exit Sub
If z = False Then MsgBox " Le fichier Export3 n'est pas présent dans " & chemin & Chr(10) & Chr(10) & _
"Veuillez le rajouter et recommencer la procédure"
If z = False Then Exit Sub

merci d'avance pour votre aide

[mercatog]

Code :

1
2
3
4
5
6
7
8
9
10
11
12
Dim Chemin As String
 
With Application.FileDialog(msoFileDialogFolderPicker)
    .Show
    If .SelectedItems.Count > 0 Then Chemin = .SelectedItems(1)
End With
If Chemin <> "" Then
    Chemin = Chemin & "\"
    MsgBox Chemin
    'ton code
 
End If

[kiki29]

Salut, ces chemins sont-ils à conserver de session en session ? si oui, passer par une feuille cachée ou les choix seront conservés ou un fichier "*.ini"

Voir aide en ligne sur GetOpenFilename

[goldfinger13]

re bonjour,
en fait pour mieux préciser je souhaiterais que le choix soit donné lors de l'installation du fichier et qu'ensuite les données soient conservées j'ai bien regardé l'aide mais je suis un peu perdu sinon ta solution Mercatog fonctionne à merveille mais oblige l'utilisateur à recherche le chemin à chaque fois.
kiki pourrais tu m’aiguiller un peu plus
@+

[mercatog]

Ajoute une feuille que tu nomme Temp (éventuellement cache la). Dans cette feuille on va écrire notre chemin (avec la possibilité de le changer)

PS: J'ai utilisé Dir dans la 2ème partie du code, tu peux aussi utiliser ta méthode

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
Sub Initialiser()
Dim Chemin As String, Msg As String, Rep As String
Dim Choix As Byte, k As Byte
Dim Er As Boolean
 
Rep = Worksheets("Temp").Range("A1")
Choix = MsgBox("Voulez vous changer le répertoire?", vbYesNo)
 
'On choisit de changer le répertoire si:
'1. le chemin n'a pas été sauvegardé dans la feuille Temp
'2. le répertoire est inexistant
'3. par choix de l'utilisateur
If Rep = "" Or Dir(Rep & "*.*") = "" Or Choix = vbYes Then
    With Application.FileDialog(msoFileDialogFolderPicker)
        .Show
        If .SelectedItems.Count > 0 Then Chemin = .SelectedItems(1)
    End With
End If
 
If Chemin <> "" Then
    Chemin = Chemin & "\"
    Worksheets("Temp").Range("A1") = Chemin
Else
    Chemin = Rep
End If
 
If Chemin <> "" Then
    Msg = "Le(s) fichier(s) suivant(s) est (sont) absent(s) du répertoire " & Chemin & " :" & vbCrLf
    For k = 1 To 3
        If Dir(Chemin & "Export" & k & ".xls") = "" Then
            Er = True
            Msg = Msg & "    - Export" & k & vbCrLf
        End If
    Next k
 
    Msg = IIf(Er, Msg & "Veuillez le(s) rajouter et recommencer la procédure.", "Tout est ok")
    MsgBox Msg
End If
End Sub

[goldfinger13]

Milles MERCI Mercatog
mon problème est résolu .