[XL-2007] création de formule complexe [Résolu]

[cess2308]

Bonjour,

je suis nouvelle sur le forum et j'aurai aimé avoir de l'aide.

voila la situation :

Dans un classeur Excel 2007, j'ai 4 feuilles: FEUILLE RECAP MATCH,CHAMPIONNAT, COUPE et SANCTIONS CHAMPIONNAT

La FEUILLE RECAP MATCH est une feuille de synthèse regroupant certaines informations des feuilles CHAMPIONNAT et COUPE

Dans CHAMPIONNAT et COUPE, je rentre toutes les informations concernant les matchs de football (composition, date, cartons, buts et commentaire)

Dans SANCTIONS CHAMPIONNAT, j'ai créé un tableau :

Colonne A : Prénom
Colonne B :CJ
Colonne C :CR

et j'ai fais ça par mois


J'aurais aimé que pour SEPTEMBRE, additionner le nombre de carton jaune (CJ) en fonction du prénom et de la date des matchs qui sont dans CHAMPIONNAT

idem pour les cartons rouges

Je n'arrive pas a créer une formule pour effectuer sa.

donc quelle formule utiliser ?

[cess2308]

oups.... j'ai oublier de joindre mon tableau

MATCH.zip

[Daniel.C]

toutes les informations concernant les matchs de football

MAIS ??? t'es une fille ??

OK, je sors. J'ai pas pu m'en empêcher (de toutes façons, vu ce que les hommes ont fait en AFS...)

Sérieusement on s'occupe de ta formule.

[Daniel.C]

Pour me faire pardonner :
J'ai dû ajouter une formule dans la colonne H de la feuille "CHAMPIONNAT" (tu peux masquer la colonne). A partir de H6 :

Code :

=SI(ESTNUM(G6);MOIS(G6);H5)

à recopier vers le bas. Ensuite, j'ai remplacé les mois de la feuille "SANCTIONS CHAMPIONNAT" par une formule :
en B10 :

Code :

=MAJUSCULE(TEXTE("01/8/11"*1;"mmmm"))

en C10 :

Code :

=MAJUSCULE(TEXTE("01/9/11"*1;"mmmm"))

etc.

En B13 :

Code :

=SOMMEPROD((CHAMPIONNAT!$H$6:$H$639=MOIS(DATEVAL("1 "&$B$10)))*(CHAMPIONNAT!$B$6:$B$639=$A13);CHAMPIONNAT!$C$6:$C$639)

à recopier vers le bas.

En C13 :

Code :

=SOMMEPROD((CHAMPIONNAT!$H$6:$H$639=MOIS(DATEVAL("1 "&$B$10)))*(CHAMPIONNAT!$D$6:$D$639=$A13);CHAMPIONNAT!$C$6:$C$639)

A cause des cellules fusionnées dans le titre, je n'ai pas trouvé de moyen de recopier les formules sans les modifier. Il faudra que tu remplaces B10 par la cellule appropriée.

[Daniel.C]

Au temps pour moi; en utilisant :

Code :

=SOMMEPROD((CHAMPIONNAT!$H$6:$H$639=MOIS(DATEVAL("1 "&B$10)))*(CHAMPIONNAT!$B$6:$B$639=$A13);CHAMPIONNAT!$C$6:$C$639)

en B13 et :

Code :

=SOMMEPROD((CHAMPIONNAT!$H$6:$H$639=MOIS(DATEVAL("1 "&B$10)))*(CHAMPIONNAT!$D$6:$D$639=$A13);CHAMPIONNAT!$C$6:$C$639)

tu peux recopier les formules telles quelles dans les autres mois.

[Daniel.C]

Oups la formule ppour les cartons rouges est fausse; utilise :

Code :

=SOMMEPROD((CHAMPIONNAT!$H$6:$H$639=MOIS(DATEVAL("1 "&G$10)))*(CHAMPIONNAT!$B$6:$B$639=$A13);CHAMPIONNAT!$D$6:$D$639)

[cess2308]

mille merci Daniel !!!

Vos formules marche a merveille et m'enlève une épine du pied !!!

J'aurai quand même passer plus de 48h sur la recherche de ces formules!!!

[Daniel.C]

Merci du retour; marque la question comme résolue, s'il te plait, ça évite à d'autres de chercher.