Ajouter Colonne dynamique [Résolu]

[benbrisefer]

Bonjour, j'aurais voulu savoir comment créer une ou plusieurs colonnes dynamiques dans une table SAS.
Je m'explique : au départ du code suivant :

Code :

1
2
3
4
5
6
7
8
9
DATA Tmp;
     INPUT NOM$ TYPE$ NUMERO$;
     CARDS;
DUPONT 10 1234567
DUPONT 20 7654321
DUBOIS 10 0123456
DUBOIS 30 6543210
;
RUN;

Comment faire pour que les 3 colonnes suivantes soient ajoutées automatiquement :
_10_NUMERO
_20_NUMERO
_30_NUMERO

Je pensais faire quelque chose du style :

Code :

1
2
3
4
DATA Tmp;
     SET Tmp;
     '_'||TYPE||'_NUMERO' = NUMERO;
RUN ;

Mais cela ne marche pas ...
Quelqu'un à une idée ?
Merci d'avance.

[olivier.decourt]

Bonjour.
L'idée est bonne mais il faut procéder en 2 temps : 1) préparer les noms de tes futures colonnes avec la formule que tu mets à gauche du = et 2) faire une proc TRANSPOSE.

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
DATA Tmp;
     INPUT NOM$ TYPE$ NUMERO$;
     CARDS;
DUPONT 10 1234567
DUPONT 20 7654321
DUBOIS 10 0123456
DUBOIS 30 6543210
;
RUN;
DATA tmp2 ;
  SET tmp ;
  nomVar = COMPRESS("_"!!type!!"_NUMERO") ;
RUN ;
PROC TRANSPOSE DATA=tmp2 OUT=tmp2 (DROP=_name_) ;
  VAR numero ;
  ID nomVar ;
  BY nom NOTSORTED ;
RUN ;

Bon courage.
Olivier

[jerome_pdv2]

Bonjour,

tu peux également penser aux ARRAYs qui semblent tout indiqués dans ton cas.

bonne journée.

[benbrisefer]

Très pratique ce PROC TRANSPOSE !!
Est-il possible de trier les colonnes ajoutées (par intitulé) ?
Merci.

[olivier.decourt]

Non, pas de tri possible à ma connaissance.

Pour ton autre question (en MP mais je préfère poster la réponse) : si tu as plusieurs colonnes à transposer, soit tu fais plusieurs proc TRANSPOSE puis un MERGE, soit tu dupliques les observations dans la table en entrée :

Code :

1
2
3
4
5
6
nom=formule1 ;
valeur=variable1 ;
OUTPUT ;
nom=formule2 ;
valeur=variable2 ;
OUTPUT ;

dans ton étape DATA, puis PROC TRANSPOSE avec ID nom et VAR valeur.

Bon courage.
Olivier

[benbrisefer]

Un tout grand merci pour toutes ces explications très intéressantes.