[XL-2003] Formule avec SI [Résolu]

[danbenzi]

Bonjour à tous,

J'ai cette formule:

Code :

SI(B42="Sam";6;SI(B42="Dim";6;31))

Est-ce que c'est possible d'inclure quelque chose qui indique lorsqu'il y a un jour férié il y aura un 6?

La formule se trouve colonne F.

Merci de votre aide.
Dan

[Alqualonde]

Bonjour !

As-tu déjà identifié les jours fériés dans ta colonne B ou dans une autre colonne ? Si oui il suffit de rajouter une condition dans ton SI.

Sinon, il existe un algorithme permettant de calculer les jours fériés mobiles...

[JOHN14]

Bonjour,
pourquoi ne pas essayer :

Code :

SI(OU(B42="Sam";B42="Dim";F42="Férié");6;31)

[danbenzi]

Bonjour à tous,

Merci pour vos réponses.
J'avais déjà essayé la formule que tu m'a donné John14, mais cela ne fonctionne pas.
J'ai identifié les jours fériés Alqualonde dans la colonne A de A50 à A60.
C'est de créer la condition qui me pose problème. J'ai tenté quelque chose uniquement dans la cellule F4 au début mais lorsque j'utilise la liste déroulante en haut à gauche, le jour reste fixe. J'ai du loupé une étape.

Je renvoie le fichier sans protection, si cela peut servir.

Cordialement
Dan

[hben1961]

Bonjour à tous,

Mets en F4 la formule matricielle suivante:

Code :

=SI(OU(INDIRECT(ADRESSE(42;LIGNES($1:2)))="Sam";INDIRECT(ADRESSE(42;LIGNES($1:2)))="Dim";A4=$A$50:$A$60);6;31)

et recopier vers le bas...


NB: La formule peut être simplifiée en formule (toujours matricielle):

Code :

=SI(OU(INDIRECT(ADRESSE(42;LIGNES($1:2)))={"Sam";"Dim"};A4=$A$50:$A$60);6;31)

Cordialement

[danbenzi]

Bonjour hben,

Merci pour ta réponse. J'ai fais ce que tu m'as dit mais j'ai "Valeur" dans la cellule. J'ai essayé autre solution, là je bloque.

Cordialement
Dan

[hben1961]

Bonjour à tous, bonjour danbenzi

Tu as dû oublier de valider la formule matricielle par CTRL+MAJ+ENTREE...

Cordialement

[Alqualonde]

Rebonjour,

Sans formule matricielle tu peux aussi utiliser la formule suivante :

Code :

=SI(OU(JOURSEM(A4;2)=6;JOURSEM(A4;2)=7);6;SI(SOMMEPROD((A$50:A$60=A4)*1);7;31))

L'utilisation de la fonction JOURSEM te permet de ne plus avoir à utiliser des cellules intermédiaires qui te déterminent "Sam", "Dim"... mais à utiliser directement la date de la cellule A4 (et des cellules suivantes en tirant la formule)

Quant à la fonction SOMMEPROD, elle permet de vérifier que la date contenue dans la cellule de la première colonne (dans mon exemple issu de ton fichier la cellule A4) figure dans la liste des jours fériés présente dans les cellules A50 à A60 (tu as d'ailleurs omis Noël, c'est normal ?).

Pour l'exemple j'ai mis des 6 pour les samedis et dimanches, des 7 pour les jours fériés de semaine et 31 sinon. Mais c'est bien entendu modifiable !

[Daranc]

as tu regarder la fonction serie.jour.ouvre ?

[danbenzi]

Bonjour à tous,

Hben, à vrai dire, je n'ai pas oublié de valider la formule, je ne savais pas qu'il fallait faire CTRL+MAJ+ENTREE. J'ai appris quelque chose. Merci pour ta formule car cela fonctionone.

Merci également Alqualonde car ta formule fonctionne aussi et en plus avec des explications cela facilite la compréhension. (j'ai zappé en effet le 25 décembre).

Ces deux formules vont bien me servir.

Cordialement
Dan