PROC TABULATE : Mettre en couleur toutes les valeurs d'une ligne total

[CHmartine]

Bonjour,

j'ai une proc tabulate dans laquelle je souhaite mettre toutes les valeurs de la ligne total (ALL) en couleur.

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
ODS PDF UNIFORM File="&FicOUT_PDF" STARTPAGE=NO                                                                                                                                                                                                     
        Style=styles.NormalPrinter;                                                                                                                                                                                                                             
 
proc tabulate DATA=RES_ME_FAD missing ;
      class LIBTYPUM LIBUM RES_MODENT / style={textalign=c font_size=8pt font_face=arial font_style=roman font_weight=bold};
      TABLE  LIBTYPUM=' ' * (LIBUM=' ' ALL='Total'*f=10.*{s={textalign=c background=white foreground=red font_size=8pt height=0.5cm font_face=arial font_style=roman}}) ALL='Total'*f=10.*{s={textalign=c foreground=red font_size=8pt height=0.5cm font_face=arial font_style=roman}} ,
             RES_MODENT="Modes d'entrée" * N="Nb RUM"*f=10.*{s={cellwidth=2.5cm textalign=r font_size=8pt height=0.5cm font_face=arial font_style=italic}}
	                  / rts=80 box={label=" " style={just=LEFT font_face=arial font_size=2 font_style=roman}} misstext=" ";                                                                                                                           
     classlev LIBUM / style={textalign=l font_size=8pt font_face=arial font_style=italic font_style=roman font_weight=light};
     classlev LIBTYPUM / style={textalign=l font_size=8pt font_face=arial font_style=italic font_style=roman font_weight=light};
     keyword ALL / style={background=white textalign=l font_size=8pt height=0.5cm font_face=arial font_style=italic font_weight=bold}; 
     keyword N / style={textalign=c font_size=8pt height=0.5cm font_face=arial font_style=italic font_weight=bold};   
run; 
ODS PDF CLOSE;

J'ai beau mettre au niveau des 2 instructions ALL : foreground=red mais à l'édition les valeurs des mes lignes 'total (ALL)' restent en couleur "noire".
Par avance je remercie la personne qui pourra m'aider à résoudre ce problème .
Cordialement.

[olivier.decourt]

Bonjour Martine.
Je ne sais pas si j'y vois clair dans la forêt d'indications de style et de formats (certaines en double pour les formats, d'ailleurs), mais une piste serait la suivante : quand une cellule du tableau reçoit plusieurs indications de style de sources différentes (par la ligne à laquelle elle appartient et par sa colonne), SAS ne les combine pas, mais fait de l'annule et remplace.
Donc la couleur rouge sur la ligne de total se trouve annulée par l'indication de style au niveau des colonnes.
Une solution est l'option STYLE_PRECEDENCE=ROW, qui rend les styles mentionnés en ligne prioritaires sur ceux des colonnes. On change juste l'ordre de l'annule et remplace, on n'obtient pas vraiment de combinaison, mais c'est déjà ça.

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
ODS PDF FILE="c:\temp\martine.pdf" ;
PROC TABULATE DATA=sashelp.class ;
  CLASS age sex ;
  TABLE age ALL*{S={FOREGROUND=RED FONT_WEIGHT=BOLD}},
        sex * N*{S={FONT_SIZE=10PT}} ;
RUN ;
PROC TABULATE DATA=sashelp.class ;
  CLASS age sex ;
  TABLE age ALL*{S={FOREGROUND=RED FONT_WEIGHT=BOLD}},
        sex * N*{S={FONT_SIZE=10PT}} 
	/ STYLE_PRECEDENCE=ROW ;
RUN ;
ODS PDF CLOSE ;

Bon courage.
Olivier