[ODS] ODS HTML : paramétrer les couleurs des lignes [Résolu]

[ash_rmy]

Bonjour tout le monde,

Comment mettre dans ma sortie Html la seconde ligne en bleu (X=B) et la troisième ligne en jaune (X=C) SVP. Merci.

Code :

1
2
3
4
5
6
7
8
9
10
11
DATA WORK.TEMP;
        X = 'A'; Y = 2; OUTPUT;
        X = 'B'; Y = 2; OUTPUT;
        X = 'C'; Y = 2; OUTPUT;
RUN;
 
FILENAME ODSOUT 'C:\TEMP';
ODS HTML PATH = ODSOUT BODY = 'TEMP.HTML';
        PROC PRINT DATA = WORK.TEMP NOOBS N= "NOMBRE TOTAL DE VARIABLES = ";
        RUN;
ODS HTML CLOSE;

ash_rmy

[olivier.decourt]

Bonjour.
La procédure PRINT propose de la mise en forme par cellule.
Tu peux te tourner vers la proc REPORT, qui pour faire un listing simple, n'est pas beaucoup plus complexe. Et tu fais des CALL DEFINE sous condition.

Code :

1
2
3
4
5
6
7
8
9
10
PROC REPORT DATA=sashelp.class NOWD ;
  COLUMNS name age sex ;
COMPUTE sex ;
  SELECT (sex);
    WHEN ("F") CALL DEFINE (_ROW_,"STYLE","STYLE=[BACKGROUND=PINK]");
    WHEN ("M") CALL DEFINE (_ROW_,"STYLE","STYLE=[BACKGROUND=CYAN]");
    OTHERWISE ;
  END ;
ENDCOMP ;
RUN ;

Bon courage.
Olivier

[ash_rmy]

Merci Olivier ! ça marche !