Création d'une variable de comptage [Résolu]

[craow87000]

Bonjour,

J'ai une table qui concerne la consommation médicamenteuse de patients. Mes patients correspondent aux observations et en variable j'ai des noms de médicaments. Chaque patient eput avoir un nombre différent de médicaments. J'aimerai créer une nouvelle variable m'indiquant combient de médicaments consomment les patients.
Ma table ressemble à ça :
numpatient medic1 medic2 medic3 medic4 .....
1 X Y
2 A Y C
3 B X D
....

comment faire

sous excel il me suffit de faire un tableau croisé dynamique mais là????????

merci par avance pour votre aide

[s_a_m]

Et ben là c'est la proc tabulate, mais il y a peut être plus simple.

[olivier.decourt]

Bonsoir.
SAS ne possède pas directement de fonction pour compter le nombre de variables de type texte qui sont renseignées. Par contre, si on soustrait le nombre de variables vides (comptées avec la fonction CMISS) du nombre total de variables (DIM à condition d'avoir rassemblé toutes les variables dans un Array), alors on a fait le travail.

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
DATA work.medicaments ;
INFILE DATALINES MISSOVER ;
INPUT numpatient (medic1 medic2 medic3 medic4) (:$1.) ;
DATALINES ;
1 X Y
2 A Y C
3 B X D
;
RUN ;
DATA work.nb ;
  SET work.medicaments ;
  ARRAY meds $ medic1-medic4 ;
  n = DIM(meds)-CMISS(OF meds[*]) ;
RUN ;

Bon courage.
Olivier

[craow87000]

bonjour,

c'est un peut l'idée que j'avais : je m'étais dit en "francais" dés que tu trouve une variable non renseignée alors tu attribues ce numéro à ma nouvelle variable. Je vais essayer votre solution et vous tiens au courant. Merci,

[craow87000]

j'ai essayé mais cela ne fonctionne pas, il me mets

Code :

1
2
3
4
5
6
7
8
9
10
11
 
ERROR 68-185: The FUNCTION CMISS IS unknown, OR cannot be accessed.
 
16   RUN ;
 
NOTE: The SAS System stopped processing this step because of errors.
WARNING: The DATA SET WORK.NB may be incomplete.  When this step was stopped there were 0
         observations AND 6 VARIABLES.
NOTE: DATA statement used (Total process time):
      real time           0.06 seconds
      cpu time            0.01 seconds

[craow87000]

ca doit être parce que je suis sous SAS 9.1

[olivier.decourt]

Oui, c'est une question de version. CMISS apparaît en v9.2.
Pour la 9.1 on va suivre de plus près ton idée initiale : s'arrêter dès qu'on trouve une valeur manquante.

Code :

1
2
3
4
5
6
7
8
 
DATA work.nb (DROP=i) ;
  SET work.medicaments ;
  ARRAY meds $ medic1-medic4 ;
  DO i=1 TO DIM(meds) WHILE(NOT MISSING(meds[i])) ;
  END ;
  n = i-1 ;
RUN ;

Comme il faut aller à la valeur manquante pour s'apercevoir, justement, qu'elle manque, on doit revenir en arrière de 1 en sortant de la boucle.
Bon courage.
Olivier

[craow87000]

ca fonctionne Super merci!!

[craow87000]

Bonjour,

en fait ca fonctionne mais il y a un petit soucis : c'est que pour les patients qui n'ont aucun médicament ca me met 0. Il faudrait que cela notre à la place . pour considérer comme valeur manquant dans les stat.

[olivier.decourt]

Hé bien juste avant le RUN, ajoutons

Code :

IF n=0 THEN n=. ;

Bon courage.
Olivier

[Rabie.]

Bonsoir

j'ai suivi le fil de la discussion pour exactement la même question mais malheureusement la nouvelle variable de comptage ne se crée par et une erreur apparait.

Au fait, j'ai douze variables distinctes, qui comportent les modalités (1 ou 2 ou missing). Je souhaite compter le nombre des valeurs valides pour l'ensemble des variables

exemple de mon fichier

patient ovophas1 ovophase2 ovophas3....etc... ovophase12
1 1 1 2 1
2 . 2 1 2
3 1 . . 2

Ce que je souhaite avoir à la fin pour chaque patient, le nombre des valeurs valides pour toutes les variables (ici patient 1 = 4, patient 2 =3 et patient 3 = 2).

j'ai fait exactement le même code que vous mais il y a une erreur, qui apparait, il ne reconnait pas la nouvelle variable de comptage

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
DATA ovoo; SET trialdat.Ovocytes;
keep OvoPHAS1 OvoPHAS2 OvoPHAS3 OvoPHAS4 OvoPHAS5 OvoPHAS6 OvoPHAS7    
OvoPHAS9 OvoPHAS8 OvoPHAS10 OvoPHAS11 OvoPHAS12; 
run;
 
 
DATA ovoo1 (DROP=i); SET ovoo; 
ARRAY NOMBREOVO $ OvoPHAS1-OvoPHAS12;
DO i=1 TO DIM(NOMBREOVO) WHILE(NOT MISSING(NOMBREOVO[i]));
END; 
n = i-1;
run; 
 
proc freq DATA=ovoo1; 
	TABLES NOMBREOVO ;
run;

[Rabie.]

le message est parti sans que je puisse vous remercier d'avance pour votre aide

bonne soirée à tous

[olivier.decourt]

Bonjour Rabie.
J'ai l'impression que dans ton cas les variables à compter sont numériques. Alors que dans le reste de cette discussion il s'agissait de noms de médicaments (donc du texte).
Tu peux essayer deux solutions :
1) en enlevant le $ dans ARRAY. C'est de cette manière qu'on indique que l'array contient des variables texte. Sans $ ce sont des données numériques. Un array ne peut pas contenir à la fois des variables texte et des variables numériques.
2) avec juste

Code :

1
2
3
4
DATA ovoo; 
SET trialdat.Ovocytes (keep=OvoPHAS1-OvoPHAS12);
n=N(OF OvoPHAS1-OvoPHAS12) ;
run;

à la place de ARRAY, de la boucle et de tout le reste. Compter les valeurs non manquantes numériques, c'est plus facile que les textes non vides.
Bon courage.
Olivier