[XL-2002] Recherchev et Vlookup [Résolu]

[johan89]

Bonjour,

J'ai besoin de retranscrire cette formule :

Code :

=RECHERCHEV(A2;'http://in-blablabla/[Gl_cle.xls]Section'!$B:$V;2;FAUX)

dans un code vba. Mais A2 doit varier.

Apparemment, il faut que j'utilise VLOOKUP à la place de RECHERCHEV.
Mais mon problème principal est que j'utilise cette formule dans une boucle est que à la place du A2, je dois utiliser

Code :

Cells (Ligne,1)

en incrémentant Ligne.
Ma boucle est créée, et fonctionne très bien avec le reste de mon code. Mais je ne trouve pas comment utiliser VLOOKUP dans ma boucle.

Quelqu'un peut-il m'aider svp

[mercatog]

Exemple sans boucle pour écrire la formule en E2:E00. Adapte le nom de la feuille et teste

Code :

Worksheets("Feuil1").Range("E2:E100").Formula = "=VLOOKUP(A2,'http://in-blablabla/[Gl_cle.xls]Section'!$B:$V,2,FALSE)"

[johan89]

Bonjour

Merci de ta réponse.

J'ai réussi en mettant cela dans ma boucle qui parcoure les lignes :

Code :

Cells(LigneOutput, 10).Formula = "=VLOOKUP(B" & LigneOutput & ",'http://blablabla/[Gl_cle.xls]Section'!$B:$V,21,0)"

Je ne savais pas que l'on pouvait concaténer la lettre d'une colonne avec ma variable ligne. C'est stylé

Je n'ai pas testé ton code, mais il doit fonctionner car j'ai vu dans le même genre sur d'autres forums.
Ma dernière ligne varie. Donc le numéro de ma dernière ligne est contenu dans une variable DerniereLigne. Maintenant, je sais que je pouvais utiliser ton code malgré ce détail. Je pensais que non avant.

[mercatog]

Pourquoi faire une boucle (consommatrice de ressources et de temps) si on peut faire directement

Code :

Worksheets("Feuil1").Range("J2:J" & DerniereLigne).Formula = "=VLOOKUP(B2,'http://blablabla/[Gl_cle.xls]Section'!$B:$V,21,0)"

[johan89]

yes

Quelle version est la plus optimisée ? La tienne ou la mienne ?

[mercatog]

A ton avis quel est le moyen le plus rapide, saluer chaque personne individuellement ou dire à haute voix Bonjour à tout le monde?

Généralement les boucles consomment plus de temps et de ressources qu'une méthode directe, surtout si on est en présence de beaucoup de données.

Fais ces 2 tests (qui donnent le même résultat)
1. Code avec boucle sur 30000 lignes

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
Sub TestBoucle()
Dim i As Long, t As Long
 
t = Timer
 
With Worksheets("Feuil1")
    .UsedRange.Clear
    For i = 1 To 30000
        .Range("A" & i).Formula = "=ROW()"
    Next i
End With
MsgBox "Code exécuté en " & Timer - t & " secondes"
End Sub

2. Code sans boucle sur 30000 lignes

Code :

1
2
3
4
5
6
7
8
9
10
11
Sub TestSansBoucle()
Dim t As Long
 
t = Timer
 
With Worksheets("Feuil1")
    .UsedRange.Clear
    .Range("A1:A30000").Formula = "=ROW()"
End With
MsgBox "Code exécuté en " & Timer - t & " secondes"
End Sub

A toi de choisir après ce petit test

[johan89]

Wouah !! en effet impressionnant la différence !
Désolé pour le temps de réponse, je n'ai pas eu vraiment le temps ces derniers jours.

Ok donc clairement, les boucles ralentissent le code.

Merci