Nom textbox en paramètre [Résolu]

[Chnoucky]

Hello

J'ai une bête question et google me semble pollué de réponse fantaisistes à ce sujet

J'ai un formulaire avec plein de textboxes. J'aimerais ajouter un événement à chacune de ces textboxs. Mais, ce serait ennuyant de personnaliser l'évenement pour toutes les textboxes.

Le top serait d'appeller une procédure avec le nom de la textbox en paramètre.

Code :

1
2
3
4
5
6
7
8
Private Sub TextBox1_Change()
Call MaMacro(thiscontrol.name)
End Sub

Private Sub TextBox2_Change()
Call MaMacro(thiscontrol.name)
End Sub

et

Code :

1
2
3
 
Mamacro(nom_textbox as string)
End sub

Mais je ne me rappelle plus comment faire. (ce n'est pas thiscontrol.name)

Quelqu'un a une idée ?
(et il n'y a pas moyen de mettre un évément pour tous les controls dans un formulaire ?)
Grand merci pour votre aide

[mercatog]

Bonjour
Utilise plutôt un module de classe gérant ceci.

Exemple:
On a un userform avec plusieurs TextBox, et on désire transformer les textes saisis en majuscules.

1. dans un module standard, définir une variable publique de type collection

Code :

Public Col As Collection

2. créer un module de classe nommé Classe1 avec le code suivant:

Code :

1
2
3
4
5
6
7
8
Public WithEvents TB As MSForms.TextBox
 
'Notre macro destinée à transformer le texte en majuscule
Private Sub TB_Change()
 
TB.Text = UCase(TB.Text)
'ici ta macro par rapport à TB
End Sub

3. dans l'initialize de ton userform

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
Private Sub UserForm_Initialize()
Dim Ctr As Control
Dim MaClasse As Classe1
 
Set Col = New Collection
For Each Ctr In Me.Controls
    If TypeOf Ctr Is MSForms.TextBox Then
        Set MaClasse = New Classe1
        Set MaClasse.TB = Ctr
        Col.Add MaClasse
    End If
Next Ctr
End Sub

[Chnoucky]

Génial, c'est .. la classe

Merci !