Problème pour remplacer un caractère dans une cellule en fonction de la présence ou non d'un autre caractère [Résolu]

[Runsh63]

Bonjour à toutes et tous,

Le titre est pas terrible mais le problème est sûrement très facile à résoudre.
Je sais avant même de la tester que ma boucle ne fonctionnera pas mais je l'ai écrite entièrement afin de vous donner une idée plus claire de ce à quoi je veux arriver.

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
'Mettre en forme les comptes
 
    Dim LR2 As Integer, ContainsSpecChar As Boolean, ExpAccount As Range
    With Sheets("Retreated Expenses")
    LR2 = .Range("A" & .Rows.Count).End(xlUp).Row
 
        For Each ExpAccount In .Range("A2:A" & LR2)
            If IsNull InStr(ExpAccount, ";") Then
                ContainsSpecChar = False
                Next ExpAccount
            Else
                Replace(ExpAccount, "/", "")
            End If
        Next ExpAccount

Alors voilà, je veux vérifier sur la totalité des cellules en A si le libellé contient un ";". Si ce n'est pas le cas, alors passer à la cellule suivante.
Par contre si il y a bien présence du ";", alors je veux remplacer le "/" par rien, donc "". Petite précision tout de même, il est possible que ma cellule contienne un ";" mais ne contienne pas de "/", je n'ai même pas réussi à formaliser ça, je pense qu'il faut rajouter un If, mais j'attends déja de voir ce que vous pouvez me proposer comme piste de départ, peut-être ensuite arriverai-je à me dépatouiller seul, ce qui est le but quelque part, car comme le dit une personne de ce forum, c'est en forgeant ...
Merci d'avance pour vos réponses, en espérant avoir été clair dans ma demande

[Daniel.C]

Bonjour,

Essaie :

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
Sub test()
Dim c As Range, ResAdr As String
With Sheets("Retreated Expenses")
    Set c = .[A:A].Find(";")
    If Not c Is Nothing Then
        ResAdr = c.Address
        Do
            c.Value = Application.Substitute(c.Value, "/", "")
            Set c = .[A:A].FindNext(c)
        Loop Until c.Address = ResAdr
    End If
End With
End Sub

[Runsh63]

Bonsoir Daniel C.,

Ecoute, ton code a l'air pas mal (j'aurai jamais pu le faire tout seul !) et j'essaie de comprendre le "ResAdr". J'ai fait un test vite fait avec les données sur une autre feuille mais le résultat me semble excellent dans le sens où j'obtiens ce que je voulais avoir. Je fais le test avec mes données finales et reviens vers toi pour te tenir au courant.
Quoiqu'il en soit, un grand MERCI !

[Daniel.C]

Tu mets l'adresse de la première cellule où tu trouves un ";" dans ResAdr; comme tu fais une recherche dans la colonne A, tu bouclerais si tu n'avais pas cette adresse. Quand Find est revenu sur la cellule initiale, la macro s'arrête.

[Runsh63]

Merci pour tes explications. Pas évident à écrire propre ce type de boucle, mais je garde ça au chaud car très utile. J'ai besoin de m'exercer.
Encore merci, bonne journée Daniel C.