boutons pour afficher images [Résolu]

[timtof2011]

bonjour tout lemonde,

j'essaye à partir d'un userForm et de deux boutons d'afficher une serie d'image dans un image1

commandBouton1 = avance
commandBouton2 = recule

image1

j'ai par exemple 3 images dans mon repertoire c:\mes photos
je souhaiterai en cliquant sur le boutons avancer les faire défiler en avant et l'inverse sur le bouton reculer...

Voilà merci pour votre aide et un bon week end à tous
Tim.

[mercatog]

Bonsoir
A adapter

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
Option Explicit
Dim Tb() As String
Dim Indx As Integer
 
Private Sub UserForm_Initialize()
Dim Chemin As String, FichImg As String
Dim i As Integer
 
Chemin = "C:\Users\user\Pictures\"
FichImg = Dir(Chemin & "*.jpg")
Do While FichImg <> ""
    i = i + 1
    ReDim Preserve Tb(1 To i)
    Tb(i) = Chemin & FichImg
    FichImg = Dir()
Loop
If UBound(Tb) >= 1 Then
    Me.Image1.Picture = LoadPicture(Tb(1))
    Indx = 1
End If
End Sub
 
Private Sub CommandButton1_Click()
 
If UBound(Tb) >= 1 Then
    Indx = IIf(Indx = UBound(Tb), 1, Indx + 1)
    Me.Image1.Picture = LoadPicture(Tb(Indx))
End If
End Sub
 
Private Sub CommandButton2_Click()
 
If UBound(Tb) >= 1 Then
    Indx = IIf(Indx = 1, UBound(Tb), Indx - 1)
    Me.Image1.Picture = LoadPicture(Tb(Indx))
End If
End Sub

[timtof2011]

Merci beaucoup Mercatog pour ce code...ça marche...depuis 16h je cherchais...

bien à vous.

Tim