Calcul du semestre à partir d'une date

[mohamed_]

Bonsoir,

Je cherche à calculer le semestre à partir d'une date.

Mais je n'arrive pas à trouver la fonction sas correspondante.

Pourriez vous m'aider ?

[RemiBousquet]

A ma connaissance,
SAS propose des formats qui permettent de retrouver directement le trimestre, mais pas le semestre, cf exemples :

Code :

1
2
3
4
5
6
DATA test ;
    date           = "01jan2010"d ;
    year_Q_quarter = put(date, yyq.) ;
    year_quarter   = put(date, yyqn.) ;
    putlog _all_ ;
run ;

Il doit même y avoir un format qtr. qui donne le trimestre sans l'année, mais à partir de la v9.2 seulement (et oui, je suis en v9.1.3 ...)

Pour avoir le semestre, il faudra donc feinter. Proposition, en partant de la fonction month() :

Code :

1
2
3
4
5
6
DATA test ;
    date           = "01jan2010"d ;
    month          = month(date) ;
    semestre       = 1 + (month(date) > 6) ;
    putlog _all_ ;
run ;

Tu peux te faire plaisir en faisante une macro %semestre() si tu en fais un usage fréquent :

Code :

1
2
3
4
5
6
7
8
%macro semestre(date) ;
    1 + (month(&date.)  > 6 )
%mend ;
DATA test ;
    date           = "01jan2010"d ;
    semestre       = %semestre(date) ;
    putlog _all_ ;
run ;

Il doit être possible de créer une fonction, mais ça j'ai jamais fait

[Manoutz]

Bonjour,

Je cherche à calculer le semestre à partir d'une date.

il ya plusieurs comprehensions possibles. Est ce qu'il s'agit de renvoyer le semestre de l'annee en cours?(0 ou 1 suivant qu'on est avant le 30 juin ou apres)?


essaye la fonction intck avec l'interval semiyear.

http://dept.kent.edu/sas/lgref/z0212868.htm

Code :

1
2
3
4
5
6
7
8
9
DATA test;
format date date9.;
date=15362;
semester=intck('semiyear',intnx('year',date,0,"b"),date);
output;
date=15552;
semester=intck('semiyear',intnx('year',date,0,"b"),date);
output;
run;

Avec intnx je recupere le debut de l'annee

[mohamed_]

Bonjour,

Manoutz, ce que je cherche est effectivement une fonction qui me permettrait de retourner le trimestre T1ou Q1. La fonction

Code :

year_Q_quarter = put(date, yyq.) ;

que Remi m'indiquait fonctionne très bien.

Par contre pour le semestre je n'ai pas trouvé.

J'essaye ton bout de code.

[mohamed_]

c'est exactement ce que je voulais en ajoutant +1 comme dans le code de Rémi.

Rémi a écrit :

Il doit être possible de créer une fonction, mais ça j'ai jamais fait

Comment faire pour créer cette fonction que je pourrais rappeler quand je voudrais ?

[datametric]

si tu as la 9.2/9.3 tu regardes la proc FCMP et son cadre d'utilisation.

[Manoutz]

ou passer par une macro fonction, tout simplement...

D'ailleurs, tu dois pouvoir parameter si tuveux calculer sur le trimestre ou le semestre, en utilisant (et en appliquant au trimestre, selon) le code que je t'ai fourni