ACM : macro plotit - option qui permet de mettre une couleur pour chaque variable [Résolu]

[the_special_one]

Bonjour,

Je réalise une ACM via SAS, afin d'améliorer la représentation graphique de mes variables à partir de la maco Plotit, j'aimerais savoir si vous connaissez l'option qui nous permets de mettre une couleur pour chaque variable.

A part cette macro, auriez vous une macro SAS qui me permetrait de résoudre mon soucis?

Merci

[olivier.decourt]

Bonjour.
Personnellement je n'utilise pas de macros, juste un peu de code. Si les indicatrices sont bien préparées en amont de la proc CORRESP, récupérer le nom des variables n'est pas très compliqué.

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
PROC FORMAT ;
  VALUE poids
   LOW - 110 = "< 50 kg"
   OTHER     = "> 50 kg"
  ;
  VALUE taille
   LOW - 63 = "< 1,60m"
   OTHER    = "> 1.60m"
  ;
RUN ;
PROC TRANSREG DATA=sashelp.class NOPRINT DESIGN ;
  MODEL CLASS(sex age weight height/ZERO=NONE SEP="=") ;
  FORMAT weight poids. height taille. ;
  ID name ;
  OUTPUT OUT=work.disjonctif (DROP=intercept _type_ _name_) ;
RUN ;
PROC CORRESP DATA=work.disjonctif DIMENS=%EVAL(&_trgIndN - 4)
			 OUTC=work.acm NOROW=PRINT NOCOLUMN=PRINT ;
  VAR &_trgind ;
  ID name ;
RUN ;
DATA work.VARIABLES ;
  SET work.acm (WHERE=(_type_="VAR")) ;
  var = SCAN(name,1,"=") ;
  val = SUBSTR(name,INDEX(name,"=")+1) ;
RUN ;
SYMBOL i=none v=dot h=1.5 pointlabel=("#val") ;
PROC GPLOT DATA=work.VARIABLES ;
  PLOT dim2 * dim1 = var / HREF=0 VREF=0 ;
RUN ; QUIT ;
GOPTION RESET=SYMBOL ;

Bon courage.
Olivier

[the_special_one]

Envoyé par olivier.decourt

Bonjour.
Personnellement je n'utilise pas de macros, juste un peu de code. Si les indicatrices sont bien préparées en amont de la proc CORRESP, récupérer le nom des variables n'est pas très compliqué.

Code :

Bon courage.
Olivier

Merci pour la rapidité de ta réponse, c'est ce que je voulais réaliser!