Problème (surement simple) de code [Résolu]

[Vincent32]

Bonjour,

Qu'est ce qui ne va pas dans cette ligne de code ?

Code :

ws1.Range(Cells(1, 1), Cells(DerL1 - 1, 1)).Copy ws4.Range("A:A")

J'ai un fichier qui comprend 20000 lignes
Je cherche à copier les cellules A2 à A19999 de la feuille 1 sur les cellules A1 à A19998 de la feuille 2

Cordialement

Vincent

[Daniel.C]

J'essaierais :

Code :

ws1.Range(Cells(2, 1), Cells(DerL1 - 1, 1)).Copy ws4.Range("A1")

si DerL1=20000

[Vincent32]

Code :

1
2
3
4
5
  'Recherche de la dernière ligne renseignée dans la colonne A de la feuille 1
    DerL1 = ws1.Range("A" & ws1.Rows.Count).End(xlUp).Row
 
    'Recopie de la colonne A2 à Ax-1 de la feuille 1 dans la feuille 4
    ws1.Range(Cells(2, 1), Cells(DerL1 - 1, 1)).Copy ws4.Range("A1")

Non ça ne fonctionne pas non plus ...

[Daniel.C]

Qu'est-ce que tu obtiens ?

[Vincent32]

J'obtiens :

Erreur d'exécution '1004' :

La méthode 'Range' de l'objet '_Worksheet' a échoué

Une idée ?

[DeTraX]

et avec

Code :

1
2
3
4
 
ws1.Range(Cells(2, 1), Cells(DerL1 - 1, 1)).Copy 
ws4.Range("A1").Select
Selection.Paste

Si ça ne marche pas, peux-tu nous donner la valeur de DerL1 au moment de la sélection ?

[Vincent32]

9a ne fonctionne pas. Toujours la même erreur.

Comment puis je trouver la valeur de DerL1 au moment de la sélection ?

Voici mon code :

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
'Déclaration des variables
    Dim ws0 As Worksheet, ws1 As Worksheet, ws2 As Worksheet, ws3 As Worksheet, ws4 As Worksheet
    Const PremL1 = 1 'Première ligne de données dans la feuille 1
    Const PremC1 = 1 'Première colonne de données dans la feuille 1
    Dim DerL1 As Long 'Dernière ligne de données dans la feuille 1
    Dim DerC1 As Long 'Dernière colonne de données dans la feuille 1
    Dim Col As Long
    Dim Lig As Long
    Dim Lign As Long
 
    'Attribution de valeurs
    Set ws0 = Worksheets("Macro")
    Set ws1 = Worksheets("Données brutes") 'L'objet Feuille 1 est attribué à la variable ws1
    Set ws2 = Worksheets("Soustraction") 'L'objet Feuille 2 est attribué à la variable ws2
    Set ws3 = Worksheets("Normalisation") 'L'objet Feuille 3 est attribué à la variable ws3
    Set ws4 = Worksheets("Dérivée")
 
    'Recherche de la dernière ligne renseignée dans la colonne A de la feuille 1
    DerL1 = ws1.Range("A" & ws1.Rows.Count).End(xlUp).Row
    'Recherche de la dernière colonne renseignée dans la ligne 1 de la feuille 1
    DerC1 = ws1.Cells(1, ws1.Columns.Count).End(xlToLeft).Column
 
    'Recopie de la colonne A de la feuille 1 dans les feuilles 2 et 3
    ws1.Range("A:A").Copy ws2.Range("A:A")
    ws1.Range("A:A").Copy ws3.Range("A:A")
    'ws1.Range("A:A").Copy ws4.Range("A:A")
    'Recopie de la colonne A2 à Ax-1 de la feuille 1 dans la feuille 4
    Sheets("Données brutes").Range(Cells(2, 1), Cells(DerL1 - 1, 1)).Copy
    Sheets("Dérivée").Range("A1").Select
    Selection.Paste

Et le document possède 1738 lignes

[DeTraX]

pour afficher tes bornes

Code :

1
2
3
4
5
6
7
 
'Recherche de la dernière ligne renseignée dans la colonne A de la feuille 1
DerL1 = ws1.Range("A" & ws1.Rows.Count).End(xlUp).Row
'Recherche de la dernière colonne renseignée dans la ligne 1 de la feuille 1
DerC1 = ws1.Cells(1, ws1.Columns.Count).End(xlToLeft).Column
' Affichage
Msgbox "DerL1 = " & DerL1 & " - " & "DerC1 = " & DerC1

[Vincent32]

Alors DerL1= 1738
DerC1=1

[Daniel.C]

Bien sûr :

Code :

ws1.Range(ws1.Cells(2, 1), ws1.Cells(DerL1 - 1, 1)).Copy ws4.Range("A1")

J'ai honte de ne pas y avoir pensé plus tôt !

[Vincent32]

Je regarde demain matin au boulot et je te dis si ta proposition fonctionne correctement


Bonne soirée

(PS Daniel, je sais que je suis "Hors la loi" vis à vis du forum et que j'abuse de ta gentillesse, mais j'aurai encore besoin d'un coup de main sur un problème que tu as résolu aujourd'hui, j'ai rajouté un message dans le poste si tu pouvais jeter un coup d'oeil sur ce poste je t'en serais très reconnaissant) :

http://www.developpez.net/forums/d11...chiers-textes/

Encore un énorme merci)

Cordialement

Vincent

[Vincent32]

Bonjour,

Merci beaucoup Daniel, le code fonctionne parfaitement !

Cordialement

Vincent